Question

Groovy 为多种集合提供了原生支持，这些类型的集合包括：list、map（映射） 或 range（范围）。它们大多基于 java 集合类型，并且附带有 GDK 中的一些额外方法。

2.1 List（列表）

2.1.1 列表字面量

你可以按照如下方式创建 lists，注意 [] 是空 list 表达式。

def list = [5, 6, 7, 8]
assert list.get(2) == 7
assert list[2] == 7
assert list instanceof java.util.List

def emptyList = []
assert emptyList.size() == 0
emptyList.add(5)
assert emptyList.size() == 1

每一个 list 表达式都创建了一个 java.util.List 接口的实现。

当然也可以把 list 作为构建其他 list 的来源：

def list1 = ['a', 'b', 'c']
//基于 list1 中的项构建一个新的列表
def list2 = new ArrayList<String>(list1)

assert list2 == list1 // == 用来检查两个列表中的每个相应元素是否相同

// 也可以调用 clone()   
def list3 = list1.clone()
assert list3 == list1  

列表其实是一个有序的对象集合：

def list = [5, 6, 7, 8]
assert list.size() == 4
assert list.getClass() == ArrayList   // 特定类型的列表

assert list[2] == 7           // 起始索引为 0
assert list.getAt(2) == 7         // 下标操作符 [] 的等效方法
assert list.get(2) == 7         // 另一种方法

list[2] = 9
assert list == [5, 6, 9, 8,]       // 允许末尾出现逗号

list.putAt(2, 10)             // 当数值发生变动时，[] 的等效方法
assert list == [5, 6, 10, 8]
assert list.set(2, 11) == 10      // 返回旧值的另一种方法
assert list == [5, 6, 11, 8]

assert ['a', 1, 'a', 'a', 2.5, 2.5f, 2.5d, 'hello', 7g, null, 9 as byte]  
// 对象的类型可以不同，对象也允许重复。

assert [1, 2, 3, 4, 5][-1] == 5       // 使用负数代表从末尾开始计算索引
assert [1, 2, 3, 4, 5][-2] == 4
assert [1, 2, 3, 4, 5].getAt(-2) == 4     // getAt() 允许出现负数索引......
try {
  [1, 2, 3, 4, 5].get(-2)         // 但负数索引不允许用于 get() 方法
  assert false
} catch (e) {
  assert e instanceof ArrayIndexOutOfBoundsException
}

2.1.2 作为布尔表达式的列表

可以将列表用作 boolean 值：

assert ![]       // 空列表的结果是 false  

//所有其他列表，不管其中包含的内容，其布尔值都是 true  
assert [1] && ['a'] && [0] && [0.0] && [false] && [null]

2.1.3 列表中的迭代

通常，列表中的迭代需要调用 each 和 eachWithIndex 方法来实现，在列表中的每一项上都将执行一定的代码：

[1, 2, 3].each {
  println "Item: $it" // `it` 是个很隐含的参数，对应着当前元素  
}
['a', 'b', 'c'].eachWithIndex { it, i -> // `it` 是当前元素，而 `i` 则是索引   
  println "$i: $it"
}

除了迭代之外，往往还用到将列表中的每个元素转换成其他内容，从而创建一个新的列表。这种操作常被称为 映射 （mapping），在 Groovy 中利用 collect 方法来实现：

assert [1, 2, 3].collect { it * 2 } == [2, 4, 6]

// 代替 `collect` 的快捷格式
assert [1, 2, 3]*.multiply(2) == [1, 2, 3].collect { it.multiply(2) }

def list = [0]
// 有可能要给 `collect` 提供收集元素的列表  
assert [1, 2, 3].collect(list) { it * 2 } == [0, 2, 4, 6]
assert list == [0, 2, 4, 6]

2.1.4 操纵列表

过滤与搜索

Groovy Development Kit 中包含着与集合相关的大量方法，这些实用性的方法大大增强了集合的标准操作。其中一些方法如下所示：

assert [1, 2, 3].find { it > 1 } == 2       // 查找符合规则的第一个元素
assert [1, 2, 3].findAll { it > 1 } == [2, 3]   // 查找符合规则的所有元素
assert ['a', 'b', 'c', 'd', 'e'].findIndexOf {    // 查找符合规则的第一个元素的索引  
  it in ['c', 'e', 'g']
} == 2

assert ['a', 'b', 'c', 'd', 'c'].indexOf('c') == 2  // 返回索引
assert ['a', 'b', 'c', 'd', 'c'].indexOf('z') == -1 // 索引 -1 意指该值并不在列表中
assert ['a', 'b', 'c', 'd', 'c'].lastIndexOf('c') == 4

assert [1, 2, 3].every { it < 5 }         // 如果所有元素都符合断言，则返回 true
assert ![1, 2, 3].every { it < 3 }
assert [1, 2, 3].any { it > 2 }         // 只要有元素符合断言，就返回 true
assert ![1, 2, 3].any { it > 3 }

assert [1, 2, 3, 4, 5, 6].sum() == 21        // 利用 plus() 方法对任何数值进行加和运算
assert ['a', 'b', 'c', 'd', 'e'].sum {
  it == 'a' ? 1 : it == 'b' ? 2 : it == 'c' ? 3 : it == 'd' ? 4 : it == 'e' ? 5 : 0
  // sum 中使用的自定义值
} == 15
assert ['a', 'b', 'c', 'd', 'e'].sum { ((char) it) - ((char) 'a') } == 10
assert ['a', 'b', 'c', 'd', 'e'].sum() == 'abcde'
assert [['a', 'b'], ['c', 'd']].sum() == ['a', 'b', 'c', 'd']

// 可以提供一个初始化值
assert [].sum(1000) == 1000
assert [1, 2, 3].sum(1000) == 1006

assert [1, 2, 3].join('-') == '1-2-3'       // 字符串连接
assert [1, 2, 3].inject('counting: ') {
  str, item -> str + item           // 减少操作
} == 'counting: 123'
assert [1, 2, 3].inject(0) { count, item ->
  count + item
} == 6

下面是 Groovy 中惯用的一种寻找集合中最大值与最小值的方法：

def list = [9, 4, 2, 10, 5]
assert list.max() == 10
assert list.min() == 2

// 跟任何类似的可对比对象一样，我们也可以比较单个的字符
assert ['x', 'y', 'a', 'z'].min() == 'a'

// 可以使用闭包来指定排序行为  
def list2 = ['abc', 'z', 'xyzuvw', 'Hello', '321']
assert list2.max { it.size() } == 'xyzuvw'
assert list2.min { it.size() } == 'z'   

除了闭包之外，还可以使用 Comparator 来定义比较条件：

Comparator mc = { a, b -> a == b ? 0 : (a < b ? -1 : 1) }

def list = [7, 4, 9, -6, -1, 11, 2, 3, -9, 5, -13]
assert list.max(mc) == 11
assert list.min(mc) == -13

Comparator mc2 = { a, b -> a == b ? 0 : (Math.abs(a) < Math.abs(b)) ? -1 : 1 }

assert list.max(mc2) == -13
assert list.min(mc2) == -1

assert list.max { a, b -> a.equals(b) ? 0 : Math.abs(a) < Math.abs(b) ? -1 : 1 } == -13
assert list.min { a, b -> a.equals(b) ? 0 : Math.abs(a) < Math.abs(b) ? -1 : 1 } == -1

添加或去除元素

我们可以使用 [] 来指定一个新的空列表，然后用 << 将列表项添加进去：

def list = []
assert list.empty

list << 5
assert list.size() == 1

list << 7 << 'i' << 11
assert list == [5, 7, 'i', 11]

list << ['m', 'o']
assert list == [5, 7, 'i', 11, ['m', 'o']]

// `<<` 链中的第一项是目标列表  
assert ([1, 2] << 3 << [4, 5] << 6) == [1, 2, 3, [4, 5], 6]

// 使用 `leftShift` 等同于使用 `<<`  
assert ([1, 2, 3] << 4) == ([1, 2, 3].leftShift(4))

我们可以用多种方式为列表添加元素：

assert [1, 2] + 3 + [4, 5] + 6 == [1, 2, 3, 4, 5, 6]
// 等于调用 `plus` 方法
assert [1, 2].plus(3).plus([4, 5]).plus(6) == [1, 2, 3, 4, 5, 6]

def a = [1, 2, 3]
a += 4    // 创建一个新列表，并以这种方式为 `a` 添加新的元素  
a += [5, 6]
assert a == [1, 2, 3, 4, 5, 6]

assert [1, *[222, 333], 456] == [1, 222, 333, 456]
assert [*[1, 2, 3]] == [1, 2, 3]
assert [1, [2, 3, [4, 5], 6], 7, [8, 9]].flatten() == [1, 2, 3, 4, 5, 6, 7, 8, 9]

def list = [1, 2]
list.add(3)
list.addAll([5, 4])
assert list == [1, 2, 3, 5, 4]

list = [1, 2]
list.add(1, 3) // 把 3 添加到索引为 1 的元素之前  
assert list == [1, 3, 2]

list.addAll(2, [5, 4]) //将 [5,4] 添加到索引为 2 的元素之前   
assert list == [1, 3, 5, 4, 2]

list = ['a', 'b', 'z', 'e', 'u', 'v', 'g']
list[8] = 'x' // `[]` 可以当操作符使用，从而按需扩展列表   
// 如果需要，也可以在列表中添加 null 值   
assert list == ['a', 'b', 'z', 'e', 'u', 'v', 'g', null, 'x']

但要提请大家注意的是，列表中的 + 操作符生成的结果是不可变的。与 << 操作符相比，使用它会创建一个新列表，而这往往不是你想要的结果，容易引起性能问题。

Groovy Development Kit 中还包含了一些可以通过值来去除列表元素的方法：

assert ['a','b','c','b','b'] - 'c' == ['a','b','b','b']
assert ['a','b','c','b','b'] - 'b' == ['a','c']
assert ['a','b','c','b','b'] - ['b','c'] == ['a']

def list = [1,2,3,4,3,2,1]
list -= 3       // 从原始列表中去除 `3` 创建一个新列表   
assert list == [1,2,4,2,1]
assert ( list -= [2,4] ) == [1,1]

也可以按照索引来去除列表元素，这时列表会发生变化：

def list = [1,2,3,4,5,6,2,2,1]
assert list.remove(2) == 3      // 去除第 3 个元素，然后返回该元素  
assert list == [1,2,4,5,6,2,2,1]

如果你只想去除列表中第一个跟值相同的元素，而不是所有元素的话，可以使用 remove 方法：

def list= ['a','b','c','b','b']
assert list.remove('c')       // 去除 'c' 并返回 true，因为元素已经清除了  
assert list.remove('b')       // 去除第一个 'b' 并返回 true，因为元素已经清除了

assert ! list.remove('z')       // 返回 false，因为没有这个元素可供清除  
assert list == ['a','b','b']

去除列表中所有元素，可以使用 clear 方法：

def list= ['a',2,'c',4]
list.clear()
assert list == []

集合操作

Groovy Development Kit 中还包含了一些便于操作集合的方法：

assert 'a' in ['a','b','c']       // 如果某一元素属于该列表，则返回 true  
assert ['a','b','c'].contains('a')    // 等同于 Java 中的 `contains` 方法   
assert [1,3,4].containsAll([1,4])     // `containsAll` 将检查是否已经找到所有的元素  

assert [1,2,3,3,3,3,4,5].count(3) == 4  // 计算匹配相应值的元素的数目  
assert [1,2,3,3,3,3,4,5].count {
  it%2==0               // 计算符合谓语要求的元素数目  
} == 2

assert [1,2,4,6,8,10,12].intersect([1,3,6,9,12]) == [1,6,12]

assert [1,2,3].disjoint( [4,6,9] )
assert ![1,2,3].disjoint( [2,4,6] )

排序

操作集合往往会用到排序。Groovy 提供了多种列表排序方法，从使用闭包到比较器，如下所示：

assert [6, 3, 9, 2, 7, 1, 5].sort() == [1, 2, 3, 5, 6, 7, 9]

def list = ['abc', 'z', 'xyzuvw', 'Hello', '321']
assert list.sort {
  it.size()
} == ['z', 'abc', '321', 'Hello', 'xyzuvw']

def list2 = [7, 4, -6, -1, 11, 2, 3, -9, 5, -13]
assert list2.sort { a, b -> a == b ? 0 : Math.abs(a) < Math.abs(b) ? -1 : 1 } ==
    [-1, 2, 3, 4, 5, -6, 7, -9, 11, -13]

Comparator mc = { a, b -> a == b ? 0 : Math.abs(a) < Math.abs(b) ? -1 : 1 }

// 只适用于 JDK 8+ 
// list2.sort(mc)
// assert list2 == [-1, 2, 3, 4, 5, -6, 7, -9, 11, -13]

def list3 = [6, -3, 9, 2, -7, 1, 5]

Collections.sort(list3)
assert list3 == [-7, -3, 1, 2, 5, 6, 9]

Collections.sort(list3, mc)
assert list3 == [1, 2, -3, 5, 6, -7, 9]  

复制元素

Groovy Development Kit 中利用操作符重载来提供列表元素的复制方法。

assert [1, 2, 3] * 3 == [1, 2, 3, 1, 2, 3, 1, 2, 3]
assert [1, 2, 3].multiply(2) == [1, 2, 3, 1, 2, 3]
assert Collections.nCopies(3, 'b') == ['b', 'b', 'b']

// JDK 的 nCopies 的语义跟列表所用的 multiply 截然不同
assert Collections.nCopies(2, [1, 2]) == [[1, 2], [1, 2]] // 而不是 [1,2,1,2]

2.2 Maps

2.2.1 Map 字面量

在 Groovy 中，Map（也被称为关联数组）可以通过 map 的字面格式（ [:] ）来创建：

def map = [name: 'Gromit', likes: 'cheese', id: 1234]
assert map.get('name') == 'Gromit'
assert map.get('id') == 1234
assert map['name'] == 'Gromit'
assert map['id'] == 1234
assert map instanceof java.util.Map

def emptyMap = [:]
assert emptyMap.size() == 0
emptyMap.put("foo", 5)
assert emptyMap.size() == 1
assert emptyMap.get("foo") == 5

Map 的键默认都是字符串： [a:1] 和 ['a':1] 是相等的。这个特点有时可能会让人感到困扰，比如当你定义了一个名为 a 的变量，而又想把 a 的 值 定义为 map 中的键时。在这种情况下，你 必须 用括号把键转义，如下所示：

def a = 'Bob'
def ages = [a: 43]
assert ages['Bob'] == null // 没有找到 `Bob` 
assert ages['a'] == 43   // 因为 `a` 是一个字面量！

ages = [(a): 43]      // 现在用括号把 `a` 转义
assert ages['Bob'] == 43   // 就找到 `Bob` 了！

除了 map 字面量之外，还可以克隆 map，获得一个新的 map 副本：

def map = [
    simple : 123,
    complex: [a: 1, b: 2]
]
def map2 = map.clone()
assert map2.get('simple') == map.get('simple')
assert map2.get('complex') == map.get('complex')
map2.get('complex').put('c', 3)
assert map.get('complex').get('c') == 3

结果的 map 是原始 map 的浅层副本，如前例所示。

2.2.2 Map 属性表示法

Map 也可以像 bean 那样，只要键是字符串这种有效的 Groovy 标识符，就可以使用属性表示法来获取/设置 Map 中的元素。

def map = [name: 'Gromit', likes: 'cheese', id: 1234]
assert map.name == 'Gromit'   // 可以替代 map.get('Gromit') 
assert map.id == 1234

def emptyMap = [:]
assert emptyMap.size() == 0
emptyMap.foo = 5
assert emptyMap.size() == 1
assert emptyMap.foo == 5

注意： map.foo 有意被设计成一直搜索 map 中的 foo 键。这意味着在一个不含有 class 键的 map 中， foo.class 将会返回 null 。如果你真的想知道类的话，必须使用 getClass() 方法。

def map = [name: 'Gromit', likes: 'cheese', id: 1234]
assert map.class == null
assert map.get('class') == null
assert map.getClass() == LinkedHashMap // 这可能是你想要的   

map = [1    : 'a',
     (true) : 'p',
     (false): 'q',
     (null) : 'x',
     'null' : 'z']
assert map.containsKey(1) // 1 不是标识符，所以可以这样用   
assert map.true == null
assert map.false == null
assert map.get(true) == 'p'
assert map.get(false) == 'q'
assert map.null == 'z'
assert map.get(null) == 'x'

2.2.3 对 map 的迭代

Groovy Development Kit ，对 map 惯用的迭代会使用 each 和 eachWithIndex 两种方法。值得注意的是，使用 map 字面量标记定义的 map 都是 有序 的。也就是说，如果你迭代 map 中的元素，元素项绝对会按照它们添加进 map 的顺序返回。

def map = [
    Bob  : 42,
    Alice: 54,
    Max  : 33
]

// `entry` 是一个 map 项
map.each { entry ->
  println "Name: $entry.key Age: $entry.value"
}

// `entry` 是一个 map 项，`i` 是 map 中的索引
map.eachWithIndex { entry, i ->
  println "$i - Name: $entry.key Age: $entry.value"
}

// 当然你还可以直接利用键与值来进行迭代  
map.each { key, value ->
  println "Name: $key Age: $value"
}

// Key、value 和 i 都可以作为 map 中的索引  
map.eachWithIndex { key, value, i ->
  println "$i - Name: $key Age: $value"
}

2.2.4 操纵 map

添加或去除元素

为 map 添加元素，可以使用 put 方法，下标运算符，或使用 putAll ：

def defaults = [1: 'a', 2: 'b', 3: 'c', 4: 'd']
def overrides = [2: 'z', 5: 'x', 13: 'x']

def result = new LinkedHashMap(defaults)
result.put(15, 't')
result[17] = 'u'
result.putAll(overrides)
assert result == [1: 'a', 2: 'z', 3: 'c', 4: 'd', 5: 'x', 13: 'x', 15: 't', 17: 'u']

去除 map 中所有元素，可以使用 clear 方法：

def m = [1:'a', 2:'b']
assert m.get(1) == 'a'
m.clear()
assert m == [:]

使用 map 字面量格式生成的 map 使用的是 equals 对象和 hashcode 方法。这意味着你 不能 使用哈希值容易改变的对象，或者说你无法再找回关联值。

另外值得一提的是，你永远不应使用 GString 作为 map 的键，因为 GString 的哈希值跟相应的 String 的哈希值是不同的。

def key = 'some key'
def map = [:]
def gstringKey = "${key.toUpperCase()}"
map.put(gstringKey,'value')
assert map.get('SOME KEY') == null

键、值与项

这里集中审视一下键、值与项的关系。

def map = [1:'a', 2:'b', 3:'c']

def entries = map.entrySet()
entries.each { entry ->
  assert entry.key in [1,2,3]
  assert entry.value in ['a','b','c']
}

def keys = map.keySet()
assert keys == [1,2,3] as Set

上述代码所返回的变异值（map 项、键或值）是非常令人失望的，因为该操作的成功直接跟操作的 map 类型有关。尤其关键的是，Groovy 依靠 JDK 的集合，所以一般无法保证能够安全地通过 keySet 、 entrySet ，或 values 来操控集合。

过滤与搜索

Groovy development kit 所包含的过滤、搜索及收集方法跟 lists 中的 差不多。

def people = [
  1: [name:'Bob', age: 32, gender: 'M'],
  2: [name:'Johnny', age: 36, gender: 'M'],
  3: [name:'Claire', age: 21, gender: 'F'],
  4: [name:'Amy', age: 54, gender:'F']
]

def bob = people.find { it.value.name == 'Bob' } // 查找单独的一个项
def females = people.findAll { it.value.gender == 'F' }

// 都能返回项，但可以使用 `collect` 来获取一些信息，比如 ages
def ageOfBob = bob.value.age
def agesOfFemales = females.collect {
  it.value.age
}

assert ageOfBob == 32
assert agesOfFemales == [21,54]

// 但你也可以使用键/值对作为闭包的参数  
def agesOfMales = people.findAll { id, person ->
  person.gender == 'M'
}.collect { id, person ->
  person.age
}
assert agesOfMales == [32, 36]

// 如果所有项都匹配谓语，`every` 就返回 true 
assert people.every { id, person ->
  person.age > 18
}

// 如果所有项都匹配谓语，`any` 就返回 true  

assert people.any { id, person ->
  person.age == 54
}   

Grouping

我们利用一些规则将列表中的各项分组归入一个新创建的 map 中，如下所示：

assert ['a', 7, 'b', [2, 3]].groupBy {
  it.class
} == [(String)   : ['a', 'b'],
    (Integer)  : [7],
    (ArrayList): [[2, 3]]
]

assert [
    [name: 'Clark', city: 'London'], [name: 'Sharma', city: 'London'],
    [name: 'Maradona', city: 'LA'], [name: 'Zhang', city: 'HK'],
    [name: 'Ali', city: 'HK'], [name: 'Liu', city: 'HK'],
].groupBy { it.city } == [
    London: [[name: 'Clark', city: 'London'],
         [name: 'Sharma', city: 'London']],
    LA  : [[name: 'Maradona', city: 'LA']],
    HK  : [[name: 'Zhang', city: 'HK'],
         [name: 'Ali', city: 'HK'],
         [name: 'Liu', city: 'HK']],
]

2.3. 范围（Ranges）

利用范围可以创建一列连续的值。它们可以像 List 那样使用，因为 Range 继承自 java.util.List 。

用 .. 标记法定义的范围是全包含的（包含首尾两个值的列表）。

用 ..< 标记法定义的范围是半包含的，即只含有起始值，而不包含末尾值。

// 全包含范围
def range = 5..8
assert range.size() == 4
assert range.get(2) == 7
assert range[2] == 7
assert range instanceof java.util.List
assert range.contains(5)
assert range.contains(8)

// 半包含范围
range = 5..<8
assert range.size() == 3
assert range.get(2) == 7
assert range[2] == 7
assert range instanceof java.util.List
assert range.contains(5)
assert !range.contains(8)

//不使用索引，获取范围的末尾值   
range = 1..10
assert range.from == 1
assert range.to == 10

注意，int 类型的范围实现的效率高，创建了一个轻量级的包含了首尾值的 Java 对象。

任何实现了 java.lang.Comparable 接口用于相互比较的 Java 对象都可以使用范围。可以用 next() 和 previous() 来返回后一个/前一个的范围项。例如，我们可以创建一定范围的 String 元素：

// 全包含范围  
def range = 'a'..'d'
assert range.size() == 4
assert range.get(2) == 'c'
assert range[2] == 'c'
assert range instanceof java.util.List
assert range.contains('a')
assert range.contains('d')
assert !range.contains('e')

你还可以利用一个经典的 for 循环来在范围中迭代：

for (i in 1..10) {
  println "Hello ${i}"
}

但你还可以采用 Groovy 更惯用的风格来做，利用 each 方法来迭代一个范围：

(1..10).each { i ->
  println "Hello ${i}"
}

范围还可以用在 switch 语句中：

switch (years) {
  case 1..10: interestRate = 0.076; break;
  case 11..25: interestRate = 0.052; break;
  default: interestRate = 0.037;
}

2.4 对集合（collection）的一些语法增强

2.4.1 GPath 支持

对于列表和 map 都支持属性标记法，Groovy 提供了语法糖，使得处理内嵌集合变得非常方便，如下例所示：

def listOfMaps = [['a': 11, 'b': 12], ['a': 21, 'b': 22]]
assert listOfMaps.a == [11, 21] //GPath 标记
assert listOfMaps*.a == [11, 21] //散布点标记  

listOfMaps = [['a': 11, 'b': 12], ['a': 21, 'b': 22], null]
assert listOfMaps*.a == [11, 21, null] // 也适合 null 值
assert listOfMaps*.a == listOfMaps.collect { it?.a } // 等价标记  
// 但只收集 非 null 值
assert listOfMaps.a == [11,21]  

2.4.2 散布操作符

散布操作符还可用于将一个集合内联到另一个中。它是一个语法糖，因为通过它能够避免调用 putAll ，有利于实现单行方式。

assert [ 'z': 900,
     *: ['a': 100, 'b': 200], 'a': 300] == ['a': 300, 'b': 200, 'z': 900]
// 在 map 定义中 散布 map 标记法
assert [*: [3: 3, *: [5: 5]], 7: 7] == [3: 3, 5: 5, 7: 7]

def f = { [1: 'u', 2: 'v', 3: 'w'] }
assert [*: f(), 10: 'zz'] == [1: 'u', 10: 'zz', 2: 'v', 3: 'w']
//在函数参数中的散布 map 标记法
f = { map -> map.c }
assert f(*: ['a': 10, 'b': 20, 'c': 30], 'e': 50) == 30

f = { m, i, j, k -> [m, i, j, k] }
//使用散布 map 标记法来处理未命名与已命名参数  
assert f('e': 100, *[4, 5], *: ['a': 10, 'b': 20, 'c': 30], 6) ==
    [["e": 100, "b": 20, "c": 30, "a": 10], 4, 5, 6]

2.4.3 星号（ * ）操作符

通过星号操作符这个快捷操作符，你可以对集合中所有的元素调用方法或属性：

assert [1, 3, 5] == ['a', 'few', 'words']*.size()

class Person {
  String name
  int age
}
def persons = [new Person(name:'Hugo', age:17), new Person(name:'Sandra',age:19)]
assert [17, 19] == persons*.age

2.4.4 利用下标操作符进行截取操作

对列表、数组及 map，使用下标表达式，可以按索引访问。有趣的是，在这种情况下，字符串也可以被看成一种特殊的集合：

def text = 'nice cheese gromit!'
def x = text[2]

assert x == 'c'
assert x.class == String

def sub = text[5..10]
assert sub == 'cheese'

def list = [10, 11, 12, 13]
def answer = list[2,3]
assert answer == [12,13]

注意，也可以使用范围来抽取部分集合：

list = 100..200
sub = list[1, 3, 20..25, 33]
assert sub == [101, 103, 120, 121, 122, 123, 124, 125, 133]

下标操作符还可以用来更新一个已存在的（可改变）集合：

list = ['a','x','x','d']
list[1..2] = ['b','c']
assert list == ['a','b','c','d']

值得一提的是，允许出现负数，从而方便了从集合末尾起提取元素。

可以利用负数从列表、数组及字符串等结构的末尾起开始计数：

text = "nice cheese gromit!"
x = text[-1]
assert x == "!"

def name = text[-7..-2]
assert name == "gromit"

最后，如果你使用了反向的范围（起始索引大于末尾索引），所得结果也是反的。

text = "nice cheese gromit!"
name = text[3..1]
assert name == "eci"

2.5 增强的集合方法

除了 列表 、 map 及 范围 之外，Groovy 还提供了大量的额外方法来实现过滤、收集、组织、计算等操作，这些方法都可以直接适用于集合，或者是更简单的实现了 iterable 接口的类。

关于更多细节，可以阅读 Groovy development kit API 文档，尤其是以下部分内容：

• Iterable 接口所添加的方法 。
• Iterator 接口所添加的方法 。
• Collection 接口所添加的方法 。
• List 接口所添加的方法 。
• Map 接口所添加的方法 。