执行嵌套 TRY / FINALLY 语句的最佳实践

Question

嗨，进行嵌套尝试的最佳方法是什么？ 最后在delphi中声明？

var cds1  : TClientDataSet;
    cds2  : TClientDataSet;
    cds3  : TClientDataSet;
    cds4  : TClientDataSet;
begin
  cds1      := TClientDataSet.Create(application );
  try
    cds2      := TClientDataSet.Create(application );
    try
      cds3      := TClientDataSet.Create(application );
      try
        cds4      := TClientDataSet.Create(application );
        try
        ///////////////////////////////////////////////////////////////////////
        ///      DO WHAT NEEDS TO BE DONE
        ///////////////////////////////////////////////////////////////////////
        finally
          cds4.free;
        end;

      finally
        cds3.free;
      end;
    finally
      cds2.free;
    end;
  finally
    cds1.free;
  end;
end;

你能建议一个更好的方法吗？

Answer 1

下面怎么样：

var cds1  : TClientDataSet;
    cds2  : TClientDataSet;
    cds3  : TClientDataSet;
    cds4  : TClientDataSet;
begin
  cds1      := Nil;
  cds2      := Nil;
  cds3      := Nil;
  cds4      := Nil;
  try
    cds1      := TClientDataSet.Create(nil);
    cds2      := TClientDataSet.Create(nil);
    cds3      := TClientDataSet.Create(nil);
    cds4      := TClientDataSet.Create(nil);
    ///////////////////////////////////////////////////////////////////////
    ///      DO WHAT NEEDS TO BE DONE
    ///////////////////////////////////////////////////////////////////////
  finally
    freeandnil(cds4);
    freeandnil(cds3);
    freeandnil(cds2);
    freeandnil(Cds1);
  end;
end;

这使其保持紧凑，并且仅尝试释放已创建的实例。 实际上没有必要执行嵌套，因为任何失败都会导致放弃到最后并执行您提供的示例中的所有清理。

就我个人而言，我尽量不要嵌套在同一个方法中......但 try/try/ except/finally 场景除外。 如果我发现自己需要嵌套，那么对我来说，这是考虑重构到另一个方法调用的好时机。

编辑由于mghie和utku。

编辑将对象创建更改为不引用应用程序，因为在本示例中没有必要。

Answer 2

我会使用这样的东西：

var
  Safe: IObjectSafe;
  cds1 : TClientDataSet;
  cds2 : TClientDataSet;
  cds3 : TClientDataSet;
  cds4 : TClientDataSet;
begin
  Safe := ObjectSafe;
  cds1 := Safe.Guard(TClientDataSet.Create(nil)) as TClientDataSet;
  cds2 := Safe.Guard(TClientDataSet.Create(nil)) as TClientDataSet;
  cds3 := Safe.Guard(TClientDataSet.Create(nil)) as TClientDataSet;
  cds4 := Safe.Guard(TClientDataSet.Create(nil)) as TClientDataSet;
  ///////////////////////////////////////////////////////////////////////
  ///      DO WHAT NEEDS TO BE DONE
  ///////////////////////////////////////////////////////////////////////

  // if Safe goes out of scope it will be freed and in turn free all guarded objects
end;

有关接口的实现，请参阅这篇文章，但您可以轻松地自己创建类似的东西。

编辑：

我刚刚注意到链接文章中的 Guard() 是一个过程。 在我自己的代码中，我重载了返回 TObject 的 Guard() 函数，上面的示例代码假设了类似的情况。 当然，使用泛型现在可以编写更好的代码...

编辑2：

如果您想知道为什么 try ...finally 在我的代码中被完全删除：在不引入可能性的情况下删除嵌套块是不可能的内存泄漏（当析构函数引发异常时）或访问冲突。 因此，最好使用辅助类，并让接口的引用计数完全接管。 即使某些析构函数引发异常，辅助类也可以释放它所保护的所有对象。

Answer 3

没有嵌套尝试的代码还有另一种变体...最后我才想到。 如果您不将构造函数的 AOwner 参数设置为 nil 来创建组件，那么您可以简单地利用 VCL 免费提供的生命周期管理：

var
  cds1: TClientDataSet;
  cds2: TClientDataSet;
  cds3: TClientDataSet;
  cds4: TClientDataSet;
begin
  cds1 := TClientDataSet.Create(nil);
  try
    // let cds1 own the other components so they need not be freed manually
    cds2 := TClientDataSet.Create(cds1);
    cds3 := TClientDataSet.Create(cds1);
    cds4 := TClientDataSet.Create(cds1);

    ///////////////////////////////////////////////////////////////////////
    ///      DO WHAT NEEDS TO BE DONE
    ///////////////////////////////////////////////////////////////////////

  finally
    cds1.Free;
  end;
end;

我是小代码的忠实拥护者（如果不是）太混乱了）。

Answer 4

如果你想走这条（IMO）丑陋的路线（将初始化设置为 nil 的组处理以了解是否需要释放），你至少必须保证你不会让析构函数之一中的异常阻止释放其余的你的对象。
就像是：

function SafeFreeAndNil(AnObject: TObject): Boolean;
begin
  try
    FreeAndNil(AnObject);
    Result :=  True;
  except
    Result := False;
  end;
end;

var cds1  : TClientDataSet;
    cds2  : TClientDataSet;
    IsOK1 : Boolean;
    IsOK2 : Boolean;
begin
  cds1      := Nil;
  cds2      := Nil; 
 try
    cds1      := TClientDataSet.Create(nil);
    cds2      := TClientDataSet.Create(nil);    
    ///////////////////////////////////////////////////////////////////////
    ///      DO WHAT NEEDS TO BE DONE
    ///////////////////////////////////////////////////////////////////////
  finally
    IsOk2 := SafeFreeAndNil(cds2);    // an error in freeing cds2 won't stop execution
    IsOK1 := SafeFreeAndNil(Cds1);
    if not(IsOk1 and IsOk2) then
      raise EWhatever....
  end;
end;

Answer 5

有一个关于构造函数中的异常的精彩视频 析构函数

它显示了一些很好的示例，例如：

var cds1  : TClientDataSet;
    cds2  : TClientDataSet;
begin
  cds1      := Nil;
  cds2      := Nil; 
 try
    cds1      := TClientDataSet.Create(nil);
    cds2      := TClientDataSet.Create(nil);    
    ///////////////////////////////////////////////////////////////////////
    ///      DO WHAT NEEDS TO BE DONE
    ///////////////////////////////////////////////////////////////////////
  finally
    freeandnil(cds2);    //// what has if there in an error in the destructor of cds2
    freeandnil(Cds1);
  end;
end;

如果 cds2 的析构函数中出现错误，会发生什么

Cds1 将不会被销毁

编辑

另一个很好的资源是：

Jim McKeeth 关于 代码范围 III 中的延迟异常处理，他谈到了在 finally 块中处理异常的问题。

Answer 6

@mghie：Delphi 有堆栈分配的对象：

type
  TMyObject = object
  private
    FSomeField: PInteger;
  public
    constructor Init;
    destructor Done; override;
  end;

constructor TMyObject.Init;
begin
  inherited Init;
  New(FSomeField);
end;

destructor TMyObject.Done;
begin
  Dispose(FSomeField);
  inherited Done;
end;

var
  MyObject: TMyObject;

begin
  MyObject.Init;
  /// ...
end;

不幸的是，如上面的示例所示：堆栈分配的对象不能防止内存泄漏。

因此，这仍然需要像这样调用析构函数：

var
  MyObject: TMyObject;

begin
  MyObject.Init;
  try
    /// ...
  finally
    MyObject.Done;
  end;
end;

好吧，我承认，这几乎是偏离主题的，但我认为在这种情况下可能会很有趣，因为提到了堆栈分配对象作为解决方案（它们不是如果没有自动析构函数调用）。