使用 Excel VBA 列出特定模式的文件

Question

如何列出用户指定目录中与特定模式匹配的所有文件？ 这应该在所选目录的子文件夹内递归地工作。 我还需要一种方便的方式（如树控件）来列出它们。

Answer 1

似乎有几个答案讨论了递归，一个答案讨论了正则表达式。 下面是一些将两个主题放在一起的代码。 我从 http://vba-tutorial.com 获取了代码

Sub FindPatternMatchedFiles()

    Dim objFSO As Object
    Set objFSO = CreateObject("Scripting.FileSystemObject")

    Dim objRegExp As Object
    Set objRegExp = CreateObject("VBScript.RegExp")
    objRegExp.pattern = ".*xlsx"
    objRegExp.IgnoreCase = True

    Dim colFiles As Collection
    Set colFiles = New Collection

    RecursiveFileSearch "C:\Path\To\Your\Directory", objRegExp, colFiles, objFSO

    For Each f In colFiles
        Debug.Print (f)
        'Insert code here to do something with the matched files
    Next

    'Garbage Collection
    Set objFSO = Nothing
    Set objRegExp = Nothing

End Sub

Sub RecursiveFileSearch(ByVal targetFolder As String, ByRef objRegExp As Object, _
                ByRef matchedFiles As Collection, ByRef objFSO As Object)

    Dim objFolder As Object
    Dim objFile As Object
    Dim objSubFolders As Object

    'Get the folder object associated with the target directory
    Set objFolder = objFSO.GetFolder(targetFolder)

    'Loop through the files current folder
    For Each objFile In objFolder.files
        If objRegExp.test(objFile) Then
            matchedFiles.Add (objFile)
        End If
    Next

    'Loop through the each of the sub folders recursively
    Set objSubFolders = objFolder.Subfolders
    For Each objSubfolder In objSubFolders
        RecursiveFileSearch objSubfolder, objRegExp, matchedFiles, objFSO
    Next

    'Garbage Collection
    Set objFolder = Nothing
    Set objFile = Nothing
    Set objSubFolders = Nothing

End Sub

Answer 2

作为一般指针，请查看 Application.FileSearch、递归函数、用户窗体和“Microsoft TreeView 控件”。

FileSearch 可用于查找与模式匹配的文件夹中的文件，递归函数可以调用自身，直到用尽所有路径，UserForm 可以托管用于显示数据的控件，TreeView 控件可以显示文件系统。

请记住，有一些预构建的函数/控件可用于显示文件系统，例如 Application.GetOpenFileName、Application.GetSaveAsFileName、Microsoft WebBrowser（给定“file://...”URL）。

Answer 3

尝试 Windows 脚本 - 文件系统对象。 这个可以从 vba 创建的 COM 对象具有列出目录等功能。

您可以在

Answer 4

不完全是你所要求的，但我想我会把它发布在这里，因为它是相关的。

这是根据 http://www.cpearson.com/excel/FOLDERTREEVIEW 中找到的代码修改的。 ASPX

这需要参考Microsoft Scripting Runtime。

Sub ListFilePaths()

    Dim Path As String
    Dim Files As Long

    Path = "C:\Folder"

    Files = GetFilePaths(Path, "A", 1)

    MsgBox "Found " & Files - 1 & " Files"

End Sub

Function GetFilePaths(Path As String, Column As String, StartRow As Long) As Long

    Dim Folder As Scripting.Folder
    Dim SubFolder As Scripting.Folder
    Dim File As Scripting.File
    Dim FSO As Scripting.FileSystemObject
    Dim CurrentRow As Long

    Set FSO = New Scripting.FileSystemObject
    Set Folder = FSO.GetFolder(folderpath:=Path)

    CurrentRow = StartRow

    For Each File In Folder.Files
        Range(Column & CurrentRow).Value = File.Path
        CurrentRow = CurrentRow + 1
    Next File

    For Each SubFolder In Folder.SubFolders
        CurrentRow = GetFilePaths(SubFolder.Path, Column, CurrentRow)
    Next SubFolder

    GetFilePaths = CurrentRow

    Set Folder = Nothing
    Set FSO = Nothing
End Function

Answer 5

我看到我上面的人已经回答了如何通过文件树递归，这可能会让您对搜索文件/文件名中的模式感兴趣。 它是一个允许使用正则表达式的 VBA 函数。

Private Function RegularExpression(SearchString As String, Pattern As String) As String

    Dim RE As Object, REMatches As Object

    'Create the regex object' 
    Set RE = CreateObject("vbscript.regexp")
    With RE
        .MultiLine = False
        .Global = False
        .IgnoreCase = True
        'set the search pattern using parameter Pattern'
        .Pattern = Pattern 
    End With

    'Search for the pattern' 
    Set REMatches = RE.Execute(SearchString) 
    If REMatches.Count > 0 Then
        'return the first match'
        RegularExpression = REMatches(0) 
    Else
        'nothing found, return empty string'
        RegularExpression = ""
    End If

End Function

您可以使用它来搜索文件名中的模式。 我建议正则表达式主页了解有关如何使用正则表达式的更多信息