很棒的 Visual Studio 宏

Question

对于小型社区讨论，您使用了哪些基本的 Visual Studio 宏？

我刚刚开始了解它们，想听听你们中的一些人离不开什么。

Answer 1

我在工具栏上添加了以下 3 个宏的按钮。 每个都将获取任何文件中当前选定的文本并用 google 搜索（或 MSDN-it 或拼写检查）。 为工具栏制作一个漂亮的图标以获得额外的风格点。

Private Const BROWSER_PATH As String = "C:\Program Files\Mozilla Firefox\firefox.exe"

Sub SearchGoogle()
    Dim cmd As String
    cmd = String.Format("{0} http://www.google.com/search?hl-en&q={1}", BROWSER_PATH, DTE.ActiveDocument.Selection.Text)
    Shell(cmd, AppWinStyle.NormalFocus)
End Sub

Sub SearchMSDN()
    Dim cmd As String
    cmd = String.Format("{0} http://www.google.com/search?hl-en&q={1}+site%3Amsdn.microsoft.com", BROWSER_PATH, DTE.ActiveDocument.Selection.Text)
    Shell(cmd, AppWinStyle.NormalFocus)
End Sub

Sub SpellCheck()
    Dim cmd As String
    cmd = String.Format("{0} http://www.spellcheck.net/cgi-bin/spell.exe?action=CHECKWORD&string={1}", BROWSER_PATH, DTE.ActiveDocument.Selection.Text)
    Shell(cmd, AppWinStyle.NormalFocus)
End Sub

Answer 2

在输出窗口中显示构建持续时间

将此代码放入您的 EnvironmentEvents 模块中。 这会将针对解决方案的任何操作（构建、重建、清理、部署）的持续时间直接写入构建窗口。

您可以更改 IsBuild 函数来指定您想要查看此信息的操作。

Dim buildStart As Date

Private Function IsBuild(ByVal scope As EnvDTE.vsBuildScope, ByVal action As EnvDTE.vsBuildAction) As Boolean
    Return scope = vsBuildScope.vsBuildScopeSolution
End Function

Private Sub BuildEvents_OnBuildBegin(ByVal Scope As EnvDTE.vsBuildScope, ByVal Action As EnvDTE.vsBuildAction) Handles BuildEvents.OnBuildBegin
    If (IsBuild(Scope, Action)) Then
        buildStart = Date.Now
    End If
End Sub

Private Sub BuildEvents_OnBuildDone(ByVal Scope As EnvDTE.vsBuildScope, ByVal Action As EnvDTE.vsBuildAction) Handles BuildEvents.OnBuildDone
    If (IsBuild(Scope, Action)) Then
        Dim buildTime = Date.Now - buildStart
        WriteToBuildWindow(String.Format("Build time: {0}", buildTime.ToString))
    End If
End Sub

Private Sub WriteToBuildWindow(ByVal message As String)
    Dim win As Window = DTE.Windows.Item(EnvDTE.Constants.vsWindowKindOutput)
    Dim ow As OutputWindow = CType(win.Object, OutputWindow)
    For Each owPane As OutputWindowPane In ow.OutputWindowPanes
        If (owPane.Name.Equals("Build")) Then
            owPane.OutputString(message)
            Exit For
        End If
    Next
End Sub

Answer 3

关闭解决方案后显示起始页（但保持 Visual Studio 打开）

将此代码放入您的 EnvironmentEvents 模块中：

Private Sub SolutionEvents_AfterClosing() Handles SolutionEvents.AfterClosing
    DTE.ExecuteCommand("View.StartPage")
End Sub

打开解决方案后隐藏起始页

将此代码放入您的 EnvironmentEvents 模块中：

Private Sub SolutionEvents_Opened() Handles SolutionEvents.Opened
    Dim startPageGuid As String = "{387CB18D-6153-4156-9257-9AC3F9207BBE}"
    Dim startPage As EnvDTE.Window = DTE.Windows.Item(startPageGuid)
    If startPage IsNot Nothing Then startPage.Close()
End Sub

当您打开解决方案时，这两者将导致您的起始页自行隐藏。 当您关闭解决方案时，起始页将返回。

Answer 4

我经常使用以下鲜为人知的快捷键：

• Ctrl+Enter：在当前行上方插入一个空行（并将光标放在此处）
• Ctrl+Shift+Enter：在当前行下面插入一个空行（并将光标放在此处）
• Ctrl+Shift+V：循环剪贴板环

Answer 5

大纲：折叠到定义但扩展区域

您是否在一家坚持在所有内容周围都有区域的商店中工作，因此当您折叠到定义时，您看不到有代码吗？

您真正需要的是一个折叠到定义但扩展区域的宏，如下所示：

Sub CollapseToDefinitionsButExpandAllRegions()
    DTE.ExecuteCommand("Edit.CollapsetoDefinitions")
    DTE.SuppressUI = True
    Dim objSelection As TextSelection = DTE.ActiveDocument.Selection
    objSelection.StartOfDocument()
    Do While objSelection.FindText("#region", 
        vsFindOptions.vsFindOptionsMatchInHiddenText)
    Loop
    objSelection.StartOfDocument()
    DTE.SuppressUI = False
End Sub

将其放入常规宏模块中，将其分配给热键，然后您的代码就回来了。

（除非......如果您与一些非常邪恶的人一起工作，他们将区域放入方法中，这将不幸地扩展这些方法。如果有人知道如何编写此代码以避免这种情况，请随意编辑。 ）

Answer 6

插入 GUID，非常适合 WiX 工作，作为按钮或快捷键添加到菜单。

Sub InsertGuid()
    Dim objTextSelection As TextSelection
    objTextSelection = CType(DTE.ActiveDocument.Selection(), EnvDTE.TextSelection)
    objTextSelection.Text = System.Guid.NewGuid.ToString.ToUpper(New System.Globalization.CultureInfo("en", False))
End Sub

组织解决方案中所有 .cs 文件的使用 - 原始作者： djpark。

Sub OrganizeSolution()
    Dim sol As Solution = DTE.Solution
    For i As Integer = 1 To sol.Projects.Count
        OrganizeProject(sol.Projects.Item(i))
    Next
End Sub

Private Sub OrganizeProject(ByVal proj As Project)
    For i As Integer = 1 To proj.ProjectItems.Count
        OrganizeProjectItem(proj.ProjectItems.Item(i))
    Next
End Sub

Private Sub OrganizeProjectItem(ByVal projectItem As ProjectItem)
    Dim fileIsOpen As Boolean = False
    If projectItem.Kind = Constants.vsProjectItemKindPhysicalFile Then
        'If this is a c# file             
        If projectItem.Name.LastIndexOf(".cs") = projectItem.Name.Length - 3 Then
            'Set flag to true if file is already open                 
            fileIsOpen = projectItem.IsOpen
            Dim window As Window = projectItem.Open(Constants.vsViewKindCode)
            window.Activate()
            projectItem.Document.DTE.ExecuteCommand("Edit.RemoveAndSort")
            'Only close the file if it was not already open                 
            If Not fileIsOpen Then
                window.Close(vsSaveChanges.vsSaveChangesYes)
            End If
        End If
    End If
    'Be sure to apply RemoveAndSort on all of the ProjectItems.         
    If Not projectItem.ProjectItems Is Nothing Then
        For i As Integer = 1 To projectItem.ProjectItems.Count
            OrganizeProjectItem(projectItem.ProjectItems.Item(i))
        Next
    End If
    'Apply RemoveAndSort on a SubProject if it exists.         
    If Not projectItem.SubProject Is Nothing Then
        OrganizeProject(projectItem.SubProject)
    End If
End Sub

Answer 7

折叠解决方案面板的所有节点，这对于大型项目非常有用：

    Public Module CollapseAllNodes
    Sub RunCollapseAllNodes()
        Dim UIHSolutionExplorer As UIHierarchy
        UIHSolutionExplorer = DTE.Windows.Item(Constants.vsext_wk_SProjectWindow).Object()

        ' Check if there is any open solution 
        If (UIHSolutionExplorer.UIHierarchyItems.Count = 0) Then
            Return
        End If

        ' Get the top node (the name of the solution) 
        Dim UIHSolutionRootNode As UIHierarchyItem
        UIHSolutionRootNode = UIHSolutionExplorer.UIHierarchyItems.Item(1)

        CloseRecursif(UIHSolutionRootNode)

        ' Select the solution node, or else when you click 
        ' on the solution windows scrollbar, it will synchronize the open document 
        ' with the tree and pop out the corresponding node which is probably not 
        ' what you want. 
        UIHSolutionRootNode.Select(vsUISelectionType.vsUISelectionTypeSelect)
    End Sub

    Function CloseRecursif(ByRef element)
        For Each UIHChild In element.UIHierarchyItems()
            CloseRecursif(UIHChild)

            If (UIHChild.UIHierarchyItems.Expanded = True) Then
                UIHChild.UIHierarchyItems.Expanded = False
            End If

        Next
    End Function
End Module

Answer 8

如果我要粘贴代码示例，我会使用 Jeff 的 FormatToHtml 宏到博客文章或电子邮件中。

Answer 9

我使用双显示器，我发现 Sharon 的布局切换宏（从 1 显示器到 2 显示器布局）非常有价值。 当您需要在键入一些代码时引用网页或其他程序时，请按 Ctrl-Alt-1 切换到 Visual Studio 窗口的单显示器布局。 完成后，按 Ctrl-Alt-2 切换到两个显示器布局并恢复所有窗口。 惊人的！

http://www. invalid-city.com/sharon/2008/06/workstation-hack-visual-studio-on-2.html

Answer 10

本身不是一个宏，但很有用：

Public Sub WriteToOutputWindow(ByVal pane as String, ByVal Msg As String)
    Dim owPane As OutputWindowPane

    Dim win As Window = DTE.Windows.Item(EnvDTE.Constants.vsWindowKindOutput)
    Dim ow As OutputWindow = win.Object
    Try
        owPane = ow.OutputWindowPanes.Item(pane)
    Catch
        owPane = ow.OutputWindowPanes.Add(pane)
    End Try
    If Not owPane Is Nothing Then
        owPane.Activate()
        owPane.OutputString(Msg & vbCrLf)
    End If
End Sub

Answer 11

我将 ctrl-shift-G 映射到一个以注册表格式生成 GUID 的宏 - 这对于编辑 IDL 很有用

Answer 12

我目前正在开发两个具有不同编码标准的不同项目，一个使用制表符作为行开头，另一个使用空格。 该宏将根据当前活动的环境在使用哪个标准之间切换：

Public Sub ToggleTabs()
  If DTE.ActiveDocument.Language = "CSharp" Then
      Dim currentSetting As Boolean = DTE.Properties("TextEditor", "CSharp").Item("InsertTabs").Value
      DTE.Properties("TextEditor", "CSharp").Item("InsertTabs").Value = Not currentSetting
  End If

  If DTE.ActiveDocument.Language = "SQL" Then
      Dim currentSQLSetting As Boolean = DTE.Properties("TextEditor", "SQL").Item("InsertTabs").Value
      DTE.Properties("TextEditor", "SQL").Item("InsertTabs").Value = Not currentSQLSetting
  End If

  If DTE.ActiveDocument.Language = "HTML" Then
      Dim currentHTMLSetting As Boolean = DTE.Properties("TextEditor", "HTML").Item("InsertTabs").Value
      DTE.Properties("TextEditor", "HTML").Item("InsertTabs").Value = Not currentHTMLSetting
  End If

  If DTE.ActiveDocument.Language = "JScript" Then
      Dim currentJScriptSetting As Boolean = DTE.Properties("TextEditor", "JScript").Item("InsertTabs").Value
      DTE.Properties("TextEditor", "JScript").Item("InsertTabs").Value = Not currentJScriptSetting
  End If

End Sub

Answer 13

我曾经在 VS 2002/2003 中使用过很多宏。 一个例子是区域创建 - 我总是喜欢将我的类划分为以下区域 - “私有成员”、“公共属性”、“公共方法”和“私有方法”。 因此，我有一个映射到快捷键的宏，可以在任何新的类文件中创建这些区域。

VS 2005/2008 中的重构支持（以及添加通用代码片段的功能）以及使用 DXCore 和 SlickEdit 等插件使我无需再创建太多宏即可工作。

Answer 14

我不能不提这个。 它甚至还有一个视频来展示如何安装和使用它。 该宏仅允许您在解决方案资源管理器中创建嵌套文件（如 resources.resx）。

编辑：更新了链接