如何在 Perl 中对实例方法进行猴子修补？

Question

我正在尝试对 LWP::UserAgent 实例进行猴子修补（duck-punch :-），如下所示：

sub _user_agent_get_basic_credentials_patch {
  return ($username, $password);
}

my $agent = LWP::UserAgent->new();
$agent->get_basic_credentials = _user_agent_get_basic_credentials_patch;

这不是正确的语法 - 它会产生：

无法修改非左值子例程 调用 [module] 行 [lineno]。

我记得（来自 Programming Perl），调度查找是基于受祝福的包动态执行的（ref($agent)，我相信），所以我不确定实例猴子修补如何在不影响受祝福的包的情况下工作。

我知道我可以对 UserAgent 进行子类化，但我更喜欢更简洁的猴子修补方法。 同意成年人，你有什么。 ;-)

Answer 1

正如 Fayland Lam 的回答，正确的语法是：

    local *LWP::UserAgent::get_basic_credentials = sub {
        return ( $username, $password );
    };

但这是修补（动态范围）整个类，而不是只是实例。 就你的情况而言，你可能可以逃脱惩罚。

如果您确实只想影响实例，请使用您描述的子类化。 这可以“即时”完成，如下所示：

{
   package My::LWP::UserAgent;
   our @ISA = qw/LWP::UserAgent/;
   sub get_basic_credentials {
      return ( $username, $password );
   };

   # ... and rebless $agent into current package
   $agent = bless $agent;
}

Answer 2

如果动态范围（使用 local）不令人满意，您可以自动化自定义包重新祝福技术：

MONKEY_PATCH_INSTANCE:
{
  my $counter = 1; # could use a state var in perl 5.10

  sub monkey_patch_instance
  {
    my($instance, $method, $code) = @_;
    my $package = ref($instance) . '::MonkeyPatch' . $counter++;
    no strict 'refs';
    @{$package . '::ISA'} = (ref($instance));
    *{$package . '::' . $method} = $code;
    bless $_[0], $package; # sneaky re-bless of aliased argument
  }
}

示例用法：

package Dog;
sub new { bless {}, shift }
sub speak { print "woof!\n" }

...

package main;

my $dog1 = Dog->new;
my $dog2 = Dog->new;

monkey_patch_instance($dog2, speak => sub { print "yap!\n" });

$dog1->speak; # woof!
$dog2->speak; # yap!

Answer 3

本着 Perl 的“让困难的事情成为可能”的精神，这里有一个示例，说明如何在不破坏继承的情况下进行单实例猴子修补。

我不建议您在任何其他人必须支持、调试或依赖的代码中实际执行此操作（就像您所说的，同意的成年人）：

#!/usr/bin/perl

use strict;
use warnings;
{

    package Monkey;

    sub new { return bless {}, shift }
    sub bar { return 'you called ' . __PACKAGE__ . '::bar' }
}

use Scalar::Util qw(refaddr);

my $f = Monkey->new;
my $g = Monkey->new;
my $h = Monkey->new;

print $f->bar, "\n";    # prints "you called Monkey::bar"

monkey_patch( $f, 'bar', sub { "you, sir, are an ape" } );
monkey_patch( $g, 'bar', sub { "you, also, are an ape" } );

print $f->bar, "\n";    # prints "you, sir, are an ape"
print $g->bar, "\n";    # prints "you, also, are an ape"
print $h->bar, "\n";    # prints "you called Monkey::bar"

my %originals;
my %monkeys;

sub monkey_patch {
    my ( $obj, $method, $new ) = @_;
    my $package = ref($obj);
    $originals{$method} ||= $obj->can($method) or die "no method $method in $package";
    no strict 'refs';
    no warnings 'redefine';
    $monkeys{ refaddr($obj) }->{$method} = $new;
    *{ $package . '::' . $method } = sub {
        if ( my $monkey_patch = $monkeys{ refaddr( $_[0] ) }->{$method} ) {
            return $monkey_patch->(@_);
        } else {
            return $originals{$method}->(@_);
        }
    };
}

Answer 4

sub _user_agent_get_basic_credentials_patch {
  return ($username, $password);
}

my $agent = LWP::UserAgent->new();
$agent->get_basic_credentials = _user_agent_get_basic_credentials_patch;

这里你没有 1 个问题，而是 2 个问题，因为这就是你正在做的事情：

( $agent->get_basic_credentials() ) = _user_agent_get_basic_credentials_patch(); 

在双方的情况下，你都在调用 subs 而不是简单地引用它们。

assign the result of 
              '_user_agent_get_basic_credentials_patch' 
to the value that was returned from
              'get_basic_credentials';

等效逻辑：

{
   package FooBar; 
   sub foo(){ 
         return 5; 
   }
   1;
}
my $x =  bless( {}, "FooBar" ); 
sub baz(){ 
      return 1; 
}
$x->foo() = baz(); 
#   5 = 1;  

所以它抱怨也就不足为奇了。

出于同样的原因，您的答案中的“固定”代码也是错误的，还有另一个您可能没有意识到的问题：

 $agent->{get_basic_credentials} = _user_agent_get_basic_credentials_patch;

这是一个相当有缺陷的逻辑思维，它的工作原理就像您想象的那样。

它真正做的事情是：

1. Dereference $agent, which is a HashRef
2. Set the hash-key 'get_basic_credentials' to the result from _user_agent_get_basic_credentials_patch

您根本没有分配任何函数。

{
package FooBar; 
sub foo(){ 
     return 5; 
} 
1;
}
my $x =  bless( {}, "FooBar" ); 
sub baz(){ 
  return 1; 
}
$x->{foo} = baz(); 
#  $x is now  = ( bless{ foo => 1 }, "FooBar" ); 
#  $x->foo(); # still returns 5
#  $x->{foo}; # returns 1; 

当然，猴子修补是相当邪恶的，我自己还没有看到如何在类似的单个实例上重写方法。

但是，您可以做的是：

  {
     no strict 'refs'; 
     *{'LWP::UserAgent::get_basic_credentials'} = sub { 
         # code here 

     }; 
  }

这将全局替换 get_basic_credentials 代码部分的行为（我可能有点错，有人纠正我）

如果您确实需要在每个实例的基础上执行此操作，您可能可以做一些类继承并只构建一个派生类，和/或动态创建新包。

Answer 5

Perl 认为您正在尝试调用赋值左侧的子例程，这就是它抱怨的原因。 我认为你也许可以直接破解 Perl 符号表（使用 *LWP::UserAgent::get_basic_credentials 或其他东西），但我缺乏 Perl-fu 来正确地执行该咒语。

Answer 6

基于 John Siracusa 的回答......我发现我仍然想要对原始函数的引用。 所以我这样做了：

MONKEY_PATCH_INSTANCE:
{
  my $counter = 1; # could use a state var in perl 5.10

  sub monkey_patch_instance
  {
    my($instance, $method, $code) = @_;
    my $package = ref($instance) . '::MonkeyPatch' . $counter++;
    no strict 'refs';
    my $oldFunction = \&{ref($instance).'::'.$method};
    @{$package . '::ISA'} = (ref($instance));
    *{$package . '::' . $method} = sub {
        my ($self, @args) = @_;
        $code->($self, $oldFunction, @args);
    };
    bless $_[0], $package; # sneaky re-bless of aliased argument
  }
}

# let's say you have a database handle, $dbh
# but you want to add code before and after $dbh->prepare("SELECT 1");

monkey_patch_instance($dbh, prepare => sub {
    my ($self, $oldFunction, @args) = @_;

    print "Monkey patch (before)\n";
    my $output = $oldFunction->(($self, @args));
    print "Monkey patch (after)\n";

    return $output;
    });

它与原始答案相同，只是我传递了一些参数 $self 和 $oldFunction 。

这让我们像往常一样调用 $self 的 $oldFunction，但在它周围装饰额外的代码。

Answer 7

http://www.google.com/codesearch/p?hl=en#tgg5_3LXifM/Authen-Simple-HTTP-0.1/lib/Authen/Simple/HTTP.pm&q=get_basic_credentials

Answer 8

编辑：这是我为后代保留的解决方案的错误尝试。 查看已投票/已接受的答案。 :-)

啊，我刚刚意识到语法需要一点调整：

$agent->{get_basic_credentials} = _user_agent_get_basic_credentials_patch;

如果没有 {} 分隔符，它看起来像一个方法调用（这不是有效的左值）。

我仍然想知道实例方法如何通过此语法进行绑定/查找。 蒂亚！