在 vdproj 中最后一步重新启动，我该如何添加它？

Question

如何将重新启动操作添加到 vdproj？

我需要一个 MSI 文件，该文件可在安装结束时重新启动电脑。

Answer 1

只需添加值为“Force”的“REBOOT”属性，这将提示用户在安装完成后重新启动，或者如果没有用户界面则自动重新启动。

如果您无法在 vdjproj 中执行此操作，则只需在构建设置后使用 Orca 编辑 MSI 的属性表即可。

如果要强制重新启动，可以设置 REBOOT=Force 和 REBOOTPROMPT=Suppress，这样就不会提示用户。

或者，您可以使用 ForceReboot 操作在安装过程中重新启动，或使用 ScheduleReboot 安排安装完成后重新启动。 同样，如果您无法在 vdjproj 中执行此操作，则可以使用 Orca 添加其中任何一个操作。

您可以使用以下 VBS 执行类似的操作

Dim installer, database, view, result
Set installer = CreateObject("WindowsInstaller.Installer")
Set database = installer.OpenDatabase ("setup.msi", 1)
Set view = database.OpenView ("INSERT INTO Property (Property, Value) VALUES ('REBOOT', 'Force')")
view.Execute
database.Commit
Set database = nothing

Answer 2

这是我基于 saschabeaumont 的 答案。

要自动修改 .msi 以在每次构建安装程序时提示重新启动：

1. 在 .vdproj 部署项目文件所在的文件夹中创建一个名为“AddRebootPrompt.vbs”的文件，其中包含下面列出的 VB 脚本。< /p>

2. 在 Visual Studio 解决方案资源管理器中找到部署项目，右键单击并转到“属性”。

3. 在 PostBuildEvent 属性中，粘贴以下内容以在构建安装程序项目后运行脚本：

cscript "$( ProjectDir)AddRebootPrompt.vbs" "$(BuiltOuputPath)"

AddRebootPrompt.vbs 内容：

Dim installer, database, view, result
Dim strPathMsi 

If WScript.Arguments.Count <> 1 Then
    WScript.Echo "Usage: cscript AddRebootPrompt.vbs <path to MSI>"
    WScript.Quit -1
End If

strPathMsi = WScript.Arguments(0)

Set installer = CreateObject("WindowsInstaller.Installer")
Set database = installer.OpenDatabase (strPathMsi, 1)
Set view = database.OpenView ("INSERT INTO Property (Property, Value) VALUES ('REBOOT', 'Force')")

WScript.Echo "Adding forced reboot prompt to install sequence."

view.Execute
database.Commit
WScript.Quit 0

如果成功，您将看到“添加强制重新启动提示以安装序列”。 构建安装程序项目时，在构建输出日志窗口中。

Answer 3

如果您需要重新启动，Windows Installer 应该会自动检测到它。 如果您想重新启动，因为您懒得手动启动服务，则需要找到其他方法（我不知道有什么简单的方法）。