Question

获取 GUI 窗口中控件的各种类型的信息。

GuiControlGet, OutputVar [, Sub-command, ControlID, Param4]

参数

OutputVar

用来存储结果的变量名. 如果此命令无法完成 (请参阅下面的 ErrorLevel), 则此变量被置空.

Sub-command

请参阅后面的列表.

ControlID

如果为空或省略, 则使用指定的输出变量名. 例如，GuiControlGet, MyEdit 等同于 GuiControlGet, MyEdit,, MyEdit。

如果目标控件有关联变量, 则指定此变量名作为 ControlID (此方法优先于下面描述的那个). 由于这个原因, 通常最好给每个之后要使用 GuiControl 或 GuiControlGet 访问的控件分配一个变量, 即使那个控件不是可输入型 (例如 GroupBox 或 Text).

或者 ControlID 可以是 ClassNN（控件的类名和实例编号）或控件的文本，它们都可以通过 Window Spy 获取。使用文本时，匹配行为由 SetTitleMatchMode 决定。注: 图片控件的文件名 (和控件创建时指定的一样) 可以作为 ControlID 使用.

[v1.1.04+]：ControlID 可以是控件的 HWND。在 ControlID 中使用其他类型的值且此控件不在默认的 Gui 上时，必须同时指定 Gui。

Param4

除了下面的子命令列表中注明的, 否则省略此参数.

ErrorLevel

[v1.1.04+] 此命令失败时会抛出异常. 想了解更多信息, 请参阅 运行时错误.

如果指定的窗口/控件不存在或由于其他问题使得命令无法工作, 则 ErrorLevel 被置为 1. 否则被置为 0.

子命令

(空): 留空 Sub-command 来获取控件的内容. 除了下面的控件类型, 其他都是无须解释的:

Picture: 获取控件创建时最初指定的图片文件名. 即使指定了新的图片文件名, 此名称也不会改变.

Edit: 获取控件的内容, 但文本中断行的位置表示为单独的换行符 (`n) 而不是非 GUI 命令 (例如 ControlGetText 和 ControlSetText) 使用的传统 CR+LF (`r`n).

Hotkey: 如果控件中不含控件, 则获取到空值. 否则它获取到修饰符和键名. 例如：^!C，^Home，+^NumpadHome。

Checkbox/Radio: 控件被选中时获取的值为 1, 未选中时为 0, 而灰色状态时为 -1. 要获取控件的文本/标题, 请指定单词 Text 到 Param4. 注: 与 Gui Submit 不同, 单选按钮的状态总是单独获取的, 不论它们是否在单选按钮组中.

UpDown/Slider/Progress: 获取控件的当前位置.

Tab/DropDownList/ComboBox/ListBox: 获取当前选择的项目/选项卡的文本 (如果控件含有 AltSubmit 则为其位置). 对于组合框, 如果没有选择的项目, 则获取控件编辑区域的文本. 对于 多选列表框, 输出结果中使用窗口的 当前分隔符.

ListView 和 TreeView: 当 Sub-command 为空时不支持它们. 作为替代, 请使用内置的 ListView 函数 和 TreeView 函数.

StatusBar: 仅获取首个部分的文本.

ActiveX: 获取控件的 ActiveX 组件的新包装器对象.

注：要无条件获取任意控件的文本/标题而不是其内容，请在 Param4 中指定单词 Text。

 

GuiControlGet, OutputVar, Pos：获取控件的位置和大小。这里的位置相对于 GUI 窗口的工作区, 这是窗口中不包括标题栏, 菜单栏和边框的区域. 获取的结果保存在四个名称以 OutputVar 开始的变量中. 例如：

GuiControlGet, MyEdit, Pos
MsgBox The X coordinate is %MyEditX%. The Y coordinate is %MyEditY%. The width is %MyEditW%. The height is %MyEditH%.

在 函数 中, 要创建一组全局变量而不是局部变量, 请在此命令前 声明 OutputVar 为全局变量 (对于 假设全局 函数, 反之亦成).

 

GuiControlGet, OutputVar, Focus：获取当前含键盘焦点的控件的标识符（ClassNN）。由于指定的 GUI 窗口必须是 活动的, 这样其中的某个控件才会含有焦点, 所以如果窗口不是活动的则 OutputVar 被置空. 用法示例：GuiControlGet, focused_control, focus。

GuiControlGet, OutputVar, FocusV [v1.0.43.06+]: 与上面的 Focus 相同, 不过它获取的是焦点控件的 关联变量 的名称. 如果那个控件没有关联变量, 则获取控件的文本/标题中前 63 个字符 (这常用来避免给每个按钮分配变量名).

GuiControlGet, OutputVar, Enabled: 如果控件是启用的则获取的值为 1, 禁用的则为 0.

GuiControlGet, OutputVar, Visible: 如果控件是可见的则获取的值为 1, 隐藏的则为 0.

GuiControlGet, OutputVar, Hwnd [v1.0.46.16+]: 获取控件的窗口句柄 (HWND). 控件的 HWND 常用于 PostMessage, SendMessage 和 DllCall. 注: HwndOutputVar 通常是获取 HWND 的一种较简便的方法.

GuiControlGet, OutputVar, Name [v1.1.03+]: 获取控件的 关联变量名, 如果没有则 OutputVar 被置空.

备注

要对非默认窗口进行操作 (请参阅下面), 需要在子命令前加上窗口名称或编号和一个冒号, 例如:

GuiControlGet, MyEdit, MyGui:
GuiControlGet, MyEdit, MyGui:Pos
GuiControlGet, Outputvar, MyGui:Focus

即使 ControlID 为控件的关联变量或 HWND 这也是必须的。

GUI 线程 是由 GUI 动作启动的. GUI 动作包含从 GUI 窗口的菜单栏选择一个项目或触发其某个 g 标签 (例如按下按钮).

GUI 线程的 默认窗口名称 是运行此线程的窗口名称. 非 GUI 线程的默认窗口编号为 1.

相关

Gui, GuiControl, ControlGet

示例

GuiControlGet, MyEdit
GuiControlGet, CtrlContents,, MyEdit  ; 和上面相同, 不过这里使用非默认的输出变量.
GuiControlGet, MyCheckbox1 ; 如果选中的则获取的值为 1, 未选中的则为 0.
GuiControlGet, MyCheckbox1,,, Text  ; 获取复选框的标题/文本.
GuiControlGet, Pic, Pos, Static4  ; 位置/大小会保存到 PicX, PicY, PicW 和 PicH