Windows IP 变更脚本

Question

Windows IP 变更脚本文件（批处理文件），主要涉及两个步骤：

1. 创建批处理文件
2. 设置以管理员身份运行

创建批处理文件

新建文本文档，参照以下内容，按需要修改，最后保存文件，并修改文件名为 IPChanger.bat （可以是任意文件名，但要求文件扩展名必须为 .bat ）。

@echo off
cls

rem 网络连接名称
set "nic=以太网"
rem 静态 IP 地址
set "ip=192.168.0.37"
set "governmentIP=192.168.166.37"
rem 子网掩码
set "subnetMask=255.255.255.0"
rem 默认网关
set "defaultGateway=192.168.0.1"
set "governmentDefaultGateway=192.168.166.1"
rem 首选 DNS 服务器
set "dns=221.12.1.227"
rem 备用 DNS 服务器
set "dns2=202.101.172.35"

:start
echo [1] 配置公司内网 IP
echo [2] 配置政务外网 IP
echo [3] 动获得 IP 地址（DHCP）
echo [4] 直接退出
set choice=
set /p choice=请输入编号，并按回车键结束:
if "%choice%"=="1" goto setStaticIP
if "%choice%"=="2" goto setGovernmentStaticIP
if "%choice%"=="3" goto setDHCP
if "%choice%"=="4" goto end
echo "%choice%" 是无效的，请重新输入
echo.
goto start

:setStaticIP
rem 网络连接名称 静态 IP 地址 子网掩码 默认网关
netsh interface ipv4 set address name=%nic% static %ip% %subnetMask% %defaultGateway%
netsh interface ipv4 add dns name=%nic% addr=%dns% > null
netsh interface ipv4 add dns name=%nic% addr=%dns2% index=2 > null
goto end

:setGovernmentStaticIP
rem 网络连接名称 静态 IP 地址 子网掩码 默认网关
netsh interface ipv4 set address name=%nic% static %governmentIP% %subnetMask% %governmentDefaultGateway%
netsh interface ipv4 add dns name=%nic% addr=%dns% > null
netsh interface ipv4 add dns name=%nic% addr=%dns2% index=2 > null
goto end

:setDHCP
rem 自动从 DHCP 服务器获取 IP 地址
netsh interface ipv4 set address name=%nic% dhcp
netsh interface ipv4 set dns name=%nic% dhcp
goto end

:end
echo.
echo 当前网络连接信息
ipconfig /all
pause

设置以管理员身份运行

1. 鼠标右键 IPChanger.bat ，打开右键菜单，点击 属性
2. 点击 高级 按钮，然后勾选 用管理员身份运行(R) ，最后 确定

使用

1. 双击 IPChanger.bat ，在弹出的用户账户控制中选择 是 （即以管理员身份运行）
2. 在命令行窗口的光标处填入对应数值，然后回车，即可自动修改当前 IP 配置