Question

材质和光照参数用来控制内置顶点光照。顶点光照是对每个顶点都进行了计算的标准的 Direct3D/OpenGL 光照模式。Lighting on 可打开照明。光照受 Material 块、ColorMaterial 和 SeparateSpecular 命令影响。

逐像素光照通常与自定义顶点/片元程序一起执行且不使用顶点光照。您可以对此不使用此处描述的任何一个命令，而是定义您自己的顶点和片元程序，从而可以自己进行光照、贴图和其他一切操作。

“顶点着色和光照”(Vertex Coloring & Lighting) 是对所有渲染的几何结构计算的第一个效果。它在顶点层级上运行，并在应用纹理前计算出使用的底色。

语法

最高层级命令控制是否使用固定功能光照和一些配置选项。主要设置位于材质块 (Material Block)，以下将进一步详述。

Color Color

将对象设置为纯色。颜色是圆括号中的 4 个 RGBA 值，或者是方括号中的颜色属性名称。

Material { Material Block }

材质块用于定义对象的材质属性。

Lighting On | Off

为使材质块中定义的设置有效，必须使用 Lighting On 命令启用照明。但如果照明关闭，则颜色会直接从 Color 命令中获取。

SeparateSpecular On | Off

此命令会将高光光照添加至着色器通道的末尾，因此贴图对高光光照没有影响。只在使用 Lighting On 命令时有效。

ColorMaterial AmbientAndDiffuse | Emission

使用逐顶点颜色，而不是材质中设置的颜色。AmbientAndDiffuse 替材质的环境 (Ambient) 值和漫射 (Diffuse) 值；Emission 代替材质的发射 (Emission) 值。

材质块 (Material Block)

材质块包含材质对光照如何反应的设置。这些属性中的任意一项都可忽略，一旦忽略，它们就默认为黑色（即无效果）。

Diffuse Color

漫射颜色分量。这是对象的底色。

Ambient Color

环境颜色分量。这是对象在被渲染设置中设置的环境光照射时的颜色。

Specular Color

对象高光亮点的颜色。

Shininess Number

亮点的清晰度在 0 和 1 之间。清晰度为 0 时，您将得到一个看起来像漫射光照的巨大亮点，为 1 时，您将得到一个很小的斑点。

Emission Color

没有光照时对象的颜色。

照射对象的光的全色是：

  Ambient * 渲染设置环境设置 +
  （光颜色 * 漫射 (Diffuse) + 光颜色 * 高光 (Specular)） + 发射 (Emission)

方程式（圆括号内）的光照部分对所有照射对象的光重复。

通常，您要使漫射 (Diffuse) 颜色与环境 (Ambient) 颜色一致（所有内置的 Unity 着色器都将如此）。

示例

始终用纯红色渲染对象：

Shader "Solid Red" {
    SubShader {
        Pass { Color (1,0,0,0) }
    }
} 

将对象渲染为白色并应用顶点光照的基础着色器：

Shader "VertexLit White" {
    SubShader {
        Pass {
            Material {
                Diffuse (1,1,1,1)
                Ambient (1,1,1,1)
            }
            Lighting On
        }
    }
} 

将材质颜色添加为材质检视器中可见的属性的扩展版本：

Shader "VertexLit Simple" {
    Properties {
        _Color ("Main Color", COLOR) = (1,1,1,1)
    }
    SubShader {
        Pass {
            Material {
                Diffuse [_Color]
                Ambient [_Color]
            }
            Lighting On
        }
    }
} 

最后，完备的顶点光照着色器（也可参阅设置纹理 (SetTexture)参考页面）：

Shader "VertexLit" {
    Properties {
        _Color ("Main Color", Color) = (1,1,1,0)
        _SpecColor ("Spec Color", Color) = (1,1,1,1)
        _Emission ("Emmisive Color", Color) = (0,0,0,0)
        _Shininess ("Shininess", Range (0.01, 1)) = 0.7
        _MainTex ("Base (RGB)", 2D) = "white" {}
    }
    SubShader {
        Pass {
            Material {
                Diffuse [_Color]
                Ambient [_Color]
                Shininess [_Shininess]
                Specular [_SpecColor]
                Emission [_Emission]
            }
            Lighting On
            SeparateSpecular On
            SetTexture [_MainTex] {
                Combine texture * primary DOUBLE, texture * primary
            }
        }
    }
}