从 TObjectList 中提取对象

Question

我有一个 OwnsObjects = true 的 TObjectList。 它包含相当多的对象。 现在我想从该列表中删除索引 Idx 处的对象，而不释放它。

Extract 方法是唯一的选择吗？

ExtractedObject := TheList.Extract(TheList[Idx]);

所有其他方法似乎都会释放该对象。 我正在寻找更有效的东西，不会每次都进行线性搜索，因为我已经知道对象的索引。 类似重载的...

ExtractedObject := TheList.Extract(Idx);

... 不存在。

Answer 1

为什么不直接将 OwnsObjects 设置为 false，进行删除，然后再次将其设置为 true？

Answer 2

这就是类助手的用处，

TObjectListHelper = class helper for TObjectList
  function ExtractByIndex(const AIndex: Integer): TObject;
end;

function TObjectListHelper.ExtractByIndex(const AIndex: Integer): TObject;
begin
  Result := Items[AIndex];
 if Result<>nil then
   Extract(Result);
end;

您现在可以使用：

MyObjList.ExtractByIndex(MyIndex);

Answer 3

如果您查看删除的代码，就会发现是通知方法导致释放发生。

这应该有效：

  TMyObjectList = Class(TObjectList)
  private
    fNotify: Boolean;
    { Private declarations }
    procedure EnableNotification;
    procedure DisableNotification;
  protected
    procedure Notify(Ptr: Pointer; Action: TListNotification); override;
  public
    constructor Create(AOwnsObjects: Boolean);overload;
    constructor Create; overload;
    function Extract(const idx : Integer) : TObject;
  end;


constructor TMyObjectList.Create(AOwnsObjects: Boolean);
begin
  inherited Create(AOwnsObjects);
  fNotify := True;
end;

constructor TMyObjectList.Create;
begin
  inherited Create;
  fNotify := True;
end;

procedure TMyObjectList.DisableNotification;
begin
  fnotify := False;
end;

procedure TMyObjectList.EnableNotification;
begin
  fNotify := True;
end;

function TMyObjectList.Extract(const idx: Integer) : TObject;
begin
  Result := Items[idx];
  DisableNotification;
  try
    Delete(idx);
  finally
    EnableNotification;
  end;
end;

procedure TMyObjectList.Notify(Ptr: Pointer; Action: TListNotification);
begin
 if fNotify then
   inherited;
end;

Answer 4

建议的辅助类（由 Gamecat）将导致 Thomas 希望摆脱的相同查找。

如果您查看源代码，您可以了解 Extract() 的真正用途，然后使用相同的方法。

我会建议像这样的东西：

obj := list[idx];
list.list^[idx] := nil;  //<- changed from list[idx] := nil;
list.delete(idx);

这将为您提供对象，就像 Extract() 所做的那样，然后从列表中删除它，而不进行任何查找。 现在，您可以将其放入某个方法中，例如辅助类或子类或您喜欢的任何地方。

Answer 5

我不久前不使用 Delphi/C++Builder，但据我所知，这是唯一的方法。
我的建议是使用 TList，并在需要时手动删除对象。

Answer 6

有什么问题吗：

ExtractedObject := TExtractedObject.Create;
ExtractedObject.Assign(Thelist[Idx]);
TheList.Delete(idx);

创建和分配需要时间，但搜索列表不需要时间。 效率取决于对象的大小 -v- 列表的大小。