如何在污点模式下使用 File::Find::Rule？

Question

我正在尝试使用类似以下内容来获取给定目录中的子目录列表：

#!/usr/bin/perl -wT
use strict;
use warnings;

use File::Find::Rule;
use Data::Dumper;

my @subdirs = File::Find::Rule->maxdepth(1)->directory->relative->in('mydir');

print Dumper(@subdirs);

但是，运行此命令会得到结果：

使用 -T 开关运行时 chdir 中的不安全依赖

我了解 File::Find 有处理污点模式的选项，但我似乎无法在 File::Find::Rule。 是否可以做到以上几点？ 我应该使用替代方法来列出子目录吗？ 我是否完全误解了一些我真正应该理解的关于污点模式的明显内容？

Answer 1

（编辑！）好吧，逻辑表明添加以下

->extras( {untaint => 1, untaint_pattern => $untaint_pattern, untaint_skip => 1} )

内容会起作用：这使您可以通过将参数直接传递给该模块的 find( ) 函数。 顺便说一句，File::Find 提到应该使用 qr// 运算符设置 $untaint_pattern。 例如，默认值是

$untaint_pattern = qr|^([-+@\w./]+)$|

但是，这是行不通的！ 事实上，您的问题是 File::Find::Rule 中的一个已知错误。 （例如，以下是 CPAN 和 Debian bug 报告。）如果您想要 bug 修复，那么这些错误报告有补丁。

如果您处于受限环境中，您可以做的一件事就是在代码中自己实现补丁。 例如，如果您想将所有内容保留在一个文件中，您可以在 use File::Find::Rule 之后添加下面的大代码块。 请注意，这是一个非常快速的修复，并且可能不是最佳的。 如果它不适合您（例如，因为您的文件名中有空格），请更改使用的模式 qr|^([-+@\w./]+)$| 。

最后请注意，如果您希望代码组织得更好一点，您可能需要将其转储到一个单独的包中，可能称为 MyFileFindRuleFix 或其他东西，您总是在 File:: 之后使用。 Find::Rule 本身。

package File::Find::Rule;
no warnings qw(redefine);
sub in {
    my $self = _force_object shift;

    my @found;
    my $fragment = $self->_compile( $self->{subs} );
    my @subs = @{ $self->{subs} };

    warn "relative mode handed multiple paths - that's a bit silly\n"
      if $self->{relative} && @_ > 1;

    my $topdir;
    my $code = 'sub {
        (my $path = $File::Find::name)  =~ s#^(?:\./+)+##;
        $path = "." if ($path eq ""); # See Debian bug #329377
        my @args = ($_, $File::Find::dir, $path);
        my $maxdepth = $self->{maxdepth};
        my $mindepth = $self->{mindepth};
        my $relative = $self->{relative};

        # figure out the relative path and depth
        my $relpath = $File::Find::name;
        $relpath =~ s{^\Q$topdir\E/?}{};
        my $depth = scalar File::Spec->splitdir($relpath);
        #print "name: \'$File::Find::name\' ";
        #print "relpath: \'$relpath\' depth: $depth relative: $relative\n";

        defined $maxdepth && $depth >= $maxdepth
           and $File::Find::prune = 1;

        defined $mindepth && $depth < $mindepth
           and return;

        #print "Testing \'$_\'\n";

        my $discarded;
        return unless ' . $fragment . ';
        return if $discarded;
        if ($relative) {
            push @found, $relpath if $relpath ne "";
        }
        else {
            push @found, $path;
        }
    }';

    #use Data::Dumper;
    #print Dumper \@subs;
    #warn "Compiled sub: '$code'\n";

    my $sub = eval "$code" or die "compile error '$code' $@";
    my $cwd = getcwd;
    # Untaint it
    if ( $cwd =~ qr|^([-+@\w./]+)$| ) {
        $cwd = $1;
    } else {
        die "Couldn't untaint \$cwd: [$cwd]";
    }
    for my $path (@_) {
        # $topdir is used for relative and maxdepth
        $topdir = $path;
        # slice off the trailing slash if there is one (the
        # maxdepth/mindepth code is fussy)
        $topdir =~ s{/?$}{}
          unless $topdir eq '/';
        $self->_call_find( { %{ $self->{extras} }, wanted => $sub }, $path );
    }
    chdir $cwd;

    return @found;
}
use warnings;
package main;