文件 MD5 校验和

Question

在这个问题中提到了wcrypt2。

我需要的只是计算一个文件的MD5。 如果我可以计算它而不需要保存它那就完美了，因为它是流格式的下载文件。

我希望有最直接的方法来做到这一点。

谢谢！

Answer 1

这是 Indy 10 的工作代码：

function MD5File(const FileName: string): string;
var
  IdMD5: TIdHashMessageDigest5;
  FS: TFileStream;
begin
 IdMD5 := TIdHashMessageDigest5.Create;
 FS := TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite);
 try
   Result := IdMD5.HashStreamAsHex(FS)
 finally
   FS.Free;
   IdMD5.Free;
 end;
end;

问候，
奥斯卡R1

Answer 2

基于@dummzeuch 的回答，我写了这个函数：

function getMD5checksum(s: TStream): string;
 var
  md5: TIdHashMessageDigest5;
  hash : T4x4LongWordRecord;
 begin
  md5 := TIdHashMessageDigest5.Create;
  s.Seek(0,0);
  hash := md5.HashValue(s);
  result := IntToHex(Integer(hash[0]), 4) +
            IntToHex(Integer(hash[1]), 4) +
            IntToHex(Integer(hash[2]), 4) +
            IntToHex(Integer(hash[3]), 4);
 end;

Answer 3

Indy 附带了计算多种哈希值的函数，MD5 就是其中之一。 至少从 Delphi 2006 开始，Indy 就包含在所有版本的 Delphi 中，并且可以免费下载旧版本。

Answer 4

关于什么：

function GetFileMD5(const Stream: TStream): String; overload;
var MD5: TIdHashMessageDigest5;
begin
    MD5 := TIdHashMessageDigest5.Create;
    try
       Result := MD5.HashStreamAsHex(Stream);
    finally
       MD5.Free;
    end;
end;

function GetFileMD5(const Filename: String): String; overload;
var FileStream: TFileStream;
begin
    FileStream := TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite);
    try
      Result := GetFileMD5(FileStream);
    finally
      FileStream.Free;
    end;
end;

Answer 5

正如您提到的，您链接到的帖子讨论了wcrypt2，这是一个加密例程库，包括 MD5。 您链接到的帖子似乎也表明它可用于 Delphi 7，因为询问者包含标记为“Delphi 7”的输出。 您已将此问题标记为 delphi7，因此我假设您也正在使用该版本。 那么是什么阻止您使用 wcrypt2 呢？

该问题链接到 wcrypt2.pas 的副本，该文件中的版权日期似乎表明该单元在 Delphi 7 发布时可用。 检查您的安装； 你可能已经拥有了。 如果没有，那么该单位还说它是通过Project Jedi获得的，所以你可以尝试看看单位也有。

您所引用问题的答案包括示例 Delphi 代码以及 Delphi 附带的用于执行 MD5 的单元名称。 它们随 Delphi 2009 一起提供，因此您应该检查它们是否也适用于您的版本。

Answer 6

看一下 Delphi 中 MD5SUM 的这个实现。 它需要一个字符串作为输入，但我想你可以轻松地使其与流一起工作。

Answer 7

MessageDigest_5 也适用于此。

Answer 8

我在 Delphi 7 和 Indy 10.1.5 中使用以下函数

uses IdHashMessageDigest, idHash, Classes;  

...

function cc_MD5File(const p_fileName : string) : string;
//returns MD5 has for a file
var
  v_idmd5 : TIdHashMessageDigest5;
  v_fs : TFileStream;
  v_hash : T4x4LongWordRecord;
begin
  v_idmd5 := TIdHashMessageDigest5.Create;
  v_fs := TFileStream.Create(p_fileName, fmOpenRead OR fmShareDenyWrite) ;
  try
    v_hash := v_idmd5.HashValue(v_fs);
    result := v_idmd5.AsHex(v_hash);
  finally
    v_fs.Free;
    v_idmd5.Free;
  end;
end;

Answer 9

如果您使用 Overbyte http://www.overbyte.eu/frame_index.html 只需添加单位并使用文件名调用函数 FileMD5

uses OverbyteIcsMd5;
....
function GetMd5File:String; 
begin
 Result := FileMD5(FileName);
end;