Textfield()-如何阻止鼠标右键菜单

Question

Textfield () - 如何防止出现鼠标右键菜单（具有复制、粘贴、全选等选项的菜单）。

Answer 1

FlashPlayers 默认菜单项。

据我所知，您无法删除有意义的基本 FlashPlayer 项目（设置和关于）。

FlashPlayers 内置项目

您可以通过在编译时或在代码中指定它来删除最重要的项目（播放、暂停等）：

contextMenu.hideBuiltInItems();

或在全局上下文中：

stage.showDefaultContextMenu = false; 

与 TextField 相关的菜单项< /strong>

文本字段的复制/粘贴/选择也是内置的，似乎您无法隐藏它们。 然而，您似乎确实想摆脱它们，这里有一个解决方法。
下面的示例说明了如何在文本字段上添加透明按钮以转移鼠标行为：

package  
{
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldType;
    import flash.ui.ContextMenu;        


    public class TestText extends Sprite 
    {

        private var textField:TextField;

        public function TestText()
        {
            // Removes the inbuit items from the contextMenu

            var contextMenu:ContextMenu = new ContextMenu();
            contextMenu.hideBuiltInItems();
            this.contextMenu = contextMenu;

            // Adds a simple input TextField

            textField = addChild(new TextField()) as TextField;
            textField.type = TextFieldType.INPUT;
            textField.text = "Test Text";

            // Covers the TextField with a transparent shape

            var shape:Sprite = addChild(new Sprite()) as Sprite;
            shape.graphics.beginFill(0, 0);
            shape.graphics.drawRect(0, 0, textField.width, textField.height);
            shape.mouseChildren = false;

            // Listens to a click on the mask to activate typing

            shape.addEventListener(MouseEvent.CLICK, eventClickHandler);
        }

        private function eventClickHandler(event:MouseEvent):void
        {
            // Sets the focus to the underlaying TextField and makes 
            // a full selection of the existing text.

            stage.focus = textField;
            textField.setSelection(0, textField.text.length);
        }
    }
}

Answer 2

您是否尝试过使用自定义 InteractiveObject.contextMenu？

Answer 3

将字段 selectable 属性设置为 false。

Answer 4

我找到了隐藏 TextFields 的默认上下文菜单项的方法！

只需设置一个自定义上下文菜单，并隐藏内置项目。 现在，当您右键单击时，什么也没有发生！

 // hide cut/copy/paste
 var cm:ContextMenu = new ContextMenu();
 cm.hideBuiltInItems();
 textfield.contextMenu = cm;