Question

全部显示

插入对标题、书签、脚注、尾注或定义了题注标签的项（如公式、图表或表格）的交叉引用。

expression.InsertCrossReference(ReferenceType, ReferenceKind, ReferenceItem, InsertAsHyperlink, IncludePosition)

expression 必需。该表达式返回“应用于”列表中的一个对象。

ReferenceTypeVariant 类型，必需。插入交叉引用的项目的类型，可以是 WdReferenceType 或 WdCaptionLabelID 常量之一，或用户定义的题注标签。

WdReferenceType 可以是下列 WdReferenceType 常量之一：

wdRefTypeBookmark

wdRefTypeEndnote

wdRefTypeFootnote

wdRefTypeHeading

wdRefTypeNumberedItem

WdCaptionLabelID 可以是下列 WdCaptionLabelID 常量之一：

wdCaptionEquation

wdCaptionFigure

wdCaptionTable

ReferenceKindWdReferenceKind，必需。交叉引用中包括的信息。

WdReferenceKind 可以是下列 WdReferenceKind 常量之一：

wdContentText

wdEndnoteNumber

wdEndnoteNumberFormatted

wdEntireCaption

wdFootnoteNumber

wdFootnoteNumberFormatted

wdNumberFullContext

wdNumberNoContext

wdNumberRelativeContext

wdOnlyCaptionText

wdOnlyLabelAndNumber

wdPageNumber

wdPosition

ReferenceItemVariant 类型，必需。如果 ReferenceType 为 wdRefTypeBookmark，则本参数指定一个书签名。对于 ReferenceType 的所有其他值，本参数将指定“交叉引用”对话框“引用类型”框中的项的编号或名称。用 GetCrossReferenceItems 方法可返回对本参数有效的项目名称列表。

InsertAsHyperlinkVariant 类型，可选。如果为 True，则将交叉引用作为超链接插入到引用的项中。

IncludePositionVariant 类型，可选。如果为 True，则根据引用项相对于交叉引用的位置，插入“above”或“below”。

说明

如果将 ReferenceKind 指定为 wdPageNumber 的值，则为了看到正确的交叉引用信息，可能需要对文档重新分页。

示例

本示例在活动文档的开头插入一个交叉引用，它引用了包含文档中第一处书签的页。

Set myRange = ActiveDocument.Range(Start:=0, End:=0)
myBookmarks = ActiveDocument _
    .GetCrossReferenceItems(wdRefTypeBookmark)
With myRange
    .InsertBefore "Page "
    .Collapse Direction:=wdCollapseEnd
    .InsertCrossReference ReferenceType:=wdRefTypeBookmark, _
        ReferenceKind:=wdPageNumber, ReferenceItem:=myBookmarks(1)
End With

本示例插入一个句子，其中包含两个交叉引用：一个引用标题文字，另一个引用标题文字出现的页。

With Selection
    .Collapse Direction:=wdCollapseStart
    .InsertBefore "For more information, see "
    .Collapse Direction:=wdCollapseEnd
    .InsertCrossReference ReferenceType:=wdRefTypeHeading, _
        ReferenceKind:=wdContentText, ReferenceItem:=1
    .InsertAfter " on page "
    .Collapse Direction:=wdCollapseEnd
    .InsertCrossReference ReferenceType:=wdRefTypeHeading, _
        ReferenceKind:=wdPageNumber, ReferenceItem:=1
    .InsertAfter "."
End With