在 SAS 中，在数据步骤之外，将宏变量中的字符替换为空白的最佳方法是什么？

Question

在 SAS 中，在数据步骤之外，将宏变量中的字符替换为空白的最佳方法是什么？

看来 TRANSLATE 是一个很好用的函数。 但是，当将 %SYSFUNC 与此函数一起使用时，参数不会用引号引起来。 您如何指示应使用空白作为替换？

Answer 1

%str( )（括号之间有一个空格）可用于指示此参数的空格。 另外要小心 TRANSLATE...第二个参数是替换字符...但是在 TRANWRD 中它是相反的。

    %macro test ;
     %let original= translate_this_var ;
     %let replaceWithThis= %str( ) ;
     %let findThis= _ ;
     %let translated= %sysfunc(translate(&original, &replaceWithThis, &findThis)) ;
     %put Original: &original ***** TRANSLATEd: &translated ;
    %mend ;
    %test;

    %macro test2 ;
     %let original= translate_this_var ;
     %let replaceWithThis= %str( ) ;
     %let findThis= _ ;
     %let tranwrded= %sysfunc(tranwrd(&original, &findThis, &replaceWithThis)) ;
     %put Original: &original ***** TRANWRDed: &tranwrded ;
    %mend ;
    %test2

Answer 2

宏语言中没有引号。 使用的唯一引号字符是 & 、 % 等，以指示文本应解释为宏“运算符”。 空白由 %str( ) 表示，如上面 Carolina 的帖子中所示。

Answer 3

您可以使用 perl reg ex 代替，例如：

%put ***%sysfunc(prxchange(s/x/ /, -1, abxcdxxf))***;
/* on log
***ab cd  f***
*/