如何使用 Perl 模块中的常量？

Question

如果我在 Perl 模块中定义一个常量，我如何在我的主程序中使用该常量？ （或者我如何在主程序中调用该常量？）

Answer 1

常量可以像其他包符号一样导出。 使用标准 Exporter 模块，您可以从 然后，

package Foo;
use strict;
use warnings;

use base 'Exporter';

use constant CONST => 42;

our @EXPORT_OK = ('CONST');

1;

在客户端脚本（或其他模块）中，

use Foo 'CONST';
print CONST;

您可以使用 %EXPORT_TAGS 哈希（请参阅导出器文档）来定义可以使用单个导入参数导出的常量组。

更新：这里是一个示例，说明如果您有多个常量，如何使用 %EXPORT_TAGS 功能。

use constant LARRY => 42;
use constant CURLY => 43;
use constant MOE   => 44;

our @EXPORT_OK = ('LARRY', 'CURLY', 'MOE');
our %EXPORT_TAGS = ( stooges => [ 'LARRY', 'CURLY', 'MOE' ] );

然后你可以说

use Foo ':stooges';
print "$_\n" for LARRY, CURLY, MOE;

Answer 2

常量只是具有空原型的子项，因此可以像任何其他子项一样导出它们。

# file Foo.pm
package Foo;
use constant BAR => 123;
use Exporter qw(import);
our @EXPORT_OK = qw(BAR);


# file main.pl:
use Foo qw(BAR);
print BAR;

Answer 3

为了扩展之前的答案，由于常量实际上只是子项，因此您也可以直接调用它们：

use Foo;
print Foo::BAR;

Answer 4

您可能需要考虑使用 Readonly 而不是常量。

Answer 5

package Foo;
use Readonly;
Readonly my  $C1 => 'const1';
Readonly our $C2 => 'const2';
sub get_c1 { return $C1 }
1;

perl -MFoo -e 'print "$_\n" for Foo->get_c1, $Foo::C2'

Answer 6

为了增加技巧，由于常量只是一个子例程，您甚至可以将其作为类方法调用。

package Foo;
use constant PI => 3.14;

print Foo->PI;

如果你有很多常量，这是一种很好的方法来获取偶尔的常量，而不必将它们全部导出。 但是，与 Foo::PI 或导出 PI 不同，Perl 不会编译出 Foo->PI，因此您会产生方法的成本打电话（这可能并不重要）。