使用变量选择元素

Question

基本上我有一个看起来像这样的小模板：

<xsl:template name="templt">
    <xsl:param name="filter" />
    <xsl:variable name="numOrders" select="count(ORDERS/ORDER[$filter])" />
</xsl:template>

我试图使用它来调用

<xsl:call-template name="templt">
    <xsl:with-param name="filter" select="PRICE &lt; 15" />
</xsl:call-template>

它 不幸的是，它似乎在调用模板之前对其进行评估（因此有效地传递了“false”）将其括在引号中只会使其成为字符串字面意义，所以这也不起作用。 有谁知道我想要实现的目标是否可能？ 如果是这样，你能解释一下吗？ 干杯

Answer 1

下面怎么样：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template name="templt">
    <xsl:param name="filterNodeName" />
    <xsl:param name="filterValue" />
    <xsl:variable name="orders" select="ORDERS/ORDER/child::*[name() = $filterNodeName and number(text()) < $filterValue]" />
    <xsl:for-each select="$orders">
      <xsl:value-of select="."/>
    </xsl:for-each>
  </xsl:template>

  <xsl:template match="/">
    <xsl:call-template name="templt">
      <xsl:with-param name="filterNodeName" select="'PRICE'" />
      <xsl:with-param name="filterValue" select="15" />
    </xsl:call-template>
  </xsl:template>
</xsl:stylesheet>

如果您仍然只想使用单个参数，您可以首先在模板“templt”中进行标记。

Answer 2

Divo 的回答很好。

但是，它将任何最终过滤限制为指定子项的名称和值。

很高兴知道可以传递一个（相当于一个）函数作为参数。 这个非常强大的概念在 FXSL（XSLT 函数式编程库）中实现。 FXSL 完全是用 XSLT 本身编写的。

这是使用 过滤器函数/模板。 我们将过滤器作为参数传递给执行过滤的模板。 过滤器可以是任何代码/逻辑。 在这种特殊情况下，我们将一个引用作为参数传递给一个检查数字是否为偶数的模板。 完整的转换仅输出那些值为偶数的“num”元素。

我们可以很容易地通过任何其他过滤器，使用完全相同的技术：过滤（不）偶数、平方、质数等。

请注意，这个过滤器不会'不必自己编写“过滤器”模板——它是一次性编写的，并且由 FXSL 库提供。 因此，您通常只需使用即可。 指令导入“过滤器”模板和 FXSL 已提供的许多其他有用的函数/模板。

以下转换：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/"
xmlns:myIsEven="myIsEven"
>

  <xsl:import href="filter.xsl"/>

  <!-- To be applied on numList.xml -->

  <xsl:output indent="yes" omit-xml-declaration="yes"/>

  <myIsEven:myIsEven/>

  <xsl:template match="/">
    <xsl:variable name="vIsEven"
         select="document('')/*/myIsEven:*[1]"/>

    Filtering by IsEven:
    <xsl:call-template name="_filter">
        <xsl:with-param name="pList" select="/*/*"/>
        <xsl:with-param name="pController" select="$vIsEven"/>
    </xsl:call-template>

  </xsl:template>

  <xsl:template name="myIsEven" mode="f:FXSL"
    match="myIsEven:*">
    <xsl:param name="arg1"/>

    <xsl:if test="$arg1 mod 2 = 0">1</xsl:if>
  </xsl:template>
</xsl:stylesheet>

当应用于此源 XML 文档时：

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

产生所需的（已过滤的）结果，仅包含具有偶数值的节点：

Filtering by IsEven:
<num>02</num>
<num>04</num>
<num>06</num>
<num>08</num>
<num>10</num>

有关 XSLT 中函数式编程的更多信息，请访问 FXSL 页面 和库本身可以从其 sourceforce 项目。

回到具体问题：

此转换：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/"
xmlns:myFilter="myFilter"
>

  <xsl:import href="filter.xsl"/>

  <!-- To be applied on Orders.xml -->

  <xsl:output indent="yes" omit-xml-declaration="yes"/>

  <myFilter:myFilter/>

  <xsl:template match="/">
    <xsl:variable name="vFilter"
         select="document('')/*/myFilter:*[1]"/>

    Filtering by PRICE < 15:
    <xsl:call-template name="_filter">
        <xsl:with-param name="pList" select="/*/*"/>
        <xsl:with-param name="pController" select="$vFilter"/>
    </xsl:call-template>

  </xsl:template>

  <xsl:template name="myFilter" mode="f:FXSL"
    match="myFilter:*">
    <xsl:param name="arg1"/>

    <xsl:if test="$arg1/PRICE < 15">1</xsl:if>
  </xsl:template>
</xsl:stylesheet>

当应用于此源 XML 文档时：

<ORDERS>
  <ORDER>
    <PRICE>10</PRICE>
  </ORDER>
  <ORDER>
    <PRICE>7</PRICE>
  </ORDER>
  <ORDER>
      <PRICE>22</PRICE>
</ORDER>
  <ORDER>
      <PRICE>16</PRICE>
  </ORDER>
  <ORDER>
      <PRICE>13</PRICE>
  </ORDER>
  <ORDER>
      <PRICE>19</PRICE>
  </ORDER>
</ORDERS>  

产生所需的结果：

Filtering by PRICE < 15:
<ORDER>
   <PRICE>10</PRICE>
</ORDER>
<ORDER>
   <PRICE>7</PRICE>
</ORDER>
<ORDER>
   <PRICE>13</PRICE>
</ORDER>

Answer 3

使用 EXSLT 库，特别是 dyn:evaluate 函数，它可以评估作为 XPath 表达式的字符串。