Question

表面着色器可在一定程度上支持 DirectX 11 GPU 密铺 (Tessellation)。理念如下：

• 密铺 (tessellation) 由 tessellate:FunctionName 修改器指示。该函数计算三角形的边和内部密铺 (tessellation) 系数。
• • 使用密铺 (tessellation) 时，针对域着色器中生成的每个顶点，在密铺 (tessellation) 之后调用“顶点修改器 (vertex:FunctionName)。在此通常需进行移位贴图。
• 表面着色器甚至可在不进行任何移位贴图的情况下有选择地计算对平滑模型表面的 phong 密铺。

当前密铺 (tessellation) 支持的局限性：

• 仅适用于三角形域 - 无四边形、无等值线密铺 (tessellatio)。
• 使用密铺 (tessellation) 时，着色器被自动编译成 Shader Model 5.0 目标，这意味着其将仅在 DX11 上有效。

顶点修改器中无 GPU 密铺 (tessellation) 的移位

让我们从一个在没有使用密铺 (tessellation) 的情况下进行了一些移位贴图的表面着色器开始。它仅基于来自移位贴图的数量沿法线移动顶点：

    Shader "Tessellation Sample" {
        Properties {
            _MainTex ("Base (RGB)", 2D) = "white" {}
            _DispTex ("Disp Texture", 2D) = "gray" {}
            _NormalMap ("Normalmap", 2D) = "bump" {}
            _Displacement ("Displacement", Range(0, 1.0)) = 0.3
            _Color ("Color", color) = (1,1,1,0)
            _SpecColor ("Spec color", color) = (0.5,0.5,0.5,0.5)
        }
        SubShader {
            Tags { "RenderType"="Opaque" }
            LOD 300

            CGPROGRAM
            #pragma surface surf BlinnPhong addshadow fullforwardshadows vertex:disp nolightmap
            #pragma target 5.0

            struct appdata {
                float4 vertex : POSITION;
                float4 tangent : TANGENT;
                float3 normal : NORMAL;
                float2 texcoord : TEXCOORD0;
            };

            sampler2D _DispTex;
            float _Displacement;

            void disp (inout appdata v)
            {
                float d = tex2Dlod(_DispTex, float4(v.texcoord.xy,0,0)).r * _Displacement;
                v.vertex.xyz += v.normal * d;
            }

            struct Input {
                float2 uv_MainTex;
            };

            sampler2D _MainTex;
            sampler2D _NormalMap;
            fixed4 _Color;

            void surf (Input IN, inout SurfaceOutput o) {
                half4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
                o.Albedo = c.rgb;
                o.Specular = 0.2;
                o.Gloss = 1.0;
                o.Normal = UnpackNormal(tex2D(_NormalMap, IN.uv_MainTex));
            }
            ENDCG
        }
        FallBack "Diffuse"
    }

上面的着色器非常标准，兴趣点为：

• 顶点修改器 disp 对移位贴图进行采样并沿法线移动顶点。
• 它使用自定义的“顶点数据输入”结构 (appdata)，而非默认的 appdata_full。虽然目前还不需要这样，但使用尽可能小的结构，密铺 (tessellation) 会更有效。
• 由于顶点数据没有第二 UV 坐标，因此我们添加 nolightmap 指令来排除光照贴图。

这便是使用该着色器时一些简单的对象的样子：

固定量的密铺 (tessellation)

让我们添加固定量的密铺 (tessellation)，即整个网格的密铺 (tessellation) 等级相同。如果模型表面的大小在屏幕上大致相等，可使用这种方法。然后一些脚本可基于到相机的距离从代码改变密铺 (tessellation) 等级。

    Shader "Tessellation Sample" {
        Properties {
            _Tess ("Tessellation", Range(1,32)) = 4
            _MainTex ("Base (RGB)", 2D) = "white" {}
            _DispTex ("Disp Texture", 2D) = "gray" {}
            _NormalMap ("Normalmap", 2D) = "bump" {}
            _Displacement ("Displacement", Range(0, 1.0)) = 0.3
            _Color ("Color", color) = (1,1,1,0)
            _SpecColor ("Spec color", color) = (0.5,0.5,0.5,0.5)
        }
        SubShader {
            Tags { "RenderType"="Opaque" }
            LOD 300

            CGPROGRAM
            #pragma surface surf BlinnPhong addshadow fullforwardshadows vertex:disp tessellate:tessFixed nolightmap
            #pragma target 5.0

            struct appdata {
                float4 vertex : POSITION;
                float4 tangent : TANGENT;
                float3 normal : NORMAL;
                float2 texcoord : TEXCOORD0;
            };

            float _Tess;

            float4 tessFixed()
            {
                return _Tess;
            }

            sampler2D _DispTex;
            float _Displacement;

            void disp (inout appdata v)
            {
                float d = tex2Dlod(_DispTex, float4(v.texcoord.xy,0,0)).r * _Displacement;
                v.vertex.xyz += v.normal * d;
            }

            struct Input {
                float2 uv_MainTex;
            };

            sampler2D _MainTex;
            sampler2D _NormalMap;
            fixed4 _Color;

            void surf (Input IN, inout SurfaceOutput o) {
                half4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
                o.Albedo = c.rgb;
                o.Specular = 0.2;
                o.Gloss = 1.0;
                o.Normal = UnpackNormal(tex2D(_NormalMap, IN.uv_MainTex));
            }
            ENDCG
        }
        FallBack "Diffuse"
    }

着色器中的密铺 (tessellation) 函数 tessFixed 返回四个密铺 (tessellation) 系数作为单个 float4 值：其中三个系数用于三角形的三条边，一个系数用于三角形的内部。在此，我们仅返回一个在材质属性中设置的常数值。

基于距离的密铺 (tessellation)

我们还可基于距相机的距离来改变密铺 (tessellation) 等级。例如，我们可定义两个距离值：一个是密铺 (tessellation) 最大时的距离（比如 10 米），另一个距离是接近它密铺 (tessellation) 等级会逐渐减少的距离（比如 20 米）。

    Shader "Tessellation Sample" {
        Properties {
            _Tess ("Tessellation", Range(1,32)) = 4
            _MainTex ("Base (RGB)", 2D) = "white" {}
            _DispTex ("Disp Texture", 2D) = "gray" {}
            _NormalMap ("Normalmap", 2D) = "bump" {}
            _Displacement ("Displacement", Range(0, 1.0)) = 0.3
            _Color ("Color", color) = (1,1,1,0)
            _SpecColor ("Spec color", color) = (0.5,0.5,0.5,0.5)
        }
        SubShader {
            Tags { "RenderType"="Opaque" }
            LOD 300

            CGPROGRAM
            #pragma surface surf BlinnPhong addshadow fullforwardshadows vertex:disp tessellate:tessDistance nolightmap
            #pragma target 5.0
            #include "Tessellation.cginc"

            struct appdata {
                float4 vertex : POSITION;
                float4 tangent : TANGENT;
                float3 normal : NORMAL;
                float2 texcoord : TEXCOORD0;
            };

            float _Tess;

            float4 tessDistance (appdata v0, appdata v1, appdata v2) {
                float minDist = 10.0;
                float maxDist = 25.0;
                return UnityDistanceBasedTess(v0.vertex, v1.vertex, v2.vertex, minDist, maxDist, _Tess);
            }

            sampler2D _DispTex;
            float _Displacement;

            void disp (inout appdata v)
            {
                float d = tex2Dlod(_DispTex, float4(v.texcoord.xy,0,0)).r * _Displacement;
                v.vertex.xyz += v.normal * d;
            }

            struct Input {
                float2 uv_MainTex;
            };

            sampler2D _MainTex;
            sampler2D _NormalMap;
            fixed4 _Color;

            void surf (Input IN, inout SurfaceOutput o) {
                half4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
                o.Albedo = c.rgb;
                o.Specular = 0.2;
                o.Gloss = 1.0;
                o.Normal = UnpackNormal(tex2D(_NormalMap, IN.uv_MainTex));
            }
            ENDCG
        }
        FallBack "Diffuse"
    }

在这里，密铺 (tessellation) 函数使用三个参数：在密铺前三个三角形角的顶点数据。需要这样来计算当前基于顶点位置的密铺 (tessellation) 等级。我们将内置帮助文件 Tessellation.cginc 包括在内，并从该文件调用 UnityDistanceBasedTess 函数来进行所有操作。该函数计算每个顶点到相机的距离，并导出最终密铺 (tessellation) 系数。

基于边长的密铺 (tessellation)

纯基于距离的密铺 (tessellation) 仅在三角形的大小非常相似的情况下效果好。在上图中，可以看到具有小三角形的对象被过度密铺，而具有大三角形的对象的密铺又不足。

然而，还可基于屏幕上三角形的边长来计算密铺 (tessellation) 等级 - 边越长，应用的密铺 (tessellation) 系数越大。ied.

    Shader "Tessellation Sample" {
        Properties {
            _EdgeLength ("Edge length", Range(2,50)) = 15
            _MainTex ("Base (RGB)", 2D) = "white" {}
            _DispTex ("Disp Texture", 2D) = "gray" {}
            _NormalMap ("Normalmap", 2D) = "bump" {}
            _Displacement ("Displacement", Range(0, 1.0)) = 0.3
            _Color ("Color", color) = (1,1,1,0)
            _SpecColor ("Spec color", color) = (0.5,0.5,0.5,0.5)
        }
        SubShader {
            Tags { "RenderType"="Opaque" }
            LOD 300

            CGPROGRAM
            #pragma surface surf BlinnPhong addshadow fullforwardshadows vertex:disp tessellate:tessEdge nolightmap
            #pragma target 5.0
            #include "Tessellation.cginc"

            struct appdata {
                float4 vertex : POSITION;
                float4 tangent : TANGENT;
                float3 normal : NORMAL;
                float2 texcoord : TEXCOORD0;
            };

            float _EdgeLength;

            float4 tessEdge (appdata v0, appdata v1, appdata v2)
            {
                return UnityEdgeLengthBasedTess (v0.vertex, v1.vertex, v2.vertex, _EdgeLength);
            }

            sampler2D _DispTex;
            float _Displacement;

            void disp (inout appdata v)
            {
                float d = tex2Dlod(_DispTex, float4(v.texcoord.xy,0,0)).r * _Displacement;
                v.vertex.xyz += v.normal * d;
            }

            struct Input {
                float2 uv_MainTex;
            };

            sampler2D _MainTex;
            sampler2D _NormalMap;
            fixed4 _Color;

            void surf (Input IN, inout SurfaceOutput o) {
                half4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
                o.Albedo = c.rgb;
                o.Specular = 0.2;
                o.Gloss = 1.0;
                o.Normal = UnpackNormal(tex2D(_NormalMap, IN.uv_MainTex));
            }
            ENDCG
        }
        FallBack "Diffuse"
    }

在这里，我们再次仅从 Tessellation.cginc 文件调用 UnityEdgeLengthBasedTess 函数来完成所有实际操作。

出于性能原因，建议调用 UnityEdgeLengthBasedTessCull 函数来代替，该函数将进行修补平截头体剔除。虽然这使着色器消耗的资源稍微多了一点，但可节省大量用于相机视野外网格部分的 GPU 工作量。

Phong 密铺 (Tessellation)

Phong 密铺修改细分表面的位置，使得产生的表面稍微跟随网格法线。对于使低面数网格变得更平滑，这是非常有效的方法。

Unity 的表面着色器可使用 tessphong:VariableName 编译指令自动计算 Phong 密铺 (tessellation)。下面是一个示例着色器：

    Shader "Phong Tessellation" {
        Properties {
            _EdgeLength ("Edge length", Range(2,50)) = 5
            _Phong ("Phong Strengh", Range(0,1)) = 0.5
            _MainTex ("Base (RGB)", 2D) = "white" {}
            _Color ("Color", color) = (1,1,1,0)
        }
        SubShader {
            Tags { "RenderType"="Opaque" }
            LOD 300

            CGPROGRAM
            #pragma surface surf Lambert vertex:dispNone tessellate:tessEdge tessphong:_Phong nolightmap
            #include "Tessellation.cginc"

            struct appdata {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float2 texcoord : TEXCOORD0;
            };

            void dispNone (inout appdata v) { }

            float _Phong;
            float _EdgeLength;

            float4 tessEdge (appdata v0, appdata v1, appdata v2)
            {
                return UnityEdgeLengthBasedTess (v0.vertex, v1.vertex, v2.vertex, _EdgeLength);
            }

            struct Input {
                float2 uv_MainTex;
            };

            fixed4 _Color;
            sampler2D _MainTex;

            void surf (Input IN, inout SurfaceOutput o) {
                half4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
                o.Albedo = c.rgb;
                o.Alpha = c.a;
            }

            ENDCG
        }
        FallBack "Diffuse"
    }

以下为普通着色器（上面一行）与使用 Phong 密铺 (tessellation) 的着色器（下面一行）的对比。可以看到即使未使用任何移位贴图，表面也变得更圆润。