Question

在职责链模式下，有意将使用并实现一个接口（一个或更多的方法）的数个对象松散耦合。一组实现接口的对象按照列表的形式进行组合（或者在极少数情况下按照树的形式）。使用接口的对象向第一个 实现器 （implementor）对象发出请求。第一个实现器对象会确定是否自己执行任何行为，以及是否将该请求沿列表（或树）传播下去。有时，当实现器对象都没有响应请求时，会在模式中编写对一些请求的默认实现。

1.4.1 范例

在该例中，脚本向 lister 对象发送请求， lister 指向 UnixLister 对象。如果它无法处理该请求，则将该请求发送给 WindowsLister 。如果还不能处理该请求，则继续发送给 DefaultLister 。

class UnixLister {
  private nextInLine
  UnixLister(next) { nextInLine = next }
  def listFiles(dir) {
    if (System.getProperty('os.name') == 'Linux') {
      println "ls $dir".execute().text
    } else {
      nextInLine.listFiles(dir)
    }
  }
}

class WindowsLister {
  private nextInLine
  WindowsLister(next) { nextInLine = next }
  def listFiles(dir) {
    if (System.getProperty('os.name') == 'Windows XP') {
      println "cmd.exe /c dir $dir".execute().text
    } else {
      nextInLine.listFiles(dir)
    }
  }
}

class DefaultLister {
  def listFiles(dir) {
    new File(dir).eachFile { f -> println f }
  }
}

def lister = new UnixLister(new WindowsLister(new DefaultLister()))

lister.listFiles('Downloads')

输出一个文件列表（根据操作系统的差别，输出格式将稍有不同）。

下面是 UML 的表示形式：

该模式的变体形式有：

• 可以利用显式接口（比如 Lister ）将实现进行静态类型转换，但由于 duck-typing 特性的存在，这是一种选择方法。
• 可以使用链树而非列表 if (animal.hasBackbone()) 委托给 VertebrateHandler ，否则就委托给 InvertebrateHandler 。
• 可以一直沿链传递，即使在处理请求时。
• 可以在一定的时间不响应不再沿链进行传递。
• 使用 Groovy 的元编程特性沿链传递未知方法。