Question

GUICtrlCreateTabItem

---

在GUI上创建一个标签页控件项目。

GUICtrlCreateTabItem ( "文本" )

参数

文本

控件的文本。

返回值

成功：	返回控件标识符（控件ID）。
失败：	返回值为0。

注意

若要设置或修改控件的各种信息请查看 GUICtrlSet....

若要让指定的标签页在对话框（窗口）打开的时候先被显示则请参考下面的示例使用语句 GUICtrlSetState(-1,$GUI_SHOW)。

若要结束标签控件的定义则只需在最后创建一个空文本的“标签项”即可。这个“标签项”将不被绘制（代码太多了 ...）

相关

GUICtrlSetState, GUIGetMsg

示例

#include <GUIConstants.au3>

GUICreate("我的 GUI 之Tab") ; 创建一个居中显示的窗口

GUISetBkColor(0x00E0FFFF)
GUISetFont(9, 300)

$tab=GUICtrlCreateTab (10,10, 200,100)

$tab0=GUICtrlCreateTabitem ("tab0")
GUICtrlCreateLabel ("label0", 30,80,50,20)
$tab0OK=GUICtrlCreateButton ("OK0", 20,50,50,20)
$tab0input=GUICtrlCreateInput ("默认文本", 80,50,70,20)

$tab1=GUICtrlCreateTabitem ( "tab----1")
GUICtrlCreateLabel ("label1", 30,80,50,20)
$tab1combo=GUICtrlCreateCombo ("", 20,50,60,40)
GUICtrlSetData(-1,"Trids|CyberSlug|Larry|Jon|Tylo", "Jon") ; 默认是 Jon
$tab1OK=GUICtrlCreateButton ("OK1", 80,50,50,20)

$tab2=GUICtrlCreateTabitem ("tab2")
GUICtrlSetState(-1,$GUI_SHOW) ; 这个标签将先显示
GUICtrlCreateLabel ("label2", 30,80,50,20)
$tab2OK=GUICtrlCreateButton ("OK2", 140,50,50)

GUICtrlCreateTabitem ("") ; 结束标签项的定义

GUICtrlCreateLabel ("label3", 20,130,50,20)

GUISetState ()

; 运行脚本直到窗口被关闭
While 1
$msg = GUIGetMsg()

If $msg = $GUI_EVENT_CLOSE Then ExitLoop
Wend