Indy 10 IdTCPClient 使用单独的线程读取数据？

Question

问题：我正在寻找的是在 Indy 10 中使用单独线程通过 IdTCPClient 接收数据的最典型或最佳实践方法。

背景： 下面的代码是我尝试执行的示例，为了清楚起见，删除了实际的数据处理部分。 线程的想法是接收所有数据（可变大小，带有声明消息其余长度的标头），然后解析它（这就是 HandleData 过程的作用）并根据命令触发事件处理程序。

TIdIOHandlerSocket 由主应用程序传递给线程，主应用程序还会在需要时将数据写入套接字。

TScktReceiveThread = class(TThread)
  private
    { Private declarations }
    procedure HandleData;
  protected
    procedure Execute; override;
  public
    FSocket: TIdIOHandlerSocket;
    constructor Create(CreateSuspended: boolean);
  end;


procedure TScktReceiveThread.Execute;
var
  FixedHeader: TBytes;
begin
  Assert(FSocket <> nil, 'You must assign the connected socket to the receiving thread');
  SetLength(FixedHeader, 2);
   while not Terminated do
    begin
      if not FSocket.Connected then
        Suspend
      else
        begin
          FSocket.CheckForDataOnSource(10);
          if not FSocket.InputBufferIsEmpty then
           begin
            FSocket.ReadBytes(FixedHeader, SizeOf(FixedHeader), false);
            // Removed the rest of the reading and parsing code for clarity
            Synchronize(HandleData);
           end;
        end;
    end;
end;

作为前缀，我使用了另一个处理 Indy 服务器组件的 StackOverflow 问题：“Delphi 2009，Indy 10，TIdTCPServer.OnExecute，如何抓取InputBuffer中的所有字节”以获得我所拥有的基础迄今为止。

谢谢你的帮助！

Answer 1

如果您想避免为每个客户端-服务器数据交换创建线程类所带来的开销，您可以创建一个移动线程类，如

http://delphidicas.blogspot.com/2008/08/anonymous-methods-when-should-they-be.html

几天前我遇到了同样的问题，我刚刚写了一个类 TMotileThreading，它具有静态函数，可以让我使用 D2009 的新匿名方法功能创建线程。 看起来像这样：

type
  TExecuteFunc = reference to procedure;

  TMotileThreading = class
  public
    class procedure Execute (Func : TExecuteFunc);
    class procedure ExecuteThenCall (Func : TExecuteFunc; ThenFunc : TExecuteFunc);
  end;

第二个过程允许我像您的情况一样执行客户端-服务器通信，并在数据到达时执行一些操作。 匿名方法的好处是您可以使用调用上下文的局部变量。 因此，通信看起来像这样：

var
  NewData  : String;
begin
  TMotileThreading.ExecuteThenCall (
    procedure
    begin
      NewData := IdTCPClient.IOHandler.Readln;
    end,
    procedure
    begin
      GUIUpdate (NewData);
    end);
 end;

Execute 和 ExecuteThenCall 方法只是创建一个工作线程，将 FreeOnTerminate 设置为 true 以简化内存管理，并执行工作线程的 Execute 和 OnTerminate 过程中提供的函数。

希望有帮助。

编辑（根据要求，TMotileThreading 类的完整实现）

type
  TExecuteFunc = reference to procedure;

  TMotileThreading = class
  protected
    constructor Create;
  public
    class procedure Execute (Func : TExecuteFunc);
    class procedure ExecuteAndCall (Func : TExecuteFunc; OnTerminateFunc : TExecuteFunc;
                                SyncTerminateFunc : Boolean = False);
  end;

  TMotile = class (TThread)
  private
    ExecFunc             : TExecuteFunc;
    TerminateHandler     : TExecuteFunc;
    SyncTerminateHandler : Boolean;
  public
    constructor Create (Func : TExecuteFunc); overload;
    constructor Create (Func : TExecuteFunc; OnTerminateFunc : TExecuteFunc;
                        SyncTerminateFunc : Boolean); overload;
    procedure OnTerminateHandler (Sender : TObject);
    procedure Execute; override;
  end;

implementation

constructor TMotileThreading.Create;
begin
  Assert (False, 'Class TMotileThreading shouldn''t be used as an instance');
end;

class procedure TMotileThreading.Execute (Func : TExecuteFunc);
begin
  TMotile.Create (Func);
end;

class procedure TMotileThreading.ExecuteAndCall (Func : TExecuteFunc;
                                                 OnTerminateFunc : TExecuteFunc;
                                                 SyncTerminateFunc : Boolean = False);
begin
  TMotile.Create (Func, OnTerminateFunc, SyncTerminateFunc);
end;

constructor TMotile.Create (Func : TExecuteFunc);
begin
  inherited Create (True);
  ExecFunc := Func;
  TerminateHandler := nil;
  FreeOnTerminate := True;
  Resume;
end;

constructor TMotile.Create (Func : TExecuteFunc; OnTerminateFunc : TExecuteFunc;
                            SyncTerminateFunc : Boolean);
begin
  inherited Create (True);
  ExecFunc := Func;
  TerminateHandler := OnTerminateFunc;
  SyncTerminateHandler := SyncTerminateFunc;
  OnTerminate := OnTerminateHandler;
  FreeOnTerminate := True;
  Resume;
end;

procedure TMotile.Execute;
begin
  ExecFunc;
end;

procedure TMotile.OnTerminateHandler (Sender : TObject);
begin
  if Assigned (TerminateHandler) then
    if SyncTerminateHandler then
      Synchronize (procedure
                   begin
                     TerminateHandler;
                   end)
    else
      TerminateHandler;
end;

Answer 2

你走在正确的轨道上。 Indy 就是打算这样使用的。 它使用阻塞套接字，因此ReadBytes调用在读取您所请求的内容之前不会返回。 与非阻塞套接字相比，在非阻塞套接字中，调用可能会提前返回，因此您可以异步轮询或收到通知来确定请求何时已被填充。

Indy 的设计预期套接字对象拥有自己的线程（或纤程）。 Indy 附带了 TIdAntifreeze，适合那些想要将套接字组件拖放到其表单和数据模块上并从主 GUI 线程使用 Indy 组件的人们，但如果您可以避免的话，这通常不是一个好主意它。

由于如果没有分配FSocket，您的线程就无法工作，因此我建议您只需在类的构造函数中接收该值即可。 如果未分配，则在构造函数中断言。 此外，创建非挂起线程是一个错误，那么为什么还要给出这个选项呢？ （如果创建的线程没有挂起，那么它将开始运行，检查FSocket是否已分配，并失败，因为创建线程尚未分配该字段。）