Flex - 将滚动条的位置更改为 Horizo​​ntalList 组件的顶部

Question

默认情况下，Horizo​​ntalList 组件的水平滚动条位于底部。 有没有办法重新定位它，使其位于顶部？

为了清楚起见，我并不是指使用scrollToIndex或horizo​​ntalScrollPosition或类似的方法移动滚动位置，而是滚动条组件的实际物理位置。

任何建议将不胜感激！

Answer 1

我不久前也在寻找类似的东西，发现这个发布。 我最终以另一种方式解决了我的问题，所以没有使用该解决方案，但它可能适合你想要的。

Answer 2

我以前也必须做同样的事情。 我必须深入研究基类（以处理一些掩蔽/定位问题），这就是我想到的：

package
{
    import flash.display.DisplayObject;

    import mx.controls.HorizontalList;
    import mx.core.EdgeMetrics;

    public class ReverseHList extends HorizontalList
    {
        override protected function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void
        {
            super.updateDisplayList(unscaledWidth, unscaledHeight);

            var w:Number = unscaledWidth;
            var h:Number = unscaledHeight;
            var vm:EdgeMetrics = viewMetrics;
            if (horizontalScrollBar && horizontalScrollBar.visible)
            {
                horizontalScrollBar.setActualSize(w - vm.left - vm.right,
                                                  horizontalScrollBar.minHeight);
                horizontalScrollBar.move(vm.left, vm.top);

                horizontalScrollBar.enabled = enabled;
            }

            var mask:DisplayObject = maskShape;

            var wd:Number = w - vm.left - vm.right;
            var ht:Number = h - vm.top - vm.bottom;

            mask.width = wd < 0 ? 0 : wd;
            mask.height = ht < 0 ? 0 : ht;

            mask.x = vm.left;
            mask.y = vm.top + vm.bottom;
        }

        override protected function adjustListContent(unscaledWidth:Number = -1,
                                       unscaledHeight:Number = -1):void
        {
            super.adjustListContent(unscaledWidth, unscaledHeight);

            var lcx:Number = viewMetrics.left + listContent.leftOffset;
            var lcy:Number = (viewMetrics.top + listContent.topOffset) + viewMetrics.bottom;
            listContent.move(lcx, lcy);
        }

    }
}