写了个操作系统从实模式跳转到保护模式的过程，不知道对不对

Question

1.在一个固定地址处处创建GDT，设置堆栈积存器地址
2.读取硬盘中的load.s到0x0处
3.打开A20地址线，设置积存器PE位，进入保护模式
4.跳转到0x0处执行load.s

注：设load.s为内核程序

Answer 1

原帖由 shineyear 于 2007-5-24 13:39 发表于 1楼  
1.在一个固定地址处处创建GDT，设置堆栈积存器地址
2.读取硬盘中的load.s到0x0处
3.打开A20地址线，设置积存器PE位，进入保护模式
4.跳转到0x0处执行load.s

注：设load.s为内核程序

进入保护模式之前，要先为保护模式建立必要的环境。GDT 是其中一个，另一个是 IDT

Answer 2

我怎么感觉IDT并不是必须的呢？

Answer 3

关了中断就可以不用idt,但这样比较无趣。

Answer 4

请问我可不可以在启动的时候（跳入保护模式之前）把内核加载到0X0000位置呢？我尝试着这么做了但好象不行，是不是必须关中断才行？

Answer 5

在pc中，0x0000处存放中断向量表，不能加载到那里，建议先在google上搜一下bios初始化完成后的内存布局

Answer 6

原帖由 shineyear 于 2007-5-25 11:23 发表于 3楼  
我怎么感觉IDT并不是必须的呢？

什么叫保护模式，要理解它的真正意义才行呀。当然，你直接将 CR0.PE 直接置 1 可以让处理器处于 Protected mode，但这样是不能正常工作的。描述符表及描述符的意义在于处理器可以提供别代码的几个该问权限级别。
从物理上来说，在 protected mode 下，执行 int 指令必须经过 IDT 该问中断例程。你的系统从来绝对不执行 INT 么？

Answer 7

我还是把代码贴上来吧

boot.s

.text
.globl    start
.set CODE_SEL, 0x08      
.set DATA_SEL, 0x10      
.set IDT_ADDR, 0x80000   

.set IDT_SIZE, (256*  
.set GDT_ADDR, (IDT_ADDR+IDT_SIZE)   

.set GDT_ENTRIES, 5      

.set GDT_SIZE, (8*GDT_ENTRIES)

.set KERNEL_SECT, 2      
.set STACK_BOT, 0xa0000   

.code16
start:
        jmp        code
gdt:   
        .quad    0x0000000000000000
        .quad    0x00cf9a000000ffff
        .quad    0x00cf92000000ffff
        .quad    0x0000000000000000
        .quad    0x0000000000000000
gdt_48:
        .word    .-gdt-1
        .long    GDT_ADDR
code:
        xorw    %ax,    %ax
        movw    %ax,    %ds   
        movw    %ax,    %ss   
        movw    $0x1000,%sp   

        movw    $0x0000,%ax
        movw    %ax,    %es
        xorw    %bx,    %bx   
        movw    $KERNEL_SECT,%cx
        movw    $1,     %si   
rd_kern:
        call    read_sect   
        addw    $512,    %bx
        incw    %si
        loop    rd_kern

        cli                 

        cld                    

        xorw    %ax,    %ax
        movw    %ax,    %ds   

        movw    $GDT_ADDR>>4,%ax   
        movw    %ax,    %es      
        movw    $gdt,   %si
        xorw    %di,    %di         
        movw    $GDT_SIZE>>2,%cx      
        rep
        movsl

enable_a20:        
        inb    $0x64,   %al   
        testb  $0x2,    %al
        jnz    enable_a20
        movb   $0xbf,   %al
        outb   %al,     $0x64

        lgdt    gdt_48            
     
        movl   %cr0,    %eax
        orl    $0x1,    %eax
        movl   %eax,    %cr0      

        ljmp   $CODE_SEL, $0x0

read_sect:
        pushw   %ax
        pushw   %cx
        pushw   %dx
        pushw   %bx

        movw    %si,    %ax        
        xorw    %dx,    %dx
        movw    $18,    %bx   

        divw    %bx
        incw    %dx
        movb    %dl,    %cl   
        xorw    %dx,    %dx
        movw    $2,     %bx   
        divw    %bx

        movb    %dl,    %dh   
        xorb    %dl,    %dl   
        movb    %al,    %ch   

        popw    %bx         
rp_read:
        movb    $0x1,   %al   
        movb    $0x2,   %ah
        int     $0x13
        jc      rp_read
        popw    %dx
        popw    %cx
        popw    %ax
        ret

.org    0x1fe,  0x90
.word   0xaa55

load.s

a.text
.globl        pm_mode
.org 0

pm_mode:
        movl    $0x10,        %eax
        movw    %ax,    %ds
        movw    %ax,    %es
        movw    %ax,    %fs
        movw    %ax,    %gs
        movw    %ax,    %ss
        movl    $0xa0000,        %esp

cld

movb    $0x07, %al
movl    $msg,  %esi
movl    $0xb8000,%edi

1:
        cmp     $0,    (%esi)
        je      1f
        movsb
        stosb
        jmp     1b
1:      jmp     1b
msg:
                .string "Hello World!\x0"

Answer 8

我在进入保护模式之后只是让他打印了一个HELLO WORLD，没有用INT
但是我现在这段程序就是运行不起来，不知道怎么搞的

Answer 9

终于找到原因了，是因为我把0X0000处的BIOS中断表给覆盖了，改了加载地址和GDT地址，下面把测试通过的代码贴上来，请指教

boot.s

1. .text
2. .globl    start
3. .set CODE_SEL, 0x08     #选择子cs
4. .set DATA_SEL, 0x10       #选择子ds
5. .set IDT_ADDR, 0x80000    #IDT位置
9. .set IDT_SIZE, (256*8)  
10. .set GDT_ADDR, (IDT_ADDR+IDT_SIZE)   #GDT位置（紧挨着IDT）
15. .set GDT_ENTRIES, 5      #GDT数量
19. .set GDT_SIZE, (8*GDT_ENTRIES)
21. .set KERNEL_SECT, 2      #需要读取的扇区数
22. .set STACK_BOT, 0xa0000   #最终的堆栈位置
28. .code16
29. start:
30.         jmp        code
32. #声明GDT
33. gdt:   
34.         .quad    0x0000000000000000
35.         .quad    0x00cf9a010000ffff # cs
36.         .quad    0x00cf92000000ffff # ds
37.         .quad    0x0000000000000000
38.         .quad    0x0000000000000000
40. #48位的GDT描述
41. gdt_48:
42.         .word    .-gdt-1 #长度
43.         .long    GDT_ADDR #位置
45. code:
46.         xorw    %ax,    %ax
47.         movw    %ax,    %ds   
48.         movw    %ax,    %ss   
49.         movw    $0x1000,%sp   #设置临时的堆栈位置
51. #将软盘中除启动扇区外的其他内容读到 es:bx处
53.         movw    $0x1000,%ax  
54.         movw    %ax,    %es
55.         xorw    %bx,    %bx   
56.         movw    $KERNEL_SECT,%cx  #需要读取多少扇区
57.         movw    $1,     %si   #跳过启动扇区
58. rd_kern:
59.         call    read_sect    #读取扇区的函数（网上找的）
60.         addw    $512,    %bx
61.         incw    %si
62.         loop    rd_kern
66.         cli                 
68.         cld                    
73.         xorw    %ax,    %ax
74.         movw    %ax,    %ds   
76. #将GDT移动到指定位置
77.         movw    $GDT_ADDR>>4,%ax   
78.         movw    %ax,    %es      
79.         movw    $gdt,   %si
80.         xorw    %di,    %di         
81.         movw    $GDT_SIZE>>2,%cx      
82.         rep
83.         movsl
86. #打开A20地址线
87. enable_a20:        
88.         inb    $0x64,   %al   
89.         testb  $0x2,    %al
90.         jnz    enable_a20
91.         movb   $0xbf,   %al
92.         outb   %al,     $0x64
94. #加载GDT
95.         lgdt    gdt_48      
97. #设置PE位      
98.      
99.         movl   %cr0,    %eax
100.         orl    $0x1,    %eax
101.         movl   %eax,    %cr0      
104. #跳到保护模式（跳转到了被加载的扇区位置）
106.         ljmp   $CODE_SEL, $0x0
108. read_sect:
109.         pushw   %ax
110.         pushw   %cx
111.         pushw   %dx
112.         pushw   %bx
114.         movw    %si,    %ax        
115.         xorw    %dx,    %dx
116.         movw    $18,    %bx   
119.         divw    %bx
120.         incw    %dx
121.         movb    %dl,    %cl   
122.         xorw    %dx,    %dx
123.         movw    $2,     %bx   
124.         divw    %bx
126.         movb    %dl,    %dh   
127.         xorb    %dl,    %dl   
128.         movb    %al,    %ch   
130.         popw    %bx         
131. rp_read:
132.         movb    $0x1,   %al   
133.         movb    $0x2,   %ah
134.         int     $0x13
135.         jc      rp_read
136.         popw    %dx
137.         popw    %cx
138.         popw    %ax
139.         ret
142. .org    0x1fe,  0x90
143. .word   0xaa55

复制代码

load.s

1. .text
2. .globl        pm_mode
3. .org 0
5. pm_mode:
6.         movl    $0x10,        %eax
7.         movw    %ax,    %ds
8.         movw    %ax,    %es
9.         movw    %ax,    %fs
10.         movw    %ax,    %gs
11.         movw    %ax,    %ss
12.         movl    $0xa0000,        %esp
14. cld
16. movb    $0x07, %al
17. movl    $msg,  %esi
18. movl    $0xb8000,%edi
20. 1:
21.         cmp     $0,    (%esi)
22.         je      1f
23.         movsb
24.         stosb
25.         jmp     1b
26. 1:      jmp     1b
27. msg:
28.                 .string "Hello World!\x0"

复制代码

as -o boot.o boot.s
ld --oformat binary -N -e start -Ttext 0x7c00 -o boot.img boot.o
as -o load.o load.s
ld --oformat binary -N -e pm_mode -Ttext 0x10000 -o load.img load.o
cat boot.img load.img > final.img

用VMWARE加载 final.img 即可

[ 本帖最后由 shineyear 于 2007-5-30 11:13 编辑 ]