DOS脚本根据日期动态获取文件名和路径

Question

我必须在 Windows 中编写一些批处理/dos 脚本，将文件放入 UNIX 框中。 但是 Windows 中的路径和文件名每年和每月都会发生变化。

假设 Windows 中的目录位于路径 C:/2009MICS，该目录将保存全年的文件（12 个文件）。 我的批次将每月运行一次，并且应该仅选择相应月份的文件。 例如，如果我的批次在 2009 年 2 月运行。 它应该从 2009MICS 文件夹中选择并传输二月份的文件。

Answer 1

copy "%date:~6%.txt" "\path\to\destination"

会将 2009.txt 复制到目标路径。 要包含月份，请使用

copy "%date:~3%.txt" "\path\to\destination"

免责声明 - 我在德语版 Win Vista 上测试了这一点，希望它也适用于国际版本。

Answer 2

一种方法是使用 GetDate.cmd（最后）将今天的日期检索到环境变量中。 由此，您可以将 %mm% 变量（当前月份）与文件日期戳的月份进行比较，如下所示：

  @echo off
  :: see http://ss64.com/nt/syntax-args.html
  for %%f in (*.bat) do (
     echo.
     echo Parameter '~tf' reports '%%~tf' for '%%f'

     :: see http://ss64.com/nt/for_f.html
     echo.
     for /f "tokens=1-2" %%g in ("%%~tf") do (
        echo the file date %%g
        echo the file time %%h
        )

     for /f "tokens=1-3 delims=- " %%i in ("%%~tf") do (
        echo the year     %%i
        echo the month    %%j
        echo the day      %%k
        )

     )

结果：

  Parameter '~tf' reports '2009-08-28 11:52 AM' for 'test-date.bat'

  the file date 2009-08-28
  the file time 11:52
  the year     2009
  the month    08
  the day      28

您可以使用类似的标记结构来解析文件名中的日期，如果日期戳不可靠/不使用。

  ::GetDate.cmd - Source: http://ss64.com/nt/syntax-getdate.html :
  @echo off
  SETLOCAL
  FOR /f "tokens=1-4 delims=/-. " %%G IN ('date /t') DO (call :s_fixdate %%G %%H %%I %%J)
  goto :s_print_the_date

  :s_fixdate
  if "%1:~0,1%" GTR "9" shift
  FOR /f "skip=1 tokens=2-4 delims=(-)" %%G IN ('echo.^|date') DO (
      set %%G=%1&set %%H=%2&set %%I=%3)
  goto :eof

  :s_print_the_date
  echo Month:[%mm%]  Day:[%dd%]  Year:[%yy%]
  ENDLOCAL
  SET mm=%mm%&SET dd=%dd%&SET yy=%yy%

进一步阅读：

http://ss64.com/nt/syntax-getdate.html - 将日期返回到独立于区域日期设置的环境变量中
http://ss64.com/nt/syntax-datemath.html - 添加或从任意日期减去天数
http://ss64.com/nt/syntax-delolder.html - 删除文件单个文件夹中超过 N 天的内容

Answer 3

我看到两种不同的方式来解释你所问的问题。

日期是由运行脚本的日期驱动的，因此实际上使用系统日期，还是由要复制的文件的文件日期驱动？

Phil 有一个很好的观点，但是如果您未能在给定日期激活 sctipt 并尝试稍后执行（例如 3 月 1 日），则将约会过程锁定到当前日期会给您带来麻烦。

对于文件部分，我会做类似的事情：

@echo off
setlocal ENABLEDELAYEDEXPANSION
pushd C:\2009MICS
for /F "delims=" %%f in ('dir /b /a-d') do (
    for /f "tokens=2 delims=- " %%t in ("%%~tf") do set TimeStamp=%%t
    if not exist !TimeStamp!\ mkdir !TimeStamp!\
    copy %%f !TimeStamp!\ >nul
)
exit /b

我希望我的问题是正确的，否则这就是一个开始:)