Erlang 和运行时记录限制

Question

我正在开发一个 Erlang 系统，并且反复出现问题，因为记录是编译时预处理器宏（几乎），并且它们无法在运行时进行操作...... 基本上，我正在使用属性模式，其中属性在运行时添加到前端（AS3）上的对象。 理想情况下，我会在 Erlang 端用一个列表来反映这一点，因为它是一种基本数据类型，但是使用 QCL 中的记录[查询 ETS 表]是不可能的，因为要使用它们，我必须具体说明我要使用哪个记录属性想要查询...我在大型表中至少有 15 列，因此将它们全部列在一个巨大的 switch 语句（case X of）中简直是丑陋的。

有谁有任何想法如何优雅地解决这个问题？ 也许有一些内置函数用于创建具有适当签名的元组以用于模式匹配（对于 QLC）？

谢谢

Answer 1

听起来您希望能够执行类似 get_record_field(Field, SomeRecord) 的操作，其中 Field 在运行时由用户界面代码确定。

你是对的，你不能在标准 erlang 中执行此操作，因为记录和 record_info 函数在编译时扩展和消除。

我使用过或研究过几种解决方案。 我的解决方案如下：（该示例提供对 inet_dns.hrl 中的 #dns_rec 和 #dns_rr 记录的运行时访问）

%% Retrieves the value stored in the record Rec in field Field.
info(Field, Rec) ->
    Fields = fields(Rec),
    info(Field, Fields, tl(tuple_to_list(Rec))).

info(_Field, _Fields, []) -> erlang:error(bad_record);
info(_Field, [], _Rec) -> erlang:error(bad_field);
info(Field, [Field | _], [Val | _]) -> Val;
info(Field, [_Other | Fields], [_Val | Values]) -> info(Field, Fields, Values).

%% The fields function provides the list of field positions
%% for all the kinds of record you want to be able to query
%% at runtime. You'll need to modify this to use your own records.
fields(#dns_rec{}) -> fields(dns_rec);
fields(dns_rec) -> record_info(fields, dns_rec);
fields(#dns_rr{}) -> fields(dns_rr);
fields(dns_rr) -> record_info(fields, dns_rr).

%% Turns a record into a proplist suitable for use with the proplists module.
to_proplist(R) ->
    Keys = fields(R),
    Values = tl(tuple_to_list(R)),
    lists:zip(Keys,Values).

此版本可以在此处进行编译： rec_test.erl

---

您还可以将此动态字段查找扩展到动态生成匹配规范与 ets:select/2 或 mnesia:select/2 一起使用，如下所示：

%% Generates a matchspec that does something like this
%% QLC psuedocode: [ V || #RecordKind{MatchField=V} <- mnesia:table(RecordKind) ]
match(MatchField, RecordKind) ->
    MatchTuple = match_tuple(MatchField, RecordKind),
    {MatchTuple, [], ['$1']}.

%% Generates a matchspec that does something like this
%% QLC psuedocode: [ T || T <- mnesia:table(RecordKind),
%%                        T#RecordKind.Field =:= MatchValue]
match(MatchField, MatchValue, RecordKind) ->
    MatchTuple = match_tuple(MatchField, RecordKind),
    {MatchTuple, [{'=:=', '$1', MatchValue}], ['$']}.

%% Generates a matchspec that does something like this
%% QLC psuedocode: [ T#RecordKind.ReturnField
%%                   || T <- mnesia:table(RecordKind),
%%                        T#RecordKind.MatchField =:= MatchValue]
match(MatchField, MatchValue, RecordKind, ReturnField) 
  when MatchField =/= ReturnField ->
    MatchTuple = list_to_tuple([RecordKind
           | [if F =:= MatchField -> '$1'; F =:= ReturnField -> '$2'; true -> '_' end
              || F <- fields(RecordKind)]]),
    {MatchTuple, [{'=:=', '$1', MatchValue}], ['$2']}.


match_tuple(MatchField, RecordKind) ->
    list_to_tuple([RecordKind
           | [if F =:= MatchField -> '$1'; true -> '_' end
              || F <- fields(RecordKind)]]).

---

Ulf Wiger 还编写了一个 parse_transform，Exprecs，或多或少会自动为您完成此操作。 我从未尝试过，但 Ulf 的代码通常非常好。

---

Answer 2

我通过使用解析转换工具读取 .hrl 文件并生成辅助函数来解决这个问题（正在开发中）。

我在 教程 上编写了一个陷阱退出。

我们一直使用它来生成比赛规范。 美妙之处在于您在开发时不需要了解有关记录当前状态的任何信息。

然而，一旦投入生产，事情就会发生变化！ 如果您的记录是表的基础（而不是表中字段的定义），则更改基础记录会更加困难（温和地说！）。

Answer 3

我不确定我是否完全理解您的问题，但我已从记录移至 proplists 在大多数情况下。 它们更加灵活，但速度也慢得多。 使用 (d)ets 我通常使用一些记录字段进行粗略选择，然后检查其余记录上的 proplist 进行详细选择。