修补 Flex 框架以立即显示预加载器？

Question

在 Flex 框架中，可以在加载站点时使用自定义预加载器。

在 Adobe 文档 中，它指定 ' 如果在下载 700 毫秒后下载的应用程序少于一半，则会显示进度条 [预加载器]。'

但是我总是希望预加载器立即出现，因为我知道我们 95% 的用户都在第一次访问者，该网站超过 500kb。 我不希望人们必须等待 0.7 秒才能出现预加载动画。

我认为理论上可以通过“猴子修补”框架来消除 0.7 秒的限制。 我没有时间弄清楚如何做，而且我以前从未这样做过。

有人帮忙吗？

Answer 1

您应该只扩展 DownloadProgressBar，尝试以下代码。 我以前用过这个，我找到了杰西·沃登网站 点击这里 usful 获取有关此内容的信息（我在那里找到了它，这是他的代码的精简版本）

package{
import flash.display.MovieClip;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.ProgressEvent;

import mx.events.FlexEvent;
import mx.preloaders.DownloadProgressBar;

public class Preloader extends DownloadProgressBar
{

    /**
    * The Flash 8 MovieClip embedded as a Class.
    */      
    [Embed(source="yourPreloaderFile.swf")]
    private var FlashPreloaderSymbol:Class;

    private var clip:MovieClip;

    public function Preloader()
    {
        super();
        clip = new FlashPreloaderSymbol();
        addChild(clip);
    }

    public override function set preloader(preloader:Sprite):void 
    {                   
        preloader.addEventListener( FlexEvent.INIT_COMPLETE ,   onFlexInitComplete );

        centerPreloader();
    }

    private function centerPreloader():void
    {
        x = (stageWidth / 2) - (clip.width / 2);
        y = (stageHeight / 2) - (clip.height / 2);
    }

    private function onFlexInitComplete( event:FlexEvent ):void 
    {
        dispatchEvent( new Event( Event.COMPLETE ) ); 
    }


    protected override function showDisplayForDownloading(time : int, event : ProgressEvent) : Boolean {
        return true;
    }

}

}

之后只需更改 main 中的预加载器属性应用程序标记到 Preloader 类。

Answer 2

这是 mx.preloaders::DownloadProgressBar.as 中 showDisplayForDownloading 函数的第 1205 行。

老派的猴子补丁已经在 AS3 中消失了，但是您可以编辑 Flex 源代码并自己编译一个新的 Framework.swc（显然很痛苦），或者只是将其包含在源路径中（源路径覆盖 .swcs）； 或者从 DownloadProgressBar 派生您自己的预加载器类，该类仅覆盖 showDisplayForDownloading 并返回 true。

您可以在“%PROGRAMFILES%\Adobe\Flex Builder 3[ Plug-in]\sdks\3.0.0\frameworks\projects\framework\src”中找到框架源代码，然后是包路径。 如果您使用的是 3.1 或其他版本，请更改 sdk 版本。

Answer 3

我猜延迟有两个原因：

1. 你不希望预加载器
   一旦页面已经存在，就“闪烁”
   缓存
2. 预加载器本身必须
   load

当我需要绝对确保立即显示预加载器时，我制作一个小型包装器 swf，其中仅预加载器并从那里加载主 swf。

Answer 4

不可能立即显示预加载器，因为在显示进度之前需要下载一些类。 另一种选择是在 html 中显示进度，当加载 Flash 影片时，它会显示在此处。