Question

data_type ::=       // 引用自附录A.2.2.1
    ...
  | struct_union [packed [signing]] {struct_union_member {struct_union_member}}
        {packed_dimension}

struct_union_member ::=
    {attribute_instance} data_type_or_void list_of_variable_identifiers;

data_type_or_void ::= data_type | void

struct_union ::= struct | union [tagged]

语法3-4 结构体与联合体（摘录自附录A）

结构体和联合体的声明遵从C语言的语法，但在“{”之前没有可选的结构体标签。

struct {
    bit[7:0] opcode;
    bit[23:0] addr;
} IR //匿名结构体，定义变量IR。

IR.opcode = 1; // 设置IR的域

其它一些声明结构体和联合体的例子如下：

typedef struct {
    bit[7:0] opcode;
    bit[23:0] addr;
} instruction;    // 命名的结构体类型

instruction IR;   // 定义变量

typedef union {
    int i;
    shortreal f;
} num;            // 命名的联合体类型

num n;

n.f = 0.0;        // 以浮点数格式设置n

typedef struct {
    bit isfloat;
    union {
        int i;
        shortreal f;
    } n;          // 匿名类型
} tagged_st;      // 命名结构体

tagged_st a[9:0]; // 结构体数组

一个结构体可以作为一个整体赋值，并且可以作为一个整体向/从一个函数或任务传递。

第2.8节讨论了如何为结构体赋初始值。

一个压缩结构体包含了位域，它们在存储器中被无缝地压缩在一起。这也就意味着，它们可以方便地转换到位向量，或从位向量转换。一个非压缩结构体具有独立于实现的压缩形式，通常与C编译器相匹配。

与压缩数组类似，在使用算术和逻辑操作符时，一个压缩结构体可以当作一个整体使用。第一个指定的成员成为最高有效位，后续的成员以降序排列。结构体在声明的时候可以使用packed关键字，根据期望的算术行为，packed关键字之后可以跟着signed或unsigned关键字。缺省情况下，结构体是无符号的。

struct packed signed {
    int a;
    shortint b;
    byte c;
    bit [7:0] d;
} pack1; // 有符号的两态值

struct packed unsigned {
    time a;
    integer b;
    logic [31:0] c;
} pack2; // 无符号的四态值

只要压缩结构体内的数据类型存在4态数据类型，那么整个结构体就被当作是4态数据类型，并且其中的任何2态成员都会使用强制类型转换进行转换。压缩结构体的一个或更多的位可以使用[n-1:0]的编号方法来选择，就好像它是一个压缩数组一样。

pack1[15:8] // c

非整数数据类型（例如real和shortreal）以及非压缩数组不允许在压缩结构体或压缩联合体中使用。

一个压缩结构体可以与typedef一起使用。

typedef struct packed { // 缺省是无符号的
    bit [3:0] GFC;
    bit [7:0] VPI;
    bit [11:0] VCI;
    bit CLP;
    bit [3:0] PT;
    bit [7:0] HEC;
    bit [47:0][7:0] Payload;
    bit [2:0] filler;
} s_atmcell;

一个压缩联合体所包含的成员只能是压缩结构体、压缩数组或者是整数数据类型，并且所有的成员必须具有相同的尺寸（而对于一个非压缩联合体，其成员可以具有不同的尺寸）。这就可以保证你可以读回作为另外一个成员写入的联合体成员。在使用算术和逻辑操作符时，一个压缩联合体可以当作一个整体使用，并且它的行为由signed或unsigned关键字确定。如果没有显式指明signed或unsigned关键字，那么它缺省是unsigned的。如果一个压缩联合体包含了2态成员和4态成员，那么整个联合体是4态的。此时，如果读取2态成员，那么它具有一个隐式的4态到2态的转换；如果写入2态成员，则具有一个隐式的2态到4态的转换。

例如，一个联合体可以使用不同的访问宽度进行访问：

typedef union packed { // 缺省是无符号的
    s_atmcell acell;
    bit [423:0] bit_slice;
    bit [52:0][7:0] byte_slice;
} u_atmcell;

u_atmcell u1;

byte b;
bit [3:0] nib;
b = u1.bit_slice[415:408];    // 与b = u1.byte_slice[51];相同
nib = u1.bit_slice[423:420];  // 与nib = u1.acell.GFC;相同

注意：对一个成员的写入与对另外一个成员的读出独立于计算机的字节顺序，这与一个普通的联合体或普通的结构体不同，这些普通的联合体或普通的结构体与C语言兼容并且以降地址的顺序排列成员。

在非压缩结构体中不允许使用符号，因此下面的声明被认为是非法的。

typedef struct signed {
    int f1;
    logic f2;
} sIllegalSignedUnpackedStructType; // 非法声明

联合体中声明中具有限定词tagged的联合体声明为标签联合体，它是一个类型检查的联合体。一个普通的（不带有标签的）联合体可以使用一个成员类型的值进行更新，而以另外一个成员类型进行读取，这有可能成为类型漏洞。一个标签联合体既储存了成员值也储存了一个标签，也就是说，使用额外的位来表示当前的成员名字。标签和值仅仅能够通过一个静态的类型检查标签联合体表达式来（参见7.15节）一起更新。成员值仅仅可以通过与当前标签值一致的类型来读取（也就是成员名）。这样，我们就不可能以一种类型来存储值，而以另外一种类型来错误地解释成员的各位。

除了类型的安全性之外，相对于使用显式标签来跟踪联合体的代码而言，将成员名以标签的方式使用也可以使代码更加简单并且更小。标签联合体还可以用在模式匹配（参见8.4节）当中，这会更进一步改进代码的可读性。

在标签联合体中，当所有信息都存在于标签本身的时候，成员还可以使用void类型来声明。就像在下面的例子中包含一个整数和一个有效位一样：

typedef union tagged {
    void Invalid;
    int Valid;
} VInt;

在上面的例子中，一个VInt类型的值或者是无效的并没有包含任何东西，或者是有效的并包含一个int类型的值。7.15节描述了如何构建这种类型的值，并且描述了怎样才能够确保不会从一个当前具有Invalid标签的VInt值中读出一个整数值。

例子：

typedef union tagged {
    struct {
        bit [4:0] reg1, reg2, regd;
    } Add;

    union tagged {
        bit [9:0] JmpU;
        struct {
            bit [1:0] cc;
            bit [9:0] addr;
        } JmpC;
    } Jmp;
} Instr;

一个Instr类型的值或者是一个Add指令或者是一个Jmp指令。如果是Add指令，它包含了三个5位寄存器域；如果是Jmp指令，它或者是一个无条件跳转或者是一个有条件跳转。如果是无条件跳转，它包含了一个10位的目的地址。如果是有条件跳转，它包含了一个2位的条件码寄存器域和一个10位的目的地址。7.15节描述了如何构建Instr类型的值 ，并且描述了如何才能使指令必须具有Jmp操作码和JmpC子操作码（例如为了读取cc域）。

当packed限定词使用在标签联合体的时候，所有的成员必须是压缩数据类型，但它们不必具有相同的尺寸。一个压缩标签联合体的标准表示方法如下：

• 尺寸总是等于所需的位的数目以便表示标签加上最大的成员尺寸；
• 标签的尺寸是编码所有成员名字所需的最小的位数目（例如5到8个成员需要3个标签位）；
• 标签位总是向左调整（也就是向最高有效位的方向调整）；
• 对于每一个成员，成员位总是向右调整（也就是向最低有效位的方向调整）；
• 在标签位与成员位之间的位是未定义的。在具有void成员的极端情况下，只有标签位是有意义的，所有其它的位都是未定义的。

这种表示机制递归地适用于任何嵌套的标签联合体。

例子：如果VInt类型定义具有packed限定词，那么InValid和Valid值分别具有如下的布局。

标签为0表示无效，标签为1表示有效。

例子：如果Instr类型具有packed限定词，那么它的值具有如下的布局：

对外层标签来讲，0表示Add，1表示Jmp；

对内层标签来讲，0表示JmpU，1表示JmpC。