如何打印 Perl 数组中的唯一元素？

Question

我在 while 语句期间将元素推入数组。 每个元素都是老师的名字。 当循环结束时，数组中最终会出现重复的教师姓名。 有时它们在阵列中并不紧邻，有时则紧邻。

在完成将值推入其中后，如何仅打印该数组中的唯一值？ 每次我想打印一个元素时，不必解析整个数组。

将所有内容推入数组后的代码如下：

$faculty_len = @faculty;
$i=0;
while ($i != $faculty_len)
{
        printf $fh '"'.$faculty[$i].'"';
        $i++;
}   

Answer 1

use List::MoreUtils qw/ uniq /;
my @unique = uniq @faculty;
foreach ( @unique ) {
    print $_, "\n";
}

Answer 2

最好的选择是使用（基本上）内置工具，例如 uniq（如 innaM 所描述）。

如果您没有能力使用 uniq 并且想要保留顺序，您可以使用 grep 来模拟它。

my %seen;
my @unique = grep { ! $seen{$_}++ } @faculty;
# printing, etc.

这首先为您提供一个散列，其中每个键都是每个条目。 然后，迭代每个元素，计算它们的数量，并添加第一个元素。 （更新了 brian d foy 的评论）

Answer 3

我建议将其放入哈希中。
像这样：

my %faculty_hash = ();
foreach my $facs (@faculty) {
  $faculty_hash{$facs} = 1;
}
my @faculty_unique = keys(%faculty_hash);

Answer 4

@array1 = ("abc", "def", "abc", "def", "abc", "def", "abc", "def", "xyz");

@array1 = grep { ! $seen{ $_ }++ } @array1;

print "@array1\n"; 

Answer 5

perldoc 中有多种解决方案回答了这个问题。 只需在命令行输入：

perldoc -q duplicate

Answer 6

请注意：某些包含哈希的答案将更改数组的顺序。 哈希没有任何顺序，因此获取键或值将生成一个具有未定义顺序的列表。

这不适用于 grep { ! $seen{$_}++ } @faculty

Answer 7

这是一个单行命令，用于按其出现的顺序打印唯一的行。

perl -ne '$seen{$_}++ || print $_' fileWithDuplicateValues

Answer 8

我刚刚找到了陈腐的 3 班轮，享受吧

my %uniq; 
undef @uniq(@non_uniq_array); 
my @uniq_array = keys %uniq; 

Answer 9

这是另一种方法，仅当您不关心顺序时有用：

my %hash;
@hash{@faculty}=1;
my @unique=keys %hash;

如果您想避免声明新变量，则可以使用某种未充分记录的全局变量 %_

@_{@faculty}=1;
my @unique=keys %_;

Answer 10

如果您需要以任何方式处理教师列表，则将数组上的映射转换为用于键合并的哈希值，然后对键进行排序是另一种好方法：

my @deduped = sort keys %{{ map { /.*/? ($_,1):() } @faculty }};
print join("\n", @deduped)."\n";

通过更改 /.*/ 正则表达式用于相应地选择或解析和捕获，并且您可以通过使 ($_,1):() 任意复杂来每次传递输出一个或多个变异的、非唯一的键。

如果您需要使用替换正则表达式修改正在运行的数据，例如从名称中删除点 (s/\.//g)，那么根据上述模式的替换将改变由于 $_ 别名而导致的原始 @faculty 数组。 您可以通过制作 @faculty 数组的匿名副本来绕过 $_ 别名（请参阅所谓的 "baby cart" 运算符)：

my @deduped = sort keys %{{ map {/.*/? do{s/\.//g; ($_,1)}:()} @{[ @faculty ]} }};
print join("\n", @deduped)."\n";
print "Unmolested array:\n".join("\n", @faculty)."\n";

在最新版本的 Perl 中，您可以传递 key hashref，您可以使用非破坏性替换：

my @deduped = sort keys { map { /.*/? (s/\.//gr,1):() } @faculty };

否则，其他地方的 grep 或 $seen[$_]++ 解决方案可能更好。