“左侧不能分配给” Delphi 中的记录类型属性

Question

我很好奇为什么 Delphi 将记录类型属性视为只读：

  TRec = record
    A : integer;
    B : string;
  end;

  TForm1 = class(TForm)
  private
    FRec : TRec;
  public
    procedure DoSomething(ARec: TRec);
    property Rec : TRec read FRec write FRec;
  end;

如果我尝试将值分配给 Rec 属性的任何成员，我会收到“左侧无法分配给”错误：

procedure TForm1.DoSomething(ARec: TRec);
begin
  Rec.A := ARec.A;
end;

同时执行相同操作允许使用底层字段：

procedure TForm1.DoSomething(ARec: TRec);
begin
  FRec.A := ARec.A;
end;

对该行为有任何解释吗？

Answer 1

由于“Rec”是一个属性，编译器对它的处理方式略有不同，因为它必须首先评估属性 decl 的“读取”。 考虑一下这一点，这在语义上等同于您的示例：

...
property Rec: TRec read GetRec write FRec;
...

如果您像这样查看它，您可以看到对“Rec”的第一个引用（在点“.”之前）必须调用 GetRec，这将创建一个临时本地Rec 的副本。 这些临时对象被设计为“只读”。 这就是你遇到的情况。

您可以在此处执行的另一件事是将记录的各个字段分解为包含类的属性：

...
property RecField: Integer read FRec.A write FRec.A;
...

这将允许您通过属性直接分配给类实例中嵌入记录的字段。

Answer 2

是的，这是一个问题。 但问题可以使用记录属性来解决：

type
  TRec = record
  private
    FA : integer;
    FB : string;
    procedure SetA(const Value: Integer);
    procedure SetB(const Value: string);
  public
    property A: Integer read FA write SetA;
    property B: string read FB write SetB;
  end;

procedure TRec.SetA(const Value: Integer);
begin
  FA := Value;
end;

procedure TRec.SetB(const Value: string);
begin
  FB := Value;
end;

TForm1 = class(TForm)
  Button1: TButton;
  procedure Button1Click(Sender: TObject);
private
  FRec : TRec;
public
  property Rec : TRec read FRec write FRec;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Rec.A := 21;
  Rec.B := 'Hi';
end;

这可以毫无问题地编译和工作。

Answer 3

我经常使用的解决方案是将属性声明为指向记录的指针。

type
  PRec = ^TRec;
  TRec = record
    A : integer;
    B : string;
  end;

  TForm1 = class(TForm)
  private
    FRec : TRec;

    function GetRec: PRec;
    procedure SetRec(Value: PRec);
  public
    property Rec : PRec read GetRec write SetRec; 
  end;

implementation

function TForm1.GetRec: PRec;
begin
  Result := @FRec;
end;  

procedure TForm1.SetRec(Value: PRec);
begin
  FRec := Value^;
end;

这样，直接分配 Form1.Rec.A := MyInteger 就可以了，而且 Form1.Rec := MyRec 也可以通过复制 MyRec 中的所有值来工作 按预期添加到 FRec 字段。

这里唯一的陷阱是，当您希望实际检索要使用的记录的副本时，您将不得不使用类似 MyRec := Form1.Rec^

Answer 4

编译器阻止您分配给临时变量。 C# 中的等效项是允许的，但没有效果； Rec 属性的返回值是基础字段的副本，并且分配给副本上的字段是 nop。

Answer 5

因为您有隐式 getter 和 setter 函数，并且您无法修改函数的 Result，因为它是 const 参数。

（注意：如果您转换对象中的记录，结果实际上是一个指针，因此相当于 var 参数）。

如果您想保留记录，则必须使用中间变量（或字段变量）或使用WITH 语句。

使用显式 getter 和 setter 函数查看以下代码中的不同行为：

type
  TRec = record
    A: Integer;
    B: string;
  end;

  TForm2 = class(TForm)
  private
    FRec : TRec;
    FRec2: TRec;
    procedure SetRec2(const Value: TRec);
    function GetRec2: TRec;
  public
    procedure DoSomething(ARec: TRec);
    property Rec: TRec read FRec write FRec;
    property Rec2: TRec  read GetRec2 write SetRec2;
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

{ TForm2 }

procedure TForm2.DoSomething(ARec: TRec);
var
  LocalRec: TRec;
begin
  // copy in a local variable
  LocalRec := Rec2;
  LocalRec.A := Arec.A; // works

  // try to modify the Result of a function (a const) => NOT ALLOWED
  Rec2.A := Arec.A; // compiler refused!

  with Rec do
    A := ARec.A; // works with original property and with!
end;

function TForm2.GetRec2: TRec;
begin
  Result:=FRec2;
end;

procedure TForm2.SetRec2(const Value: TRec);
begin
  FRec2 := Value;
end;

Answer 6

最简单的方法是：

procedure TForm1.DoSomething(ARec: TRec);
begin
  with Rec do
    A := ARec.A;
end;

Answer 7

这是因为属性实际上是作为函数编译的。 属性仅返回或设置一个值。 它不是指向记录的引用或指针

，因此：

Testing.TestRecord.I := 10;  // error

与调用这样的函数相同：

Testing.getTestRecord().I := 10;   //error (i think)

您可以做的是：

r := Testing.TestRecord;    // read
r.I := 10;
Testing.TestRecord := r;    //write

它有点混乱，但是是这种类型的体系结构所固有的。

Answer 8

正如其他人所说 - 读取属性将返回记录的副本，因此字段的分配不会作用于 TForm1 拥有的副本。

另一种选择是这样的：

  TRec = record
    A : integer;
    B : string;
  end;
  PRec = ^TRec;

  TForm1 = class(TForm)
  private
    FRec : PRec;
  public
    constructor Create;
    destructor Destroy; override;

    procedure DoSomething(ARec: TRec);
    property Rec : PRec read FRec; 
  end;

constructor TForm1.Create;
begin
  inherited;
  FRec := AllocMem(sizeof(TRec));
end;

destructor TForm1.Destroy;
begin
  FreeMem(FRec);

  inherited;
end;

Delphi 将为您取消引用 PRec 指针，因此这样的事情仍然有效：

Form1.Rec.A := 1234; 

不需要属性的写入部分，除非您想交换 FRec 指向的 PRec 缓冲区。 无论如何，我真的不建议通过属性进行此类交换。