从 Perl 子例程返回整个数组是否效率低下？

Question

我经常在 Perl 中使用一个子例程，用一些信息填充数组。 因为我也习惯在 C++ 中进行黑客攻击，所以我发现自己经常在 Perl 中这样做，使用引用：

my @array;
getInfo(\@array);

sub getInfo {
   my ($arrayRef) = @_;
   push @$arrayRef, "obama";
   # ...
}

而不是更简单的版本：

my @array = getInfo();

sub getInfo {
   my @array;
   push @array, "obama";
   # ...
   return @array;
}

当然，原因是我不想创建数组本地在子例程中，然后在返回时复制。

是对的吗？ 或者 Perl 是否会优化它？

Answer 1

如果我查看您的示例并思考您想要做什么，我习惯于以这种方式编写它：

sub getInfo {
  my @array;
  push @array, 'obama';
  # ...
  return \@array;
}

当我需要返回大量数据时，在我看来这是直接版本。 正如您在第一个代码片段中编写的那样，不需要在 sub 之外分配数组，因为 my 会为您做这件事。 无论如何，你不应该像Leon Timmermans那样过早优化建议。

Answer 2

回答最后的思考，不，Perl 并没有对此进行优化。 事实上，它不能，因为返回数组和返回标量是根本不同的。

如果您正在处理大量数据或者性能是主要考虑因素，那么您的 C 习惯将对您很有帮助 - 传递和返回对数据结构的引用而不是结构本身，这样就不需要复制它们。 但是，正如 Leon Timmermans 指出的那样，绝大多数时候，您处理的数据量较小，而且性能并不是什么大问题，因此请以最易读的方式进行操作。

Answer 3

这是我通常返回数组的方式。

sub getInfo {
  my @array;
  push @array, 'foo';
  # ...
  return @array if wantarray;
  return \@array;
}

这样，它将在标量或列表上下文中按照您想要的方式工作。

my $array = getInfo;
my @array = getInfo;

$array->[0] == $array[0];

# same length
@$array == @array;

除非您知道它是代码中速度较慢的部分，否则我不会尝试优化它。 即使那样，我也会使用基准测试来查看哪个子例程实际上更快。

Answer 4

有两个考虑。 显而易见的一个问题是您的阵列将有多大？ 如果它少于几十个元素，那么大小就不是一个因素（除非您对某些快速调用的函数进行微优化，但您必须首先进行一些内存分析来证明这一点）。

这是最简单的部分。 经常被忽视的第二个考虑因素是界面。 返回的数组将如何使用？ 这很重要，因为整个数组取消引用在 Perl 中有点糟糕。 例如：

for my $info (@{ getInfo($some, $args) }) {
    ...
}

那太丑了。 这好多了。

for my $info ( getInfo($some, $args) ) {
    ...
}

它还适用于映射和 grep。

my @info = grep { ... } getInfo($some, $args);

但是，如果您要挑选单个元素，则返回数组引用会很方便：

my $address = getInfo($some, $args)->[2];

这比：

my $address = (getInfo($some, $args))[2];

或者：

my @info = getInfo($some, $args);
my $address = $info[2];

但在这一点上，您应该质疑 @info 是否真正是列表或散列。

my $address = getInfo($some, $args)->{address};

您不应该做的是让 getInfo() 在标量上下文中返回一个数组引用，在列表上下文中返回一个数组。 这混淆了标量上下文作为数组长度的传统使用，这会让用户感到惊讶。

最后，我将插入我自己的模块 Method::Signatures，因为它提供了传递数组引用而不必使用数组引用语法的折衷方案。

use Method::Signatures;

method foo(\@args) {
    print "@args";      # @args is not a copy
    push @args, 42;   # this alters the caller array
}

my @nums = (1,2,3);
Class->foo(\@nums);   # prints 1 2 3
print "@nums";        # prints 1 2 3 42

这是通过 Data::Alias 的魔力来完成的。

Answer 5

如果您正在读取整个较大的文件并将其切片到数组中，则还有其他 3 个可能较大的性能改进：

1. 使用 sysread() 而不是 read() 关闭缓冲（手动警告
   关于混合）
2. 通过评估最后一个元素来预先扩展数组 -
   节省内存分配
3. 使用 Unpack() 快速拆分数据，如 uint16_t 图形通道数据

将数组引用传递给函数允许主程序处理简单的数组，而一次写入即忘记工作函数使用更复杂的“$ @”和箭头 ->[$II] 访问表单。 由于相当 C'ish，它可能会很快！

Answer 6

我对 Perl 一无所知，所以这是一个与语言无关的答案。

从某种意义上说，将数组从子例程复制到调用程序中效率很低。 效率低下的原因是使用了额外的内存以及将数据从一个地方复制到另一个地方所花费的时间。 另一方面，对于除最大数组之外的所有数组，您可能根本不在乎，并且可能出于优雅、粗鲁或任何其他原因而更愿意将数组复制出来。

有效的解决方案是子程序将数组的地址传递给调用程序。 正如我所说，我对 Perl 在这方面的默认行为一无所知。 但有些语言为程序员提供了选择哪种方法的选项。

Answer 7

首先返回一个数组引用怎么样？

sub getInfo {
  my $array_ref = [];
  push @$array_ref, 'foo';
  # ...
  return $array_ref;
}

my $a_ref = getInfo();
# or if you want the array expanded
my @array = @{getInfo()};

根据 dehmann 的评论进行编辑：

也可以在函数中使用普通数组并返回对其的引用。

sub getInfo {
  my @array;
  push @array, 'foo';
  # ...
  return \@array;
}      

Answer 8

传递引用效率更高，但差异并不像 C++ 中那么大。 参数值本身（这意味着：数组中的值）始终通过引用传递（尽管返回值被复制）。

问题是：这重要吗？ 大多数时候，事实并非如此。 如果您返回 5 个元素，请不要担心。 如果您要返回/传递 100,000 个元素，请使用引用。 仅当它是瓶颈时才对其进行优化。