我可以用 Perl 编写 DSL 吗？

Question

我们使用 Perl 进行 GUI 测试自动化。 它非常成功。 我们为 GUI 测试编写了一种非常轻量级的 DSL 语言。 DSL 与对象模型非常相似。

例如，我们在根有一个 Application 对象。 应用程序中的每个属性表都是一个 View 对象。 页面下的每个页面称为Page对象本身。 我们从 Perl 向 GUI 应用程序发送命令，GUI 解释该命令并很好地响应该命令。 要发送命令，我们执行以下操作：

socket_object->send_command("App.View2.Page2.Activate()")
socket_object->send_command("App.View1.Page3.OKBtn.Click()")

这不太可读。 相反，我想为应用程序、视图和页面编写 Perl DSL。 Perl 是否提供了某种 DSL 结构，我可以在其中执行以下操作？

App.View2.Page2.Activate();
App.View1.Page2.Click();

其中 App 应是 Application 类的实例。 我必须在运行时获取 View2 的对象。

这样的东西怎么用呢？

Answer 1

您几乎可以用 Perl 做任何事情。 但是你必须做一些奇怪的事情来让 Perl 使用非 Perl 的语法来执行。

• 要准确处理您所拥有的内容，您将必须使用许多高级技巧，而这些技巧从定义上来说是不那么可维护的。 你必须：

  • 重载连接运算符“.” （需要有祝福的参考）
  • 关闭限制或创建AUTOLOAD 子句以允许这些裸词 - 当然，您可以为您想要使用的所有单词编写子句（或使用 barewords 模块）。
  • 可以创建多个包，并使用多个 AUTOLOAD

• 另一种方法是 源过滤器，我可能会因为提及此功能而投反对票。 因此，我不会向寻求帮助的人推荐这种方法。 但它就在那里。 源过滤器（我已经完成了我的分享）只是您可能认为自己太聪明而不利于自己的领域之一。

  不过，如果您对 Perl 作为 DSL“宿主”语言感兴趣，那么 源过滤器并不是完全禁止的。 但是，将其限制为您想要执行的操作，Perl6::Attributes 可能会立即完成您需要的大部分功能。 它将采用 . 并将它们翻译为“->” Perl 会理解的。 但您仍然可以查看源过滤器以了解幕后发生了什么。

  我也不想离开这个主题而不建议使用 Damian Conway 的 Filter::Simple。

• 最简单的事情就是放弃“.” 运算符，而只是期望 Perl 外观的代码。

  App->View2->Page2->Activate();  
    应用程序->视图1->页面2->点击(); 
    

  App 可以是一个包或一个子包。 在当前包中定义或导入，返回一个对象，该对象被祝福到带有 View2 子包的包中（可能是 AUTOLOAD sub) 返回包的名称或被祝福到包中的引用，它理解 Page2，然后最后的返回将理解Activate或Click。 （如果需要，请参阅面向对象教程。）

Answer 2

我建议您停止尝试做奇怪的“DSL”事情，而只编写 Perl 类来处理您想要管理的对象。 我建议您考虑使用新的 Moose Perl 对象系统来实现此目的，尽管传统的 Perl OO 就可以了。 深入研究 OO 教程的 Perl 文档； 他们都是伟大的。

Answer 3

perl5 中的方法调用使用 -> 而不是 .，因此它看起来像 App->View2->Page2->Activate()< /code> 或 $App->View2->Page2->Active() 除非您做了一些非常有趣的事情（例如，源过滤器）。 假设没问题，您可以使用普通的 Perl OO 内容。

现在，您需要的下一部分是在运行时创建方法。 这实际上相当简单：

sub _new_view {
    my ($view, $view_num);

    # ...
    # ... (code to create $view object)
    # ...

    my $sym = "App::View$view_num";
    *$sym = sub { return $view }; # can also use Symbol package
}

或者，如果您只想在调用方法时创建方法，那么 AUTOLOAD 就是这样做的。 您还可以滥用自动加载来使所有方法调用成功（但要注意具有特殊含义的方法，例如 DESTROY）。

这将为您提供语法。 让您的对象生成一个字符串传递给 send_command 应该不会那么困难。

另外，我对它不太熟悉，但你可能想看看 Moose 。 它可能有更简单的方法来实现这一点。

Answer 4

DSL 源过滤器

这是另一种尝试。 Skiphoppy 有一点道理，但再看一遍，我注意到（到目前为止）你并没有问太多那么复杂的问题。 您只想获取每个命令并告诉远程服务器执行该操作。 perl 不需要理解这些命令，而是服务器。

因此，我删除了一些有关源过滤器的警告，并决定向您展示
如何写一个简单的。 再说一次，你所做的事情并不那么复杂，我下面的“过滤”非常简单。

package RemoteAppScript;
use Filter::Simple;    # The basis of many a sane source filter
use Smart::Comments;   # treat yourself and install this if you don't have 
                       # it... or just comment it out.

# Simple test sub
sub send_command { 
    my $cmd = shift;
    print qq(Command "$cmd" sent.\n);
    return;
}

# The list of commands
my @script_list;

# The interface to Filter::Simple's method of source filters.
FILTER { 
    # Save $_, because Filter::Simple doesn't like you reading more than once.
    my $mod = $_;

    # v-- Here a Smart::Comment.
    ### $mod

    # Allow for whole-line perl style comments in the script
    $mod =~ s/^\s*#.*$//m;

    # 1. Break the package up into commands by split
    # 2. Trim the strings, if needed
    # 3. lose the entries that are just blank strings.
    @script_list 
        = grep { length } 
          map  { s/^\s+|\s+$//g; $_ } 
          split /;/, $mod
        ;
    ### @script_list

    # Replace the whole script with a command to run the steps.
    $_ = __PACKAGE__ . '::run_script();';
    # PBP.
    return;
};

# Here is the sub that performs each action.
sub run_script { 
    ### @script_list
    foreach my $command ( @script_list ) {
        #send_command( $command );
        socket_object->send_command( $command );
    }
}

1;

您需要将其保存在 Perl 可以找到的 RemoteAppScript.pm 中。 （如果您需要知道在哪里，请尝试 perl -MData::Dumper -e 'print Dumper( \@INC ), "\n"' 。）

然后您可以创建一个包含以下内容的“perl”文件： this：

use RemoteAppScript;
App.View2.Page2.Activate();
App.View1.Page2.Click();

但是，

没有真正的原因表明您无法读取包含服务器命令的文件。 这会抛出 FILTER 调用。 你的脚本文件中会有

App.View2.Page2.Activate();
App.View1.Page2.Click();

这样的内容，你的 perl 文件看起来更像这样：

#!/bin/perl -w 

my $script = do { 
    local $/;
    <ARGV>;
};

$script =~ s/^\s*#.*$//m;

foreach my $command ( 
    grep { length() } map  { s/^\s+|\s+$//g; $_ } split /;/, $script 
) { 
    socket_object->send_command( $command );
}

并像这样调用它：

perl run_remote_script.pl remote_app_script.ras

Answer 5

http://search.cpan.org/dist/Devel-Declare/ 是现代的源过滤器的替代方案，它可以直接集成到 perl 解析器中，值得一看。

Answer 6

覆盖 '.' 或使用 -> 语法的替代方法可能是使用包语法 (::)，即创建 App::View2 和 App::View2 等包::Page2 当 View2 / Page 2 创建时，将 AUTOLOAD 子添加到委托给 App::View::Page 或 App::View 方法的包中，如下所示：

在您的 App/DSL.pm:

package App::DSL;
use strict; 
use warnings;
# use to avoid *{"App::View::$view::method"} = \&sub and friends
use Package::Stash;

sub new_view(%);
our %views;

# use App::DSL (View1 => {attr1 => 'foo', attr2 => 'bar'}); 
sub import {
    my $class = shift;
    my %new_views = @_ or die 'No view specified';

    foreach my $view (keys %new_views) {
            my $stash = Package::Stash->new("App::View::$view");
        # In our AUTOLOAD we create a closure over the right
        # App::View object and call the right method on it
        # for this example I just used _api_\L$method as the
        # internal method name (Activate => _api_activate)
        $stash->add_package_symbol('&AUTOLOAD' =>  
            sub {  
                our $AUTOLOAD;
                my ($method) = 
                   $AUTOLOAD =~ m{App::View::\Q$view\E::(.*)};
                my $api_method = "_api_\L$method";
                die "Invalid method $method on App::View::$view"
                   unless my $view_sub = App::View->can($api_method);
                my $view_obj = $views{$view}
                    or die "Invalid View $view";
                my $sub = sub {
                        $view_obj->$view_sub();
                };
                     # add the function to the package, so that AUTOLOAD
                     # won't need to be called for this method again
                $stash->add_package_symbol("\&$method" => $sub);
                goto $sub;
            });
        $views{$view} = bless $new_views{$view}, 'App::View';
    }
}

package App::View;

# API Method App::View::ViewName::Activate;
sub _api_activate {
    my $self = shift;
    # do something with $self here, which is the view 
    # object created by App::DSL
    warn $self->{attr1};
}

1;

中你的脚本：

use strict;
use warnings;
# Create App::View::View1 and App::View::View2
use App::DSL (View1 => {attr1 => 'hello'}, View2 => {attr1 => 'bye'});
App::View::View1::Activate();
App::View::View2::Activate();
App::View::View1::Activate();