从 Excel VBA 发送格式化的 Lotus Notes 富文本电子邮件

Question

我对 Lotus Script 或 Notes/Domino 的了解很少，但我有一个很久以前从某处复制的过程，它允许我从 VBA 通过 Notes 发送电子邮件。 我通常只将其用于内部通知，其中格式并不重要。

我现在想用它向客户发送外部电子邮件，而企业类型希望电子邮件符合我们的风格指南（基本上是无衬线字体）。

我正要告诉他们该代码仅适用于纯文本，但后来我注意到该例程确实引用了某种 CREATERICHTEXTITEM 对象。 这是否意味着我可以在将正文字符串传递到邮件例程之后对其应用某种格式？ 除了维护我们宝贵的品牌价值之外，这对我来说对于突出显示电子邮件中的某些段落也非常方便。

我对“网络”进行了深入研究，看看这段代码是否可以改编，但由于不熟悉 Notes 的对象模型，而且在线 Notes 资源似乎反映了应用程序本身的迟钝性，这意味着我并没有得到太多的帮助。远的。

代码：

Sub sendEmail(EmailSubject As String, EMailSendTo As String, EMailBody As String, MailServer as String)

    Dim objNotesSession As Object
    Dim objNotesMailFile As Object
    Dim objNotesDocument As Object
    Dim objNotesField As Object
    Dim sendmail As Boolean

    'added for integration into reporting tool
    Dim dbString As String

    dbString = "mail\" & Application.UserName & ".nsf"

On Error GoTo SendMailError
    'Establish Connection to Notes
    Set objNotesSession = CreateObject("Notes.NotesSession")
On Error Resume Next
    'Establish Connection to Mail File
    Set objNotesMailFile = objNotesSession.GETDATABASE(MailServer, dbString)
    'Open Mail
    objNotesMailFile.OPENMAIL
On Error GoTo 0

    'Create New Memo
    Set objNotesDocument = objNotesMailFile.createdocument

    Dim oWorkSpace As Object, oUIdoc As Object
    Set oWorkSpace = CreateObject("Notes.NotesUIWorkspace")
    Set oUIdoc = oWorkSpace.CurrentDocument

    'Create 'Subject Field'
    Set objNotesField = objNotesDocument.APPENDITEMVALUE("Subject", EmailSubject)

    'Create 'Send To' Field
    Set objNotesField = objNotesDocument.APPENDITEMVALUE("SendTo", EMailSendTo)

    'Create 'Copy To' Field
    Set objNotesField = objNotesDocument.APPENDITEMVALUE("CopyTo", EMailCCTo)

    'Create 'Blind Copy To' Field
    Set objNotesField = objNotesDocument.APPENDITEMVALUE("BlindCopyTo", EMailBCCTo)

    'Create 'Body' of memo
    Set objNotesField = objNotesDocument.CREATERICHTEXTITEM("Body")

    With objNotesField
        .APPENDTEXT emailBody
        .ADDNEWLINE 1
    End With

    'Send the e-mail

    Call objNotesDocument.Save(True, False, False)
    objNotesDocument.SaveMessageOnSend = True
    'objNotesDocument.Save
    objNotesDocument.Send (0)

    'Release storage
    Set objNotesSession = Nothing
    Set objNotesMailFile = Nothing
    Set objNotesDocument = Nothing
    Set objNotesField = Nothing

    'Set return code
    sendmail = True

    Exit Sub

SendMailError:
    Dim Msg
    Msg = "Error # " & Str(Err.Number) & " was generated by " _
                & Err.Source & Chr(13) & Err.Description
    MsgBox Msg, , "Error", Err.HelpFile, Err.HelpContext
    sendmail = False
End Sub

Answer 1

简短的回答是肯定的。 冗长的答案令人痛苦。 没有任何优秀的类可以用来操作 Notes 中的富文本项目。 不过，您可以研究的一些内容包括 NotesRichTextStyle、NotesRichTextParagraphStyle 和 NotesRichTextTable 等。 这些类可帮助您定义一些富文本元素并以编程方式将它们添加到富文本字段中。

由于您要发送电子邮件，另一种方法是使用 NotesMIMEEntity 类并使用 HTML 构建电子邮件（方式更简单）。 下面是一些示例代码：

Set s = New NotesSession
Dim docMail As NotesDocument
Dim body As NotesMIMEEntity
Dim stream As NotesStream

Set db = s.CurrentDatabase
s.ConvertMIME = False ' Do not convert MIME to rich text

'Create email to be sent
Set docMail = db.CreateDocument

With docMail
        .SendTo = SEND TO ADDRESS
        .From = FROM ADDRESS
        .Principal = FROM ADDRESS
        .ReplyTo = REPLY TO ADDRESS
        .Subject = SUBJECT
        .Form = "Memo"
End With

  Set stream = s.CreateStream
Set body = docMail.CreateMIMEEntity
Call stream.WriteText ("YOUR HTML CODE GOES HERE")

'ENC_IDENTITY_8BIT used because of technote found on notes.net
'http://www-10.lotus.com/ldd/nd6forum.nsf/55c38d716d632d9b8525689b005ba1c0/aeedaf28e47546ad85256f6a000a4b48?OpenDocument
Call body.SetContentFromText (stream, "text/html;charset=iso-8859-1",ENC_IDENTITY_8BIT) 

Call docMail.Send(False)
Set docMail = Nothing
Set body = Nothing
Set stream = Nothing

s.ConvertMIME = True ' Restore conversion   

本质上，您需要在 NotesSession 中关闭 ConvertMIME 设置。 然后创建一个新文档，设置邮件属性等。该部分已经在您的 VBA 代码中。 接下来，创建 MIMEEntity 和一个流来保存 HTML 文本。 最后调用 MIMEEntity 对象上的 SetContentFromText 方法。 然后发送您的电子邮件。 请注意，最后一次调用是为 NotesSession 重新打开 ConvertMIME 功能。

我不确定这是否都可以通过 COM 工作，但它在 Notes 中的 LotusScript 代理中工作得很好。

我希望这有帮助！

Answer 2

要更改其发件人，请创建通用 Notes ID（例如自动发送/YourCompany）并使用该 ID 保存代理。

Answer 3

我喜欢它本来的样子。 然而我不得不改变
dbString = "邮件\" & Application.UserName & “.nsf”
到
dbString = "邮件\" & Application.CurrentUser 和 “.nsf”

第一条评论：我希望在发送时不必打开 Lotus Notes。

第二条评论：我希望我可以更改电子邮件的发件人（即，如果我要向 50 个人发送报告，我希望它来自通用地址，而不是我的工作地址）