使用 SQLDataReader 对象时关闭 SQLConnection 对象的重要性

Question

我目前的合同工作是在一家大型电子商务公司。 他们的代码库的起源可以追溯到.Net 1.0，这让我大吃一惊，其中包含许多问题，这些问题使我的嗅觉水平超出了我上次的垃圾水平。

尽管如此，并试图分散我的注意力，我还是愉快地尝试添加功能来解决其他问题或扩展更多垃圾。 当我触摸 DAL/BLL 时，修复上述问题所需的时间就会完成。 然而，我希望得到专家们的信任投票，以确保不会浪费客户的时间，或者更糟糕的是，我的可信度会因接触“有效的东西”而被否决。 当然，单元测试可以解决或至少减轻这种担忧。 也许这也应该添加到 wtf.com 中？

Public Function GetSizeInfoBySite(ByVal siteID As String) As IList
    Dim strSQL As String = "YES INLINE SQL!! :)"
    Dim ci As CrapInfo
    Dim alAnArrayList As ArrayList

    Dim cn As New SqlConnection(ConfigurationSettings.AppSettings("ConnectionString"))
    Dim cmd As New SqlCommand(strSQL, cn)
    cmd.Parameters.Add(New SqlParameter("@MySiteID", SqlDbType.NVarChar, 2)).Value = siteID
    cn.Open()
    Dim rs As SqlDataReader = cmd.ExecuteReader(CommandBehavior.CloseConnection)
    While rs.Read()
        ci = New CategoryInfo(rs("someID"), rs("someName"))
        If IsNothing(alAnArrayList) Then
            alAnArrayList = New ArrayList
        End If
        alAnArrayList.Add(ci)
    End While
    rs.Close()
    Return CType(alAnArrayList, IList)
End Function

除了让我感到不安的内联 SQL 之外，还有人看到这个问题吗？ 至少，您通常不会将上述内容包装在我们大多数人都知道自 .Net v1.0 以来就存在的 try/catch/finally 中吗？ 更好的是，用Using语句修复不是更明智吗？ SQLDataReader close 是否真的封装了连接自动关闭？

Answer 1

如果用户输入被正确参数化，那么内联 sql 没有任何问题，看起来确实如此。

除此之外，是的，您确实需要关闭连接。 在繁忙的网站上，您可能会达到极限，这会导致各种奇怪的情况。

我还注意到它仍然使用数组列表。 由于它们已经从 .Net 1.0 发展而来，因此是时候将它们更新为通用 List（并避免调用 CType - 您应该能够使用 DirectCast() 来代替）。

Answer 2

一定要在 Connection 和 Reader 对象周围使用一些 using 语句。 如果出现异常，它们将不会被关闭，直到垃圾收集器处理它们为止。

当有 using 语句时，我倾向于不调用 .Close() 。 即使 SqlDataReader 在处置时关闭连接（检查 doco），在 Connection 周围放置 using 也不会造成伤害并坚持模式。

如果你这样做，只有当你需要在那里进行异常处理时才需要 try/finally 。 我倾向于将异常处理留在较高级别（包装每个 UI 入口点、库入口点、异常中的额外信息），因为堆栈跟踪通常足以调试错误。

这并不重要，但如果要重构，请将集合初始化移到循环之外。 再想一想，如果没有记录，代码将返回 null。

至少使用了SqlParameters！ 如果发现任何将用户输入与 SQL 连接起来的东西（SQL 注入攻击），无论它“清理”得多么好，都将其删除。

Answer 3

当阅读器关闭时，连接将关闭，因为它使用 CloseConnection 命令行为。

Dim rs As SqlDataReader = cmd.ExecuteReader(CommandBehavior.CloseConnection)

根据 MSDN (http://msdn.microsoft.com /en-us/library/aa326246(VS.71).aspx)

如果创建 SqlDataReader 时将 CommandBehavior 设置为 CloseConnection，则关闭 SqlDataReader 会自动关闭连接。

Answer 4

为了回应乔尔和罗伯特提出的一些重要观点，我重构了如下方法，该方法运行完美。

Public Function GetSomeInfoByBusObject(ByVal SomeID As String) As IList
Dim strSQL As String = "InLine SQL"
Dim ci As BusObject
Dim list As New GenList(Of BusObject)
Dim cn As New SqlConnection(
    ConfigurationSettings.AppSettings("ConnectionString"))
Using cn
    Dim cmd As New SqlCommand(strSQL, cn)
    Using cmd
        cmd.Parameters.Add(New SqlParameter
            ("@SomeID", SqlDbType.NVarChar, 2)).Value = strSiteID
        cn.Open()
            Dim result As SqlDataReader = cmd.ExecuteReader(CommandBehavior.CloseConnection)
                While result.Read()
                    ci = New BusObject(rs("id), result("description"))
                    list.Add(DirectCast(ci, BusObject))
                End While
            result.Close()
        End Using
    Return list
End Using

End Function

创建了一个漂亮的小帮助器类来包装通用细节

Public Class GenList(Of T)
    Inherits CollectionBase
    Public Function Add(ByVal value As T) As Integer
        Return List.Add(value)
    End Function
    Public Sub Remove(ByVal value As T)
        List.Remove(value)
    End Sub
    Public ReadOnly Property Item(ByVal index As Integer) As T
        Get
            Return CType(List.Item(index), T)
        End Get
    End Property
End Class

Answer 5

如果您使用 C#，我会将数据读取器创建包装在 using 语句中，但我认为 VB 没有这些？

Answer 6

Public Function GetSizeInfoBySite(ByVal siteID As String) As IList(Of CategoryInfo)
        Dim strSQL As String = "YES INLINE SQL!! :)"

        'reference the 2.0 System.Configuration, and add a connection string section to web.config
        '  <connectionStrings>
        '   <add name="somename" connectionString="someconnectionstring" />
        '  </connectionStrings >

        Using cn As New SqlConnection(System.Configuration.ConfigurationManager.ConnectionStrings("somename").ConnectionString

            Using cmd As New SqlCommand(strSQL, cn)

                cmd.Parameters.Add(New SqlParameter("@MySiteID", SqlDbType.NVarChar, 2)).Value = siteID
                cn.Open()

                Using reader As IDataReader = cmd.ExecuteReader()

                    Dim records As IList(Of CategoryInfo) = New List(Of CategoryInfo)

                    'get ordinal col indexes
                    Dim ordinal_SomeId As Integer = reader.GetOrdinal("someID")
                    Dim ordinal_SomeName As Integer = reader.GetOrdinal("someName")

                    While reader.Read()
                        Dim ci As CategoryInfo = New CategoryInfo(reader.GetInt32(ordinal_SomeId), reader.GetString(ordinal_SomeName))
                        records.Add(ci)
                    End While

                    Return records

                End Using
            End Using
        End Using
    End Function

您可以尝试类似上面的操作，using 语句将处理连接关闭和对象处置。 当类实现 IDisposable 时，此功能可用。 还构建并返回 CategoryInfo 的 IList。