zsh 中的 Home/End 键不适用于 putty

Question

我在 Ubuntu 机器上运行 zsh 作为默认 shell，并且使用 gnome-terminal （据我所知它模拟 xterm）一切正常。 当我通过 ssh 和 putty（也模拟 xterm）从 windows 盒子登录时，home/end 键突然不再起作用。

我已经能够解决将这些行添加到我的 zshrc 文件中的问题...

bindkey '\e[1~' beginning-of-line
bindkey '\e[4~' end-of-line

...但我仍然想知道这里出了什么问题。 任何想法？

Answer 1

这对我有用。

将这些行添加到 ~/.zshrc

bindkey "\e[1;5D" backward-word
bindkey "\e[1;5C" forward-word

# ctrl-bs and ctrl-del
bindkey "\e[3;5~" kill-word
bindkey "\C-_"    backward-kill-word

# del, home and end
bindkey "\e[3~" delete-char
bindkey "\e[H"  beginning-of-line
bindkey "\e[F"  end-of-line

# alt-bs
bindkey "\e\d"  undo

Answer 2

这些绑定似乎不属于 emacs 模式中设置的默认绑定的一部分。

运行“bindkey -e”后在我的默认 zsh 安装上执行“where-is begin-of-line”显示它仅绑定到 ^a。 也许你应该问 zsh 开发人员为什么:-)

Answer 3

看来是个腻子的东西。 Gnome 终端分别发送 ^[OH 和 ^[OF 表示 Home 和 End，而 putty 则发送 ^[[1~ 和 <代码>^[[4~. putty 中有一个选项可以将 Home/End 键从 standard 模式更改为 rxvt 模式，这似乎可以修复 Home 键，但不能修复 End 键（现在发送 ^[Ow)。 猜猜是时候在某个地方提交错误报告了......:-)

Answer 4

在 PuTTY 配置对话框中，转到“连接”->“连接” 数据并在连接之前在终端类型字符串中输入 linux。

Answer 5

距离这个问题首次提出已经过去近 11 年了。 当时，一些发行版确实附带了 putty terminfo 条目，但它充其量只是平庸。 从那以后的几年里，情况有所改善，十多年来所必需的黑客攻击已不再需要。 PuTTY 仍然默认将 TERM 设置为 xterm 以实现兼容性，但如果您要连接到现代的最新系统，您可能会幸运地覆盖此设置，并且将其设置为 putty-256color：

1. 确保主机具有 putty-256color 的 terminfo 条目：toe -a | grep -F putty
2. 撤消您可能启用的任何黑客行为，以使 PuTTY 与 zsh 或其他程序正常工作。
3. 确保 PuTTY 是最新的。 当有更新可用时，它不会通知您，如果更新已经过时，您可能会遇到很多相同的问题。 您可能希望使用 Chocolatey 等内容自动保持最新状态。
4. 在 PuTTY 的配置对话框中，转到“连接”->“连接” 数据并将“终端类型字符串”设置为 putty-256color。
5. 当您执行此操作时，在同一配置屏幕上添加新的环境变量以启用 24 位颜色。 该变量不是标准化的，但它是由许多其他主流终端仿真器（例如 iTerm2）发送的，并且许多程序都可以理解它。
   1. 变量：COLORTERM
   2. 值：真彩色
6. 截至撰写本文时，我还没有找到默认通过 SSH 接受 COLORTERM 变量的发行版。 您需要在主机上编辑 OpenSSH 配置以允许它。 例如，在类似 Debian 的发行版上，编辑 /etc/ssh/sshd_config 并将 COLORTERM 添加到 AcceptEnv 行。
7. 现在一切都应该“正常工作”。 如果没有：
   1. 确保您在进行更改后已重新连接，或者至少在更改 TERM 后运行 exec zsh。 zsh 在运行时不会对 TERM 中的更改做出反应。
   2. 确保 TERM 实际上设置为您想要的内容：echo $TERM
   3. 您使用的是最新版本的发行版吗？ 例如，如果您正在进行长期支持生命周期构建，即使您的版本在技术上仍然受支持，它也可能没有最新的 terminfo 条目。
   4. 您使用的是screen还是tmux？ 那又是一整罐蠕虫。 首先进行测试，以缩小问题发生的范围。 在 tmux 中，尝试设置TERM=tmux-256color。 在屏幕中，尝试 TERM=screen-256color。
   5. 您使用的是最新版本的 PuTTY 吗？
   6. 您是否有实现键绑定或其他 hack 的 RC 文件？ 尝试使用默认的 RC 文件。
   7. 在尝试 terminfo 修复之前，您是否已更改各种 PuTTY 设置以尝试修复该问题？ 您可能需要重置这些设置。

Answer 6

这对我有用

bindkey -v

bindkey '\eOH'  beginning-of-line
bindkey '\eOF'  end-of-line

Answer 7

应该在所有发行版（不一定是 zsh 的所有版本，这里是 ymmv）之间移植的正确答案是使用 zkbd 中的 zkbd 帮助程序实用程序。

键盘定义
键盘、工作站、终端、模拟器和窗口系统的大量可能组合使得 zsh 不可能为每种情况都提供内置的键绑定。 Functions/Misc 中的 zkbd 实用程序可以帮助您快速为您的配置创建键绑定。

将 zkbd 作为自动加载函数或 shell 脚本运行：

zsh -f ~/zsh-4.3.17/Functions/Misc/zkbd

当您运行 zkbd 时，它首先要求您输入终端类型； 如果它提供的默认值是正确的，只需按回车键即可。 然后它会要求您按多个不同的键来确定您的键盘和终端的特性； zkbd 警告您
如果它发现任何异常情况，例如删除键既不发送 ^H 也不发送 ^?。

zkbd 读取的击键记录为名为 key 的关联数组的定义，并写入 HOME 或 ZDOTDIR 目录中的子目录 .zkbd 中的文件中。 文件名由 TERM、VENDOR 和 OSTYPE 组成
参数，用连字符连接。

您可以使用 source 或 . 命令将此文件读入您​​的 .zshrc 或其他启动文件，然后在 bindkey 命令中引用 key 参数，如下所示：< /p>

          source ${ZDOTDIR:-$HOME}/.zkbd/$TERM-$VENDOR-$OSTYPE
          [[ -n ${key[Left]} ]] && bindkey "${key[Left]}" backward-char
          [[ -n ${key[Right]} ]] && bindkey "${key[Right]}" forward-char
          # etc.

请注意，为了使 autoload zkbd 正常工作，zkbd 文件必须位于 fpath 数组中指定的目录之一（请参阅 zshparam(1)）。 如果您有标准的 zsh 安装，情况应该已经如此； 如果不是，请将 Functions/Misc/zkbd 复制到适当的目录。

请参阅 man -P "less -p 'keyboardDefinition'" zshcontrib，或搜索元手册页 zshall

Answer 8

我发现它是一个组合：

One

ZSH 开发人员认为 ZSH 不应该定义 Home、End、Del 的操作，...键。

Debian 和 Ubuntu 通过在全局 /etc/zsh/zshrc 文件中定义普通用户期望的正常操作来解决此问题。 遵循相关代码（在 Debian 和 Ubuntu 上是相同的）：

if [[ "$TERM" != emacs ]]; then
[[ -z "$terminfo[kdch1]" ]] || bindkey -M emacs "$terminfo[kdch1]" delete-char
[[ -z "$terminfo[khome]" ]] || bindkey -M emacs "$terminfo[khome]" beginning-of-line
[[ -z "$terminfo[kend]" ]] || bindkey -M emacs "$terminfo[kend]" end-of-line
[[ -z "$terminfo[kich1]" ]] || bindkey -M emacs "$terminfo[kich1]" overwrite-mode
[[ -z "$terminfo[kdch1]" ]] || bindkey -M vicmd "$terminfo[kdch1]" vi-delete-char
[[ -z "$terminfo[khome]" ]] || bindkey -M vicmd "$terminfo[khome]" vi-beginning-of-line
[[ -z "$terminfo[kend]" ]] || bindkey -M vicmd "$terminfo[kend]" vi-end-of-line
[[ -z "$terminfo[kich1]" ]] || bindkey -M vicmd "$terminfo[kich1]" overwrite-mode

[[ -z "$terminfo[cuu1]" ]] || bindkey -M viins "$terminfo[cuu1]" vi-up-line-or-history
[[ -z "$terminfo[cuf1]" ]] || bindkey -M viins "$terminfo[cuf1]" vi-forward-char
[[ -z "$terminfo[kcuu1]" ]] || bindkey -M viins "$terminfo[kcuu1]" vi-up-line-or-history
[[ -z "$terminfo[kcud1]" ]] || bindkey -M viins "$terminfo[kcud1]" vi-down-line-or-history
[[ -z "$terminfo[kcuf1]" ]] || bindkey -M viins "$terminfo[kcuf1]" vi-forward-char
[[ -z "$terminfo[kcub1]" ]] || bindkey -M viins "$terminfo[kcub1]" vi-backward-char

# ncurses fogyatekos
[[ "$terminfo[kcuu1]" == "^[O"* ]] && bindkey -M viins "${terminfo[kcuu1]/O/[}" vi-up-line-or-history
[[ "$terminfo[kcud1]" == "^[O"* ]] && bindkey -M viins "${terminfo[kcud1]/O/[}" vi-down-line-or-history
[[ "$terminfo[kcuf1]" == "^[O"* ]] && bindkey -M viins "${terminfo[kcuf1]/O/[}" vi-forward-char
[[ "$terminfo[kcub1]" == "^[O"* ]] && bindkey -M viins "${terminfo[kcub1]/O/[}" vi-backward-char
[[ "$terminfo[khome]" == "^[O"* ]] && bindkey -M viins "${terminfo[khome]/O/[}" beginning-of-line
[[ "$terminfo[kend]" == "^[O"* ]] && bindkey -M viins "${terminfo[kend]/O/[}" end-of-line
[[ "$terminfo[khome]" == "^[O"* ]] && bindkey -M emacs "${terminfo[khome]/O/[}" beginning-of-line
[[ "$terminfo[kend]" == "^[O"* ]] && bindkey -M emacs "${terminfo[kend]/O/[}" end-of-line
fi

因此，如果您要连接到 Debian 或 Ubuntu 机器，则无需执行任何操作。 一切都应该自动工作（如果没有，请参见下文）。

但是...如果您连接到另一个机器（例如 FreeBSD），可能没有用户友好的默认值 zshrc。 解决方案当然是将 Debian/Ubuntu zshrc 中的行添加到您自己的 .zshrc 中。

Two

Putty 将 xterm 作为终端类型发送到远程主机。 但在某个地方搞砸了，并且没有发送 Home、End 的正确控制代码，...这是人们期望从 xterm 获得的。 或者 xterm 终端预计不会发送这些内容或其他内容...（Del 键在 xterm 中确实有效，但是，如果您对其进行配置在 ZSH 中）。 另请注意，您的数字键盘在 Vim 中表现得很有趣，例如在 xterm 终端中。

解决方案是将 Putty 配置为发送另一种终端类型。 我尝试过 xterm-color 和 linux。 xterm-color 修复了 Home/End 问题，但数字键盘仍然很有趣。 将其设置为 linux 解决了这两个问题。

您可以在 Putty 中的“连接”->“连接”下设置终端类型。 数据。 不要试图在 .zshrc 中使用 export TERM=linux 设置终端类型，这是错误的。 终端类型应由您的终端应用程序指定。 例如，如果您从 Mac 机与 Mac SSH 客户端进行连接，它可以设置自己的终端类型。

请注意，TERM 指定您的终端类型，与您要连接的主机无关。 我可以在 Putty 中将终端类型设置为 linux 并毫无问题地连接到 FreeBSD 服务器。

所以，解决这两个问题就可以了:)