MSIL 和 Java 字节码之间的区别？

Question

我是 .Net 的新手，我想首先了解基础知识。 MSIL 和 Java 字节码有什么区别？

Answer 1

CIL 又名 MSIL 旨在人类可读。 Java 字节码不是。

将 Java 字节码视为不存在的硬件（但由 JVM 模拟）的机器代码。

CIL 更像是汇编语言——距离机器代码一步之遥，同时仍然是人类可读的。

Answer 2

Serge Lidin 撰写了一本关于 MSIL 详细信息的不错的书：Expert .NET 2.0 IL Assembler。 我还能够通过使用 .NET Reflector 和 Ildasm（教程）。

MSIL 和 Java 字节码之间的概念非常相似。

Answer 3

没有那么多差异。 两者都是您编写的代码的中间格式。 执行时，虚拟机将执行托管的中间语言，这意味着虚拟机控制变量和调用。 甚至有一种我现在不记得的语言可以以同样的方式在 .Net 和 Java 上运行。

基本上，它只是同一事物的另一种格式

编辑：找到语言（除了 Scala）：它是 FAN（http:// www.fandev.org/），看起来很有趣，但还没时间评估

Answer 4

同意，差异很小，作为初学者可以忽略。 如果您想从基础开始学习 .Net，我建议您查看公共语言基础结构和公共类型系统。

Answer 5

我认为MSIL不应该与Java字节码相比较，而是“组成Java字节码的指令”。

没有反汇编的java字节码的名称。 “Java Bytecode”应该是一个非官方的别名，因为我在官方文档中找不到它的名字。
Java 类文件反汇编器 说

打印出类中每个方法的反汇编代码，即组成 Java 字节码的指令。 这些都记录在 Java 虚拟机规范中。

“Java VM指令”和“MSIL”都被组装成.NET字节码和Java代码，这些都是人类无法阅读的。

Answer 6

它们本质上在做同样的事情，MSIL 是 Microsoft 版本的 Java 字节码。

内部的主要区别是：

1. 字节码是为编译和解释而开发的，而 MSIL 是为 JIT 编译而明确开发的
2. MSIL 是为支持多种语言（C# 和 VB.NET 等）而开发的，而字节码只是为 Java 编写的，从而导致字节码在语法上比 IL 与任何特定 .NET 语言在语法上更类似于 Java
3. MSIL 在值和引用类型之间有更明确的描述

更多信息和详细比较可以在 K John Gough 的这篇文章（后记文档）

Answer 7

首先我要说的是，我不认为 Java 字节码和 MSIL 之间的细微差别会困扰 .NET 开发新手。 它们都具有相同的目的，即定义一个抽象目标机器，该目标机器是最终使用的物理机器之上的一层。

MSIL 和 Java 字节码非常相似，实际上有一个名为 Grasshopper 它将 MSIL 转换为 Java 字节码，我是 Grasshopper 开发团队的一员，所以我可以分享一些我的（褪色的）知识。
请注意，当 .NET Framework 2.0 发布时，我就停止了这方面的工作，因此其中一些内容可能不再正确（如果是这样，请发表评论，我会更正它）。

• .NET 允许用户定义的类型具有与常规引用语义 (struct) 不同的值语义。
• .NET支持无符号类型，这使得指令集更加丰富。
• Java 在字节码中包含方法的异常规范。 虽然异常规范通常仅由编译器强制执行，但如果使用默认类加载器以外的类加载器，则可能由 JVM 强制执行。
• .NET 泛型用 IL 表示，而 Java 泛型仅使用类型擦除。
• .NET 属性在 Java 中没有等效项（这仍然是真的吗？）。
• .NET enum 只不过是整数类型的包装器，而 Java enums 几乎是完全成熟的类（感谢 网友评论）。
• .NET 有 out 和 ref 参数。

还有其他语言差异，但大多数都不是在字节码级别上表达的，例如，如果没记错的话，Java 的非静态内部类（.NET 中不存在）不是一个字节码功能时，编译器会为内部类的构造函数生成一个附加参数并传递外部对象。 .NET lambda 表达式也是如此。

Answer 8

CIL（MSIL 的专有名称）和 Java 字节码的相同点多于不同点。 但存在一些重要的区别：

1) CIL 从一开始就被设计为作为多种语言的目标。 因此，它支持更丰富的类型系统，包括有符号和无符号类型、值类型、指针、属性、委托、事件、泛型、具有单个根的对象系统等等。 CIL 支持初始 CLR 语言（C# 和 VB.NET）不需要的功能，例如全局函数和尾调用优化 。 相比之下，Java 字节码被设计为 Java 语言的目标，并反映了 Java 本身的许多限制。 使用Java字节码编写C或Scheme会困难得多。

2) CIL 旨在轻松集成到本机库和非托管代码中

3) Java 字节码设计为可解释或编译，而 CIL 的设计仅假设 JIT 编译。 也就是说，Mono 的初始实现使用了解释器而不是 JIT。

4) CIL 被设计（并指定）为人类可读可写的汇编语言直接映射到字节码形式的形式。 我相信 Java 字节码（顾名思义）只能是机器可读的。 当然，Java字节码相对容易反编译回原始Java，并且如下所示，它也可以被“反汇编”。

我应该指出，JVM（其中大多数）比 CLR（其中任何一个）优化程度更高。 因此，原始性能可能是首选针对 Java 字节码的一个原因。 但这是一个实现细节。

有人说 Java 字节码是为多平台设计的，而 CIL 是为 Windows 设计的。 不是这种情况。 .NET 框架中有一些“Windows”主义，但 CIL 中没有。

作为上面第 4) 点的示例，我不久前编写了一个 Java 到 CIL 编译器的玩具。 如果您向该编译器提供以下 Java 程序：

class Factorial{
    public static void main(String[] a){
    System.out.println(new Fac().ComputeFac(10));
    }
}

class Fac {
    public int ComputeFac(int num){
    int num_aux ;
    if (num < 1)
        num_aux = 1 ;
    else 
        num_aux = num * (this.ComputeFac(num-1)) ;
    return num_aux ;
    }
}

我的编译器将输出以下 CIL：

.assembly extern mscorlib { }
.assembly 'Factorial' { .ver  0:0:0:0 }
.class private auto ansi beforefieldinit Factorial extends [mscorlib]System.Object
{
   .method public static default void main (string[] a) cil managed
   {
      .entrypoint
      .maxstack 16
      newobj instance void class Fac::'.ctor'()
      ldc.i4 3
      callvirt instance int32 class Fac::ComputeFac (int32)
      call void class [mscorlib]System.Console::WriteLine(int32)
      ret
   }
}

.class private Fac extends [mscorlib]System.Object
{
   .method public instance default void '.ctor' () cil managed
   {
      ldarg.0
      call instance void object::'.ctor'()
      ret
   }

   .method public int32 ComputeFac(int32 num) cil managed
   {
      .locals init ( int32 num_aux )
      ldarg num
      ldc.i4 1
      clt
      brfalse L1
      ldc.i4 1
      stloc num_aux
      br L2
   L1:
      ldarg num
      ldarg.0
      ldarg num
      ldc.i4 1
      sub
      callvirt instance int32 class Fac::ComputeFac (int32)
      mul
      stloc num_aux
   L2:
      ldloc num_aux
      ret
   }
}

这是一个有效的 CIL 程序，可以将其输入到像 ilasm.exe 这样的 CIL 汇编器中以创建可执行文件。 正如您所看到的，CIL 是一种完全人类可读可写的语言。 您可以在任何文本编辑器中轻松创建有效的 CIL 程序。

您还可以使用 javac 编译器编译上面的 Java 程序，然后通过 javap“反汇编器”运行生成的类文件，得到以下内容：

class Factorial extends java.lang.Object{
Factorial();
  Code:
   0:   aload_0
   1:   invokespecial   #1; //Method java/lang/Object."<init>":()V
   4:   return

public static void main(java.lang.String[]);
  Code:
   0:   getstatic   #2; //Field java/lang/System.out:Ljava/io/PrintStream;
   3:   new #3; //class Fac
   6:   dup
   7:   invokespecial   #4; //Method Fac."<init>":()V
   10:  bipush  10
   12:  invokevirtual   #5; //Method Fac.ComputeFac:(I)I
   15:  invokevirtual   #6; //Method java/io/PrintStream.println:(I)V
   18:  return

}

class Fac extends java.lang.Object{
Fac();
  Code:
   0:   aload_0
   1:   invokespecial   #1; //Method java/lang/Object."<init>":()V
   4:   return

public int ComputeFac(int);
  Code:
   0:   iload_1
   1:   iconst_1
   2:   if_icmpge   10
   5:   iconst_1
   6:   istore_2
   7:   goto    20
   10:  iload_1
   11:  aload_0
   12:  iload_1
   13:  iconst_1
   14:  isub
   15:  invokevirtual   #2; //Method ComputeFac:(I)I
   18:  imul
   19:  istore_2
   20:  iload_2
   21:  ireturn
}

javap< /code> 输出不可编译（据我所知），但如果将其与上面的 CIL 输出进行比较，您会发现两者非常相似。