按下鼠标左键时如何更改鼠标光标？

Question

在 Delphi 2007 中，在鼠标移动事件中，我尝试使用以下命令更改鼠标光标：

procedure TFr_Board_Display.PaintBox_Proxy_BoardMouseMove(Sender: TObject;
  Shift: TShiftState; X, Y: Integer);
begin

  if left_mouse_button_down then begin  
    if some_condition then begin
      Cursor := crDrag;
    end
    else begin
      Cursor := crNoDrop;
    end;
  end
  else begin
    if some_other_condition then begin
      Cursor := crHandPoint;
    end
    else begin
      Cursor := crDefault;
    end;
  end;
end;

例如。 但是，当按下鼠标左键并移动鼠标时，光标不会更改为 crDrag 或 crNoDrop。 代码被执行（例如 Cursor := crDrag;），但光标没有改变。 当鼠标左键抬起时，我移动鼠标，光标变化没有问题。

（我最初尝试使用一些拖放事件和属性，但无法让所有内容按照我想要的方式工作。）

编辑：澄清所需的行为和格式化代码。

编辑：谢谢你，Gamecat，但我希望当鼠标左键按下时光标会发生变化，并且当鼠标移动时光标应该在 crDrag 和 crNoDrop 之间来回变化。

Answer 1

如果您在 OnMouseDown 中设置鼠标光标并在 OnMouseUp 中重置它，则一切正常：

procedure TForm4.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  Cursor := crCross;
end;

procedure TForm4.FormMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  Cursor := crDefault; // Or you can restore a saved cursor.
end;

如果您希望鼠标光标在鼠标移动时做出反应，请使用以下命令：

procedure TForm4.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
  if ssLeft in Shift then begin
    if X<100 then
      Screen.Cursor := crCross
    else
      Screen.Cursor := crHourGlass;
  end else
    Screen.Cursor := crDefault;  // Or you can restore a saved cursor.
end;

procedure TForm4.FormMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  Screen.Cursor := crDefault; // Or you can restore a saved cursor.
end;

需要 MouseUp，否则光标将不会变回如果它悬停在控件上方。

请务必在任何地方使用 Screen.Cursor。

Answer 2

有点偏离主题，但也许对你有用。

我创建了一个全局堆栈以允许嵌套游标更改。 它允许任何代码段将鼠标光标设置为他们想要的位置，而不必担心调用者或被调用者将其设置为什么。

例如：

procedure AskUserWhatToDo;
begin
  PushMouseCursor(crArrow);
  try
     if MessageDlg('Abort?', mtConfirmation, [mbYes, mbNo], 0) = mrYes then
        SysUtils.Abort;
  finally
     PopMouseCursor;
  end;
end;

procedure LongProcess;
begin
  PushMouseCursor(crHourglass);
  try
     //  do something
     if QuestionableState then
       AskUserWhatToDo;
     //  do something
  finally
    PopMouseCursor;
  end;
end;

两个过程都不​​必担心另一个过程需要什么状态或离开鼠标光标。

//===============================================================
//   in a universal utility module (mine is called CraftWindows.pas)

function SetMouseCursor(ACursor : TCursor) : TCursor;
begin
   Result := Screen.Cursor;
   Screen.Cursor := ACursor;
end;

var
   GlobalMouseCursorStack : TList = nil;

procedure PushMouseCursor(ACursor : TCursor);
begin
   if GlobalMouseCursorStack = nil then
       GlobalMouseCursorStack := TList.Create;

   GlobalMouseCursorStack.Add(Pointer(SetMouseCursor(ACursor)));
end;

procedure PopMouseCursor;
begin
   if (GlobalMouseCursorStack <> nil) and (GlobalMouseCursorStack.Count > 0) then
   begin
       SetMouseCursor(TCursor(GlobalMouseCursorStack.Last));
       GlobalMouseCursorStack.Delete(GlobalMouseCursorStack.Count - 1);
   end;
end;

...

finalization
  GlobalMouseCursorStack.Free;