如何知道 var 是什么类型？

Question

TypeInfo(Type) 返回有关指定类型的信息，有什么方法可以知道 var 的类型信息吗？

var
  S: string;
  Instance: IObjectType;
  Obj: TDBGrid;
  Info: PTypeInfo;
begin
  Info:= TypeInfo(S);
  Info:= TypeInfo(Instance);
  Info:= TypeInfo(Obj);
end

此代码返回：

[DCC Error] Unit1.pas(354): E2133 TYPEINFO 标准函数需要类型标识符

我知道非实例化的 var 只是一个指针地址。 在编译时，编译器会解析并进行类型安全检查。

在运行时，有没有办法只传递它的地址来更多地了解 var？

Answer 1

不。

首先，不存在“非实例化变量”这样的东西。 您只需在源文件中键入其名称和类型即可实例化它。

其次，通过在源代码中查看变量，您已经了解了有关该变量的所有信息。 一旦程序被编译，变量就不再存在。 在那之后，一切都只是碎片。

指针仅在编译时具有类型。 在运行时，对该地址可以执行的所有操作都已确定。 正如您已经指出的那样，编译器会对此进行检查。 在运行时检查变量的类型仅在变量类型可能更改的语言中有用，例如在动态语言中。 Delphi 最接近的就是它的 Variant 类型。 变量的类型始终是Variant，但您可以在其中存储多种类型的值。 要了解它包含的内容，您可以使用 VarType 函数。

任何时候您想要使用 TypeInfo 来获取与变量关联的类型的类型信息时，您也可以直接命名您感兴趣的类型； 如果变量在作用域内，那么您可以找到它的声明并在对 TypeInfo 的调用中使用声明的类型。

如果您想将任意地址传递给函数并让该函数自行发现类型信息，那么您就不走运了。 您需要将 PTypeInfo 值作为附加参数传递。 这就是所有内置 Delphi 函数的作用。 例如，当您对指针变量调用 New 时，编译器会插入一个附加参数，该参数保存您要分配的类型的 PTypeInfo 值。 当您对动态数组调用 SetLength 时，编译器会插入数组类型的 PTypeInfo 值。

您给出的答案表明您正在寻找与您要求的不同的东西。 鉴于您的问题，我认为您正在寻找一个可以满足此代码的假设函数：

var
  S: string;
  Instance: IObjectType;
  Obj: TDBGrid;
  Info: PTypeInfo;
begin
  Info:= GetVariableTypeInfo(@S);
  Assert(Info = TypeInfo(string));

  Info:= GetVariableTypeInfo(@Instance);
  Assert(Info = TypeInfo(IObjectType));

  Info:= GetVariableTypeInfo(@Obj);
  Assert(Info = TypeInfo(TDBGrid));
end;

让我们使用 IsClass 和 IsObject 来自 JCL 的函数来构建该函数：

function GetVariableTypeInfo(pvar: Pointer): PTypeInfo;
begin
  if not Assigned(pvar) then
    Result := nil
  else if IsClass(PPointer(pvar)^) then
    Result := PClass(pvar).ClassInfo
  else if IsObject(PPointer(pvar)^) then
    Result := PObject(pvar).ClassInfo
  else
    raise EUnknownResult.Create;
end;

显然不会适用于上面的 S 或 Instance，但让我们看看 Obj 会发生什么：

Info := GetVariableTypeInfo(@Obj);

这应该会导致访问冲突。 Obj 没有值，因此 IsClass 和 IsObject 都将读取未指定的内存地址，可能不属于您的进程。 您要求一个使用变量地址作为输入的例程，但仅使用地址是不够的。

现在让我们仔细看看 IsClass 和 IsObject 的实际行为。 这些函数采用任意值并检查该值是否看起来它可能是给定类型的值，无论是对象（实例）还是类。 像这样使用它：

// This code will yield no assertion failures.
var
  p: Pointer;
  o: TObject;
  a: array of Integer;
begin
  p := TDBGrid;
  Assert(IsClass(p));

  p := TForm.Create(nil);
  Assert(IsObject(p));

  // So far, so good. Works just as expected.
  // Now things get interesting:

  Pointer(a) := p;
  Assert(IsObject(a));
  Pointer(a) := nil;
  // A dynamic array is an object? Hmm.

  o := nil;
  try
    IsObject(o);
    Assert(False);
  except
    on e: TObject do
      Assert(e is EAccessViolation);
  end;
  // The variable is clearly a TObject, but since it
  // doesn't hold a reference to an object, IsObject
  // can't check whether its class field looks like
  // a valid class reference.
end;

请注意，函数不会告诉您有关变量的任何信息，只会告诉您它们所保存的值。 那么，我不会真正考虑这些函数来回答如何获取有关变量的类型信息的问题。

此外，您说您对变量的了解只是它的地址。 您找到的函数不采用变量的地址。 它们获取变量的值。 这是一个演示：

var
  c: TClass;
begin
  c := TDBGrid;
  Assert(IsClass(c));
  Assert(not IsClass(@c)); // Address of variable
  Assert(IsObject(@c)); // Address of variable is an object?
end;

您可能会反对我通过将明显垃圾的内容传递给这些函数来滥用这些函数。 但我认为这是谈论这个话题的唯一方式。 如果您知道永远不会有垃圾值，那么您就不需要您所要求的函数，因为您已经足够了解您的程序，可以为变量使用真实类型。

总的来说，你问了错误的问题。 你不应该问如何确定变量的类型或内存中值的类型，你应该问你如何让自己陷入还不知道变量和数据的类型的境地< /强>。

Answer 2

使用泛型，现在可以在不指定类型的情况下获取类型信息。
某些用户表示以下代码无法正确编译。
从 Delphi 10 Seattle 版本 23.0.20618.2753 开始，它编译时没有错误，如下面的屏幕截图所示。

program TypeInfos;
{$APPTYPE CONSOLE}
{$R *.res}

uses
  System.SysUtils, System.TypInfo;

type
  TTypeInfo = class
    class procedure ShowTypeInfo<T>(const X: T);
  end;

{ TTypeInfo }

class procedure TTypeInfo.ShowTypeInfo<T>(const X: T);
var
  LTypeInfo: PTypeInfo;
begin
  LTypeInfo := TypeInfo(T);
  WriteLn(LTypeInfo.Name);
end;

var
  L: Exception;
  B: Boolean;
begin
                             // Console output
  TTypeInfo.ShowTypeInfo(L); // Exception
  TTypeInfo.ShowTypeInfo(B); // Boolean
end.

Answer 3

从来没听说过。 您可以获取类的已发布属性的 RTTI（运行时类型信息），但不能获取字符串和整数等“普通”变量。 这些信息根本不存在。

此外，在不传递类型的情况下传递 var 的唯一方法是使用泛型 TObject 参数、泛型类型（D2008，如 中）或作为无类型参数。 我想不出另一种可以编译的传递它的方法。