如何为自定义 Flex 组件定义默认样式？

Question

我正在创建一个新的 Flex 组件 (Flex 3)。 我希望它有一个默认样式。 我的 .cs 文件是否有命名约定或其他内容以使其成为默认样式？ 我错过了什么吗？

Answer 1

Christian 关于应用 CSS 的说法是正确的，但如果您计划在跨项目的库中使用该组件，您将需要为该库编写一个默认的 css 文件。 操作方法如下：

1. 创建一个名为“defaults.css”的 css 文件（只有此文件名才有效！）并将其放在库的“src”文件夹下的顶层。 如果 css 文件引用任何资源，它们也必须位于“src”下。
2. （重要！）转到库项目的“属性”> Flex 库构建路径 > 资产并包括 css 文件和所有资产。

这就是 Adob​​e 团队设置所有默认样式的方式，现在您也可以这样做。 刚刚发现这个-巨大

Answer 2

一般有两种方式。 一种方法是直接引用类名 - 例如，如果您在 ActionScript 中创建了一个新的组件类 MyComponent，或者通过创建一个扩展另一个名为 MyComponent< 的 UIComponent 的 MXML 组件来间接引用/code>，在这两种情况下，组件都会选择外部样式表中声明的样式，前提是样式表已导入到您的应用程序中（例如，通过 Style source）：

MyComponent
{
     backgroundColor: #FFFFFF;
}

另一种方法是设置UIComponent 的 styleName 属性（作为字符串）：

public class MyComponent
{
     // ...

     this.styleName = "myStyle";

     // ...
}

...并像这样在 CSS 文件中定义样式（注意点符号）：

.myStyle
{
     backgroundColor: #FFFFFF;
}

有意义吗？

Answer 3

除了 Christian Nunciato 建议之外，另一个选择是为 Flex 组件的样式定义静态初始值设定项。 这允许您设置默认样式，而无需开发人员包含 CSS 文件。

private static function initializeStyles():void
{
    var styles:CSSStyleDeclaration = StyleManager.getStyleDeclaration("ExampleComponent");
    if(!styles)
    {
        styles = new CSSStyleDeclaration();
    }

    styles.defaultFactory = function():void
    {
        this.exampleNumericStyle = 4;
        this.exampleStringStyle = "word to your mother";
        this.exampleClassStyle = DefaultItemRenderer //make sure to import it!
    }

    StyleManager.setStyleDeclaration("ExampleComponent", styles, false);
}
//call the static function immediately after the declaration
initializeStyles();

Answer 4

对 joshtynjala 建议的改进：

public class CustomComponent extends UIComponent {
    private static var classConstructed:Boolean = classConstruct();

    private static function classConstruct():Boolean {
        if (!StyleManager.getStyleDeclaration("CustomComponent")) {
            var cssStyle:CSSStyleDeclaration = new CSSStyleDeclaration();
            cssStyle.defaultFactory = function():void {
                this.fontFamily = "Tahoma";
                this.backgroundColor = 0xFF0000;
                this.backgroundAlpha = 0.2;
            }
            StyleManager.setStyleDeclaration("CustomComponent", cssStyle, true);
        }
        return true;
    }
}

我在某处的文档中读过此内容； classContruct 方法会被自动调用。

Answer 5

您可能希望使用 标签或类似标签覆盖默认样式。 如果是这种情况，则在检查 classConstructed 时 CSSStyleDeclaration 可能已经存在。 这是一个解决方案：

private static var classConstructed:Boolean = getClassConstructed ();
private static function getClassConstructed ():Boolean {
  var defaultCSSStyles:Object = {
    backgroundColorGood: 0x87E224, 
    backgroundColorBad: 0xFF4B4B, 
    backgroundColorInactive: 0xCCCCCC, 
    borderColorGood: 0x333333, 
    borderColorBad: 0x333333, 
    borderColorInactive: 0x666666, 
    borderWeightGood: 2, 
    borderWeightBad: 2, 
    borderWeightInactive: 2
  };
  var cssStyleDeclaration:CSSStyleDeclaration = FlexGlobals.topLevelApplication.styleManager.getStyleDeclaration ("StatusIndicator");
  if (!cssStyleDeclaration) {
    cssStyleDeclaration = new CSSStyleDeclaration ("StatusIndicator", FlexGlobals.topLevelApplication.styleManager, true);
  }
  for (var i:String in defaultCSSStyles) {
    if (cssStyleDeclaration.getStyle (i) == undefined) {
      cssStyleDeclaration.setStyle (i, defaultCSSStyles [i]);
    }
  }
  return (true);
}

Answer 6

要创建默认样式，您还可以在类中拥有一个属性并覆盖 UIComponent 中的 styleChanged() 函数，例如仅在组件宽度的一半上绘制背景颜色：

// this metadata helps flex builder to give you auto complete when writing
// css for your CustomComponent
[Style(name="customBackgroundColor", type="uint", format="color", inherit="no")]

public class CustomComponent extends UIComponent {

    private static const DEFAULT_CUSTOM_COLOR:uint = 0x00FF00;

    private var customBackgroundColor:uint = DEFAULT_CUSTOM_COLOR;

    override public function styleChanged(styleProp:String):void
    {
        super.styleChanged(styleProp);

        var allStyles:Boolean = (!styleProp || styleProp == "styleName");

        if(allStyles || styleProp == "customBackgroundColor")
        {
            if(getStyle("customBackgroundColor") is uint);
            {
                customBackgroundColor = getStyle("customBackgroundColor");
            }
            else
            {
                customBackgroundColor = DEFAULT_CUSTOM_COLOR;
            }
            invalidateDisplayList();
        }

        // carry on setting any other properties you might like
        // check out UIComponent.styleChanged() for more examples
    }

    override protected function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void
    {
        super.updateDisplayList(unscaledWidth, unscaledHeight);

        graphics.clear();
        graphics.beginFill(customBackgroundColor);
        graphics.drawRect(0,0,unscaledWidth/2,unscaledHeight);
    }
}

您还可以为 customBackgroundColor 创建一个 setter ，该 setter 称为invalidateDisplayList()，因此您还可以通过编程方式以及通过 css 设置 customBackgroundColor 属性。