如何使用带有样式表和 xsltproc 的 xslt 从 xml 中删除元素？

Question

我有很多 XML 文件，它们具有以下形式：

<Element fruit="apple" animal="cat" />

我想将其从文件中删除。

使用 XSLT 样式表和 Linux 命令行实用程序 xsltproc，我该如何做到这一点？

此时在脚本中我已经有了包含我想要删除的元素的文件列表，因此单个文件可以用作参数。

---

编辑：这个问题最初缺乏意图。

我想要实现的是删除整个元素“Element”（fruit==“apple”&&animal==“cat”）。 在同一个文档中有许多名为“Element”的元素，我希望保留这些元素。 所以

<Element fruit="orange" animal="dog" />
<Element fruit="apple"  animal="cat" />
<Element fruit="pear"   animal="wild three eyed mongoose of kentucky" />

会变成：

<Element fruit="orange" animal="dog" />
<Element fruit="pear"   animal="wild three eyed mongoose of kentucky" />

Answer 1

使用最基本的 XSLT 设计模式之一：“覆盖 标识转换”，只需编写以下内容：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

 <xsl:output omit-xml-declaration="yes"/>

    <xsl:template match="node()|@*">
      <xsl:copy>
         <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="Element[@fruit='apple' and @animal='cat']"/>
</xsl:stylesheet>

请注意第二个模板如何仅针对具有属性“fruit”的名为“Element”的元素覆盖身份（第一个）模板”，值为“apple”，属性“animal”，值为“cat”。 该模板的主体为空，这意味着匹配的元素将被简单地忽略（匹配时不会产生任何内容）。

当此转换应用于以下源 XML 文档时：

<doc>... 
    <Element name="same">foo</Element>...
    <Element fruit="apple" animal="cat" />
    <Element fruit="pear" animal="cat" />
    <Element name="same">baz</Element>...
    <Element name="same">foobar</Element>...
</doc>

产生想要的结果：

<doc>... 
    <Element name="same">foo</Element>...
    <Element fruit="pear" animal="cat"/>
    <Element name="same">baz</Element>...
    <Element name="same">foobar</Element>...
</doc>

可以找到使用和覆盖身份模板的更多代码片段 此处。

Answer 2

@Dimitre Novatchev 的答案当然既正确又优雅，但有一个概括（OP 没有询问）：如果您要过滤的元素也有您想要保留的子元素或文本怎么办？

我相信这个微小的变化涵盖了这种情况：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    version="2.0">

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <!-- drop DropMe elements, keeping child text and elements -->
    <xsl:template match="DropMe">
        <xsl:apply-templates/>
    </xsl:template>

</xsl:stylesheet>

匹配条件可能会很复杂以指定其他属性等，并且如果您要删除其他内容，您可以使用多个此类模板。

所以这个输入：

<?xml version="1.0" encoding="UTF-8"?>
<mydocument>
    <p>Here's text to keep</p>
    <p><DropMe>Keep this text but not the element</DropMe>; and keep what follows.</p>
    <p><DropMe>Also keep this text and <b>this child element</b> too</DropMe>, along with what follows.</p>
</mydocument>

产生这个输出：

<?xml version="1.0" encoding="UTF-8"?><mydocument>
    <p>Here's text to keep</p>
    <p>Keep this text but not the element; and keep what follows.</p>
    <p>Also keep this text and <b>this child element</b> too, along with what follows.</p>
</mydocument>

归功于 XSLT Cookbook。