我必须在 Perl 预编译正则表达式中转义哪些字符？

Question

我很难确定在使用 Perl 的 qr{} 构造时必须转义哪些字符

我正在尝试为包含大量正常转义字符的文本创建多行预编译正则表达式（ #*.>:[]) 并且还包含另一个预编译的正则表达式。 此外，出于测试目的，我需要尽可能严格地匹配。

my $output = q{# using defaults found in .config
*
*
Options:
  1. opt1
> 2. opt2
choice[1-2?]: };

my $sc = qr{(>|\s)}smx;
my $re = qr{# using defaults found in .config
*
*
Options:
$sc 1. opt1
$sc 2. opt2
choice[1-2?]: }mx;

if ( $output =~ $re ) {
  print "OK!\n";
}
else {
  print "D'oh!\n";
}

错误：

Quantifier follows nothing in regex; marked by <-- HERE in m/# using defaults found in .config
* <-- HERE 
*
Options:
(?msx-i:(>|\s)) 1. opt1
(?msx-i:(>|\s)) 2. opt2
choice[1-2?]: / at ./so.pl line 14.

尝试转义星号会导致匹配失败（D'oh 输出）。 尝试转义其他讨厌的字符也会导致匹配失败。 我可以继续尝试不同的逃脱组合，但这里有很多变化，我希望有人能提供一些见解。

Answer 1

您必须转义 qr// 的分隔符，并且必须转义任何要用作文字的正则表达式元字符。 如果您希望它们是文字 * 的，则需要转义它们，因为 * 是正则表达式量词。

您的问题是您添加的各种正则表达式标志。 /m 不执行任何操作，因为您不使用字符串开头或结尾锚点（^、$）。 /s 不执行任何操作，因为您不使用通配符。 元字符。 /x 使正则表达式中的所有空格变得毫无意义，并将带有 # 的行转换为正则表达式注释。

这就是您想要的，删除了正则表达式标志并转义了正确的内容：

my $sc = qr{(>|\s)};

my $re = qr{# using defaults found in \.config
\*
\*
Options:
$sc 1\. opt1
$sc 2\. opt2
choice\[1-2\?]: };

尽管 Damian Conway 告诉 Perl 最佳实践 中的人们始终将这些选项放在他们的正则表达式中，但您现在明白为什么他错了。 仅当您想要它们做什么时才应添加它们，并且仅当您知道它们做什么时才应添加它们。 :) 如果您想使用 /x，您可以执行以下操作。 您必须转义任何文字空白，需要以某种方式表示行结尾，并且必须转义文字 # 字符。 以前可读的内容现在变得一团糟：

my $sc  = qr{(>|\s)};
my $eol = qr{[\r\n]+};

my $re  = qr{\# \s+ using \s+ defaults \s+ found \s+ in \s+ \.config $eol
\*                    $eol
\*                    $eol
Options:              $eol
$sc \s+ 1\. \s+ opt1   $eol
$sc \s+ 2\. \s+ opt2   $eol
choice\[1-2\?]: \s+
}x;

if ( $output =~ $re ) {
  print "OK!\n";
}
else {
  print "D'oh!\n";
}

Answer 2

听起来你真正想要的是期望，但你最直接的东西寻找的是 quotemeta 运算符，它转义对正则表达式具有特殊含义的所有字符。

但是，要直接回答您的问题，除了取消引号字符（在本例中 } ）之外，您还需要至少转义 .[$()|*+?{\

Answer 3

就像布莱恩所说，你必须转义分隔符和正则表达式元字符。 请注意，当使用 qr//x （您就是）时，您还必须转义空白字符和 # （这是注释标记）。 您可能实际上不想在这里使用 /x 。 如果您想安全，您可以转义任何非字母数字字符。