Question

全部显示

从选定内容，或者查找或替换操作的格式限定中删除文本或段落格式设置。

expression.ClearFormatting

expression 必需。该表达式返回“应用于”列表中的一个对象。

说明

若要确认在查找或替换操作中不包含作为条件的格式设置，请在执行操作前使用该方法。

示例

当应用于 Selection 对象时。

本示例从活动文档中删除所有文字和段落格式设置。

Sub ClrFmtg()

    ActiveDocument.Select
    Selection.ClearFormatting

End Sub

本示例从活动文档的第二至第四段删除所有文字和段落的格式设置。

Sub ClrFmtg2()

    ActiveDocument.Range(Start:=ActiveDocument.Paragraphs(2).Range.Start, _
        End:=ActiveDocument.Paragraphs(4).Range.End).Select
    Selection.ClearFormatting

End Sub

当应用于 Replacement 对象时。

本示例在将活动文档中的单词“Inc.”替换为“incorporated”之前，清除查找或替换条件的格式设置。

Sub ClrFmtgReplace()

    Dim rngTemp As Range

    Set rngTemp = ActiveDocument.Content
    With rngTemp.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .MatchWholeWord = True
        .Execute FindText:="Inc.", ReplaceWith:="incorporated", _
            Replace:=wdReplaceAll
    End With

End Sub

当应用于 Find 对象时。

本示例在搜索选定内容之前从查找条件中取消格式限定。如果找到了加粗的“Hello”，则选定整个段落，并复制到“剪贴板”。

Sub ClrFmtgFind()

    With Selection.Find
        .ClearFormatting
        .Font.Bold = True
        .Execute FindText:="Hello", Format:=True, Forward:=True
        If .Found = True Then
            .Parent.Expand Unit:=wdParagraph
            .Parent.Copy
        End If
    End With

End Sub