Question

GUICtrlCreateIcon

---

在GUI上创建一个图标（Icon）控件。

GUICtrlCreateIcon ( 文件名, 图标ID, 左侧, 上方 [, 宽度 [, 高度 [, 风格 [, 扩展风格]]]] )

参数

文件名	要加载的图标文件。
图标ID	若指定的图标文件含有多个图标则要指定图标标识符（编号），否则使用 -1。
左侧	控件左侧的位置。若此值为 -1 则根据 GUICoordMode 的设置来计算左侧位置。
上方	控件上方的位置。若此值为 -1 则根据 GUICoordMode 的设置来计算上方位置。
宽度	[可选参数] 控件的宽度（默认值为上一个控件的宽度）。
高度	[可选参数] 控件的高度（默认值为上一个控件的高度）。
风格	[可选参数] 指定控件的风格。请查看附录中关于 GUI 控件风格的说明。 默认值（-1）： $SS_NOTIFY 强制性风格：$WS_TABSTOP, $SS_ICON
扩展风格	[可选参数] 指定控件的扩展风格。请查看附录的 扩展风格表。

返回值

成功：	返回控件标识符（控件ID）。
失败：	返回值为0。

注意

若要设置或修改控件的各种信息请查看 GUICtrlSet....

若要更新图标则可使用 GUICtrlSetImage。

要在默认风格的基础上添加一个新的风格可使用 BitOr($GUI_SS_DEFAULT_ICON, 新风格,...)。

相关

GUICoordMode（选项）, GUICtrlSetImage, GUICtrlSet..., GUIGetMsg

示例

#include <GUIConstants.au3>

;示例1 ---------------------------
GUICreate(" 我的 GUI 之图标")

$icon = GUICtrlCreateIcon ("shell32.dll",10, 20,20)
$icon2 = GUICtrlCreateIcon ("explorer.icl",10, 20,80)
$icon3 = GUICtrlCreateIcon ("explorer.icl",6, 80,80)
$n1=GUICtrlCreateIcon (@windowsdir & "\cursors\horse.ani",-1, 20,120,32,32)
$n2=GUICtrlCreateIcon ("shell32.dll",7 ,20,160,32,32)
GUISetState ()

; 运行脚本直到窗口被关闭
While 1
$msg = GUIGetMsg()

If $msg = $GUI_EVENT_CLOSE Then ExitLoop
Wend




; 示例2 ---------------------------
Opt("GUICoordMode",1)

GUICreate("我的 GUI 之图标会赛跑", 350,74,-1,-1)
GUICtrlCreateLabel ("", 331,0,1,74,5)
$n1=GUICtrlCreateIcon (@windowsdir & "\cursors\dinosaur.ani", -1, 0,0,32,32)
$n2=GUICtrlCreateIcon ( @windowsdir & "\cursors\horse.ani", -1, 0,40,32,32)

GUISetState (@SW_SHOW)

Dim $a = 0, $b = 0
While ($a < 300) And ($b < 300)
$a = $a + int(Random(0,1)+0.5)
$b = $b + int(Random(0,1)+0.5)
GUICtrlSetPos($n1, $a,0)
GUICtrlSetPos($n2, $b,40)
Sleep(20)
WEnd
sleep(1000)