如何为 Flex Datagrid 制作可重复使用的 labelFunction？

Question

我有一个标签函数，例如：

private function formatDate (item:Object, column:DataGridColumn):String
{
    var df:DateFormatter = new DateFormatter();
    df.formatString = "MM/DD/YY";

    if (column.dataField == "startDate") {
        return df.format(item.startDate);
    }

    return "ERR";
}

我通过使用 labelFunction 在数据列中使用它。

如果我的数据字段名为“startDate”，则效果很好。 我想让这个函数变得通用，这样我就可以在任何地方使用它。

我怎样才能做到这一点。 我想我需要使用某种“反思” - 或者也许完全是另一种方法？

Answer 1

您可以使用列的 dataField 属性作为项目的键来使该函数通用。

private function formatDate (item:Object, column:DataGridColumn):String
{
    var df:DateFormatter = new DateFormatter();
    df.formatString = "MM/DD/YY";

    var value:object = item[column.dataField];

    return df.format(value);
}

-本

Answer 2

您可以定义另一个函数，我们称之为 partial ，它将一些额外的参数绑定到您的函数：

function partial( func : Function, ...boundArgs ) : Function {
  return function( ...dynamicArgs ) : * {
    return func.apply(null, boundArgs.concat(dynamicArgs))
  }
}

然后您可以像这样更改您的函数：

private function formatDate( dataField : String, item : Object, column : DataGridColumn ) : String {
  var df : DateFormatter = new DateFormatter();

  df.formatString = "MM/DD/YY";

  if ( column.dataField == dataField ) {
    return df.format(item[dataField]);
  }

  return "ERR";
}

请注意，我添加了一个名为 dataField 的新参数> 在参数列表中第一个，并将所有对“startDate”的引用替换为该参数。

并像这样使用它：

var startDateLabelFunction : Function = partial(formatDate, "startDate");
var endDateLabelFunction   : Function = partial(formatDate, "endDate");

partial 函数返回一个新函数，该函数使用调用partial的参数调用原始函数，并将参数与新函数的参数连接起来......你和我一样吗？ 另一种说法是它可以返回一个新函数，其中 N 个参数预先绑定到特定值。

让我们一步一步地看一下：

partial(formatDate, "startDate") 返回一个如下所示的函数：

function( ...dynamicArgs ) : * {
  return func.apply(null, boundArgs.concat(dynamicArgs));
}

但是 func 和 boundArgs是你作为参数传递给 partial 的内容，所以你可以说它看起来像这样：

function( ...dynamicArgs ) : * {
  return formatDate.apply(null, ["startDate"].concat(dynamicArgs));
}

当它被调用时，它或多或少与这个

function( item : Object, column : DataGridColumn ) : * {
  return formatDate("startDate", item, column);
}

Tada 相同！

Answer 3

这是更通用的方法：

public static function getDateLabelFunction(dateFormatString:String=null, mxFunction:Boolean = false) : Function {
        var retf:Function;

        // defaults
        if(dateFormatString == null) dateFormatString = "MM/DD/YY";
        if(mxFunction) {
            retf = function  (item:Object, column:DataGridColumn):String
            {
                var df:DateFormatter = new DateFormatter();
                df.formatString = dateFormatString;

                var value:Object = item[column.dataField];

                return df.format(value);
            }
        }else {
            retf = function  (item:Object, column:GridColumn):String
            {
                var df:DateFormatter = new DateFormatter();
                df.formatString = dateFormatString;

                var value:Object = item[column.dataField];

                return df.format(new Date(value));
            }
        }

        return retf;

    }

用法（Spark DataGrid）

var labelFunction = getDateLabelFunction();

或 MX Datagrid

var labelFunction = getDateLabelFunction(null,true);

传递自定义日期格式字符串：

var labelFunction = getDateLabelFunction("DD/MM/YYYY",true);

默认为“MM/DD/YYYY”；