Question

如果定义一个基本类，它的对象在实例化的时候可以具有不同的数组尺寸或数据类型，那么这种功能通常很有用。我们可以不必为每一个尺寸或类型编写相同的代码，并且可以为本质上不同并且不可互换的对象使用同一个说明（这与C++的类模板类似）。

普通的Verilog参数机制可以用来参数化一个类：

class vector #(int size = 1);
    bit [size-1:0] a;
endclass

接下来，这个类的实例就可以像模块或接口一样实例化：

vector #(10) vten;        // 尺寸为10的vector对象
vector #(.size(2)) vtwo;  // 尺寸为2的vector对象
typedef vector#(4) Vfour; // vector尺寸为4的类

当将类型作为参数的时候，这个功能特别有用：

class stack #(type T = int);
    local T items[];

    task push(T a);
        ...
    endtask

    task pop(ref T a);
        ...
    endtask
endclass

上面的类定义了一个基本的stack类，它可以使用任意类型实例化：

stack is;             // 缺省：int类型的堆栈
stack#(bit[1:10]) bs; // 10位向量的堆栈
stack#(real) rs;      // 实数的堆栈

任何类型都可以用作参数，包括用户定义的类型，例如类或结构体。

基本类和真实参数值的组合被称作一个特例（或变种）。类的每一个特例又具有一组单独的静态成员变量（这与C++模板类一致）。为了在多个类特例间共享静态成员变量，这些变量必须放置在一个非参数化的基类中。

class vector #(int size = 1);
    bit [size-1:0] a;
    static int count = 0;

    function void disp_count();
        $display("count: %d of size %d", count, size);
    endfunction
endclass

上面例子中的变量count只能通过对应的disp_count方法访问。对于vector类的每一个特例，count都具有它自己的唯一的拷贝。

为了避免必须在声明中或产生该类的参数中重复特例，我们应该使用typedef：

typedef vector#(4) Vfour;
typedef stack#(Vfour) Stack4;
Stack4 s1, s2;  // 声明Stack4类型的对象

一个参数化的类可以扩展另外一个参数化的类，例如：

class C #(type T = bit); ... endclass           // 基类
class D1 #(type P = real) extends C;            // T的类型为bit（缺省）
class D2 #(type P = real) extends C #(integer); // T的类型为integer
class D3 #(type P = real) extends C #(P);       // T的类型为P

D1类使用基类的缺省类型（bit）参数扩展了基类C。 D2类使用一个integer参数扩展了基类。D3类使用参数化类型（P，它使得扩展类被参数化）扩展了基类C。