如何向我的班级用户表明验证要求？

Question

我正在实现一个类，该类使用非常严格定义的模式封装 xml 文档。 我不控制架构。

类中的属性之一用于模式指示必须与特定正则表达式匹配的元素值。 在属性的设置器中，如果字符串与表达式不匹配，我将引发异常。

我的问题是，如何才能更好地向我班级的用户传达该领域的要求？ 有我可以使用的属性吗？ Xml 注释（所以它显示在智能感知中）？ 除了抛出异常之外，我还应该做些什么吗？ 我还有什么其他选择？

Answer 1

如果您随程序集一起提供 XmlComments 可能会有所帮助，但我想说，如果不满足要求，最好不要抛出异常，并使异常消息尽可能详细。 如果当用户调用依赖于该属性的方法/属性时未满足要求，我也会抛出异常（同样有很多细节）。

您实际上无法采取任何措施来阻止使用该代码的人第一次犯错误，但是当错误确实发生时，您应该尽可能清楚地了解如何纠正它。

Answer 2

您的代码文档应满足要求，或者模式文档应解释要求。 对于那些不愿意研究他们将要使用的代码的人，你无能为力。

Answer 3

感谢您的建议。

我在考虑这个问题时想到的一个想法是创建一个名为 MatchedString 之类的新类来强制执行约束。

它有一个需要正则表达式字符串的构造函数，构造后表达式将仅通过只读属性向用户公开。 然后它会有一个用户可以设置的 value 属性，该属性将根据 setter 中的表达式进行检查。

我的想法是，我还可以为不同的行为创建选项，以便在枚举中验证失败时使用，并让用户指定他们想要的选项：

• 设置为空字符串
• 设置为空字符串并抛出异常
• 无论如何设置错误值
• 设置错误值无论如何，抛出异常
• 只是抛出异常
• 什么都不做

此外，我认为这将允许我的类用户进行一些基本测试，而不必在自己的代码中复制 RegEx 对象。 添加与字符串类型之间的隐式转换，对于类用户来说应该是直观的。

对此有什么想法吗？

Answer 4

无论我是否使用它，实现 MatchedString 类看起来都很有趣。 所以这里是：

Public Class MatchedString
    Public Enum InvalidValueBehaviors
        SetToEmpty
        AllowSetToInvalidValue
        DoNothing
    End Enum

    Public Sub New(ByVal Expression As String)
        Me.expression = Expression
        exp = New Regex(Me.expression)
    End Sub

    Public Sub New(ByVal Description As String, ByVal Expression As String)
        Me.expression = Expression
        exp = New Regex(Me.expression)
        _expressiondescription = Description
    End Sub

    Public Sub New(ByVal Expression As String, ByVal ThrowOnInvalidValue As Boolean, ByVal InvalidValueBehavior As InvalidValueBehaviors)
        Me.expression = Expression
        exp = New Regex(Me.expression)
        Me.ThrowOnInvalidValue = ThrowOnInvalidValue
        Me.InvalidValueBehavior = InvalidValueBehavior
    End Sub

    Public Sub New(ByVal Description As String, ByVal Expression As String, ByVal ThrowOnInvalidValue As Boolean, ByVal InvalidValueBehavior As InvalidValueBehaviors)
        Me.expression = Expression
        exp = New Regex(Me.expression)
        _expressiondescription = Description
        Me.ThrowOnInvalidValue = ThrowOnInvalidValue
        Me.InvalidValueBehavior = InvalidValueBehavior
    End Sub

    Private exp As Regex
    Private expression As String

    Public ReadOnly Property MatchExpression() As String
        Get
            Return expression
        End Get
    End Property

    Public ReadOnly Property ExpressionDescription() As String
        Get
            Return _expressiondescription
        End Get
    End Property
    Private _expressiondescription As String

    Public Function CheckIsMatch(ByVal s As String)
        Return exp.IsMatch(s)
    End Function

    Public Property ThrowOnInvalidValue() As Boolean
        Get
            Return _thrownoninvalidvalue
        End Get
        Set(ByVal value As Boolean)
            _thrownoninvalidvalue = value
        End Set
    End Property
    Private _thrownoninvalidvalue = True

    Public Property InvalidValueBehavior() As InvalidValueBehaviors
        Get
            Return _invalidvaluebehavior
        End Get
        Set(ByVal value As InvalidValueBehaviors)
            _invalidvaluebehavior = value
        End Set
    End Property
    Private _invalidvaluebehavior As InvalidValueBehaviors = InvalidValueBehaviors.DoNothing

    Public Property Value() As String
        Get
            Return _value
        End Get
        Set(ByVal value As String)
            If value Is Nothing Then value = "" 'Never set to Nothing

            If CheckIsMatch(value) Then
                _value = value
            Else
                Select Case InvalidValueBehavior
                    Case InvalidValueBehaviors.AllowSetToInvalidValue
                        _value = value
                    Case InvalidValueBehaviors.SetToEmpty
                        _value = ""
                End Select

                If ThrowOnInvalidValue Then
                    Throw New ArgumentOutOfRangeException(String.Format("String: {0} does not match expression: {1}", value, MatchExpression))
                End If
            End If
        End Set
    End Property
    Private _value As String = ""

    Public Overrides Function ToString() As String
        Return _value
    End Function
End Class

Answer 5

将其记录在 XML 注释中，并引发异常。 使消息明确：

Element <elementname> must match /regex/